1

我将 Grails 3.3.2 与 mongoDB 插件 (v6.1.4) 和 Spring Security Core 插件 (v3.2.0) 一起使用。

我有UserPasswordEncoderListener以下persistenceEvent方法：

 @Override
protected void onPersistenceEvent(AbstractPersistenceEvent event) {
    if (event.entityObject instanceof User) {
        User u = (event.entityObject as User)
        if (u.password && (event.eventType == EventType.PreInsert || (event.eventType == EventType.PreUpdate && u.hasChanged('password')))) {
            event.getEntityAccess().setProperty("password", encodePassword(u.password))
        }
    }
}

问题是hasChanged每次我保存一个没有更新的用户对象时调用总是返回true，导致已经编码的密码被重新编码，从而破坏了身份验证。

一种解决方法是使用旧方法，只需从数据库中检索原始密码并在编码之前进行比较，但我想知道为什么hasChanged错误地返回 true。

我hasChanged通过在 groovy 控制台中运行以下命令测试了它在其他地方的行为是否正确：

def user = User.findByEmail("user@email.com")
println "Result: "+ user.hasChanged('password')

结果是Result: false。为什么它在持久性侦听器类中不起作用？

仅供参考：我在 resources.groovy 中定义了以下 bean：

userPasswordEncoderListener(UserPasswordEncoderListener,ref('mongoDatastore'))
4

2 回答 2

1

您是否尝试过使用isDirty()而不是hasChanged()在您的听众中？

例如：

package com.mycompany.myapp

import grails.plugin.springsecurity.SpringSecurityService
import org.grails.datastore.mapping.engine.event.AbstractPersistenceEvent
import org.grails.datastore.mapping.engine.event.PreInsertEvent
import org.grails.datastore.mapping.engine.event.PreUpdateEvent
import org.springframework.beans.factory.annotation.Autowired
import grails.events.annotation.gorm.Listener
import groovy.transform.CompileStatic

@CompileStatic
class UserPasswordEncoderListener {

    @Autowired
    SpringSecurityService springSecurityService

    @Listener(User)
    void onPreInsertEvent(PreInsertEvent event) {
        encodePasswordForEvent(event)
    }

    @Listener(User)
    void onPreUpdateEvent(PreUpdateEvent event) {
        encodePasswordForEvent(event)
    }

    private void encodePasswordForEvent(AbstractPersistenceEvent event) {
        if (event.entityObject instanceof User) {
            User u = event.entityObject as User
            if (u.password && ((event instanceof  PreInsertEvent) || (event instanceof PreUpdateEvent && u.isDirty('password')))) {
                event.getEntityAccess().setProperty('password', encodePassword(u.password))
            }
        }
    }

    private String encodePassword(String password) {
        springSecurityService?.passwordEncoder ? springSecurityService.encodePassword(password) : password
    }
}

更多信息见：https ://grails-plugins.github.io/grails-spring-security-core/3.2.x/index.html#tutorials

于 2018-06-28T16:06:38.463 回答
0

现在临时解决方法：

@Override
protected void onPersistenceEvent(AbstractPersistenceEvent event) {
    if (event.entityObject instanceof User) {
        User u = (event.entityObject as User)
        if (u.password && (event.eventType == EventType.PreInsert || (event.eventType == EventType.PreUpdate && u.hasChanged('password')))) {
            if(event.eventType == EventType.PreUpdate){ //Temp workaround until hasChanged behaves correctly
                def originalUser = User.get(u?.id)
                if(originalUser.password != u.password){
                    event.getEntityAccess().setProperty("password", encodePassword(u.password))
                }
            }else {
                event.getEntityAccess().setProperty("password", encodePassword(u.password))
            }

        }
    }
}

在 github 存储库 ( https://github.com/grails-plugins/grails-spring-security-core/issues/539 ) 上留下了一个问题。将根据反馈进行更新。

于 2018-04-07T17:07:44.693 回答