1

我有两个要与comm命令进行比较的 ID 列表。我的问题是输出如下所示：

YAL002W
YAL003W
        YAL004W
        YAL005C
                YAL008W
        YAL011W

我想要做的就是尝试以某种方式对其进行管道传输，以便在写入文件时没有空的空间，当我在excel. 我已经尝试了所有我发现的 grep、awk 和 sed 的可能组合来删除空格而没有运气......
所以我得出的结论是，列分别由一个或两个制表符分隔，因此我无法轻松删除它们就像在不删除文件格式的情况下删除空格一样。

欢迎任何帮助或建议。谢谢

编辑：

我希望我的输出是三列，制表符分隔，没有空格

YAL002W YAL004W YAL008W
YAL003W YAL005C
        YAL011W

EDIT2 避免引用的 XY 问题：

原始问题（X）：我必须列出，我想在两个列表之间找到共同和独特的词（稍后生成维恩图）。这comm似乎是一个完美的解决方案，因为我同时获得了所有三个列表，以后我可以轻松地将其导入到 Excel 中。

次要问题（Y）：生成的三列不是三列（或者我开始认为），因为我不能，也不能用通常的或cut -f删除空格（例如）。awk 'NF'grep .

4

5 回答 5

2

鉴于此输入和comm输出：

$ cat file1
YAL002W
YAL003W
YAL008W

$ cat file2
YAL004W
YAL005C
YAL008W
YAL011W

$ comm file1 file2
YAL002W
YAL003W
        YAL004W
        YAL005C
                YAL008W
        YAL011W

这将满足您的要求：

$ cat tst.awk
BEGIN { FS=OFS="\t" }
{
    colNr = NF
    rowNr = ++rowNrs[colNr]
    val[rowNr,colNr] = $NF
    numCols = (colNr > numCols ? colNr : numCols)
    numRows = (rowNr > numRows ? rowNr : numRows)
}
END {
    for (rowNr=1; rowNr<=numRows; rowNr++) {
        for (colNr=1; colNr<=numCols; colNr++) {
            printf "%s%s", val[rowNr,colNr], (colNr<numCols ? OFS : ORS)
        }
    }
}

.

$ comm file1 file2 | awk -f tst.awk
YAL002W YAL004W YAL008W
YAL003W YAL005C
        YAL011W

但是当然，您可以直接跳过对commawk 的调用并立即使用：

$ cat tst.awk
BEGIN { FS=OFS="\t" }
NR==FNR {
    file1[$0]
    next
}
{
    if ($0 in file1) {
        colNr = 3
        delete file1[$0]
    }
    else {
        colNr = 2
    }
    rowNr = ++rowNrs[colNr]
    val[rowNr,colNr] = $0
}
END {
    for (v in file1) {
        colNr = 1
        rowNr = ++rowNrs[colNr]
        val[rowNr,colNr] = v
    }

    numRows = (rowNrs[1] > rowNrs[2] ? rowNrs[1] : rowNrs[2])
    numRows = (numRows   > rowNrs[3] ? numRows   : rowNrs[3])
    numCols = 3
    for (rowNr=1; rowNr<=numRows; rowNr++) {
        for (colNr=1; colNr<=numCols; colNr++) {
            printf "%s%s", val[rowNr,colNr], (colNr<numCols ? OFS : ORS)
        }
    }
}

.

$ awk -f tst.awk file1 file2
YAL002W YAL004W YAL008W
YAL003W YAL005C
        YAL011W
于 2018-04-05T21:56:46.123 回答
1

对于更多的踢，一个非 awk 的答案

comm file1 file2 | ruby -e '
    data = Array.new(3) {Array.new}
    readlines.each {|line| 
        fields = line.chomp.split("\t")
        data[fields.length - 1] << fields[-1]
    }
    m = data.map(&:length).max
    data.collect {|lst| (lst + [""] * m).first(m)}   # pad shorter lists
        .transpose
        .each {|row| puts row.join("\t")}
'

YAL002W YAL004W YAL008W
YAL003W YAL005C 
        YAL011W
于 2018-04-05T23:26:21.070 回答
1

对于踢，实施没有comm.

gawk '
    NR == FNR {file1[$0]; next}
    $0 in file1 {common[$0]; delete file1[$0]; next}
    {file2[$0]}
    END {
        PROCINFO["sorted_in"] = "@ind_str_asc"
        c=0; for (e in file1)  v[1,++c] = e; max = c
        c=0; for (e in file2)  v[2,++c] = e; if (c > max) max = c
        c=0; for (e in common) v[3,++c] = e; if (c > max) max = c
        for (i=1; i<=max; i++)
            printf "%s\t%s\t%s\n", v[1,i], v[2,i], v[3,i]
    }
' file1 file2

YAL002W YAL004W YAL008W
YAL003W YAL005C 
    YAL011W

需要 GNU awk 才能使用 PROCINFO。

于 2018-04-05T22:07:26.877 回答
0

使用awkTAB 作为字段分隔符。找到第一个填写的字段，并将其添加到多维数组的相应列中。为每一列使用单独的计数器，以便填写该数组中的下一行。

awk -F'\t' 'BEGIN {col1=0; col2=0; col3=0; max=0; SUBSEP="\t"}
            { if (!out[max]) {out[max,1] = ""; out[max,2] = ""; out[max,3] = ""} }
            length($1) { out[col1, 1] = $1; if(col1 > max) max = col1++; next }
            length($2) { out[col2, 2] = $2; if(col2 > max) max = col2++; next }
            length($3) { out[col3, 3] = $3; if(col3 > max) max = col3++;  }
            END { for (i = 0; i < max; i++) { print(out[i]; }'
于 2018-04-05T22:01:59.520 回答
0

对于comm输出，列数是固定的，这里有一个量身定制的解决方案

$ awk 'BEGIN {FS=OFS="\t"}
             {for(i=1;i<=3;i++) 
                if($i) {a[i,++c[i]]=$i; if(max<c[i]) max=c[i]}} 
       END   {for(i=1;i<=max;i++) print a[1,i],a[2,i],a[3,i]}' file

YAL002W YAL004W YAL008W
YAL003W YAL005C
        YAL011W
于 2018-04-05T22:04:22.047 回答