3

我想从我的 PLC 中导出一些数据，方法是将其写入文本文件并将其保存到 USB 记忆棒中。我设法创建了文本文件，但我不能写任何东西。

我在以下代码中使用来自 TwinCAT 标准库的函数：

PROGRAM P_WriteFile
VAR
    nStateP         :   INT :=  1;
    fbOpenFile      :   FB_FileOpen;    // open or create file
    fbWriteFile     :   FB_FilePuts;    // write to file
    fbCloseFile     :   FB_FileClose;   // Close file

    sPath           :   STRING  :=  '\Hard Disk2\foobar.txt';    // target path
    sAmsNetID       :   STRING  := '1.23.34.456.1.1';
    sOutput         :   STRING  :=  'foo';

    bDone           :   BOOL;
END_VAR

CASE nStateP OF
1:
// open/create file
    fbOpenFile(sNetId := sAmsNetID, sPathName := sPath, nMode := 2, bExecute := TRUE, tTimeout := INT_TO_TIME(200), bBusy =>, bError => , nErrId =>, hFile => );
    IF fbOpenFile.bBusy THEN
        nStateP :=  2;
    END_IF
2:
    // write to file
    IF NOT fbOpenFile.bError THEN
        fbWriteFile(sNetId := sAmsNetID, hFile := fbOpenFile.hFile, sLine := sOutput, bExecute := TRUE, tTimeout := INT_TO_TIME(200), bBusy =>, bError =>, nErrId =>);
        fbOpenFile(bExecute := FALSE);
    END_IF  
    IF fbWriteFile.bBusy THEN
        nStateP :=  3;
    END_IF

3:
    // Close file
    IF NOT fbWriteFile.bBusy AND NOT fbWriteFile.bError THEN
        fbCloseFile(sNetId := sAmsNetID, hFile := fbOpenFile.hFile, bExecute := TRUE, tTimeout := INT_TO_TIME(200), bBusy =>, bError =>, nErrId =>);
    END_IF

    IF fbWriteFile.bBusy THEN
        nStateP :=  4;
    END_IF

4:
    IF NOT fbCloseFile.bBusy AND NOT fbCloseFile.bError THEN
        bDone   :=  TRUE;
        nStateP :=  1;
    ELSE
        bDone   :=  FALSE;
    END_IF
END_CASE

程序进入所有状态，但结果是一个空的文本文件，我无法在控制面板上打开它。("访问 \Hard Disk2\foobar.txt 时发生共享冲突")

此外，函数的 bBusy - 变量（例如 FB_FileOpen.bBusy）不会变回“FALSE”。

如果有人可以帮助我，那就太好了！谢谢 ：）

4

2 回答 2

5

通常：busy-flag 告诉您的是功能块当前正忙于执行您请求 FB 执行的操作。这意味着您不应该在状态机忙碌时更改它的状态，反之亦然。在进行下一步之前，您还应该检查操作是否成功（通过查看 bError 标志）。只要您正在调用的功能块正忙 (bBusy = true)，您就可以在 bExecute-flag 设置为低的情况下调用功能块。我通常做的是将其设置为两个单独的打开阶段，例如：

某种伪代码：

Step1_Open:
  FBOPENFILE(bExecute=TRUE)...
   GOTO STEP2_OPEN

Step2_Open:
  FBOPENFILE(bExecute=FALSE)
  IF NOT FBOPENFILE.bBusy AND NOT FBOPENFILE.bError THEN
     GOTO Step3_StartWrite
  END_IF

Step3_StartWrite
  FBWRITEFILE(bExecute=TRUE)
  GOTO STEP4_WRITEFILE

Step4_Writefile:
  FBWRITEFILEFILE(bExecute=FALSE)
  IF NOT FBWRITEFILEFILE.bBusy AND NOT FBWRITEFILEFILE.bError THEN
     NEXT STEP
  END_IF

……等等……

因此，在您的示例中，您的第 2 阶段非常关键。在写入完成之前，您不应该关闭文件，一旦 bBusy 为假，它就会关闭。你基本上在做的是在文件还在写的时候关闭它！此外，您可以删除“fbOpenFile(bExecute := FALSE);” 在此阶段，因为一旦（成功）打开文件并拥有文件句柄，您就不需要再调用此功能块了。

其他想法：

sAmsNetId 是您计算机的本地计算机吗？如果是本地的，我认为您不需要提供。

我已经编写了自己的文件编写器，我已经使用了很长时间并且正在工作。它的代码是：

fbRisingEdge(CLK := bExecute);
CASE eFileWriteStep OF
    E_FileWriteStep.IDLE :
        IF fbRisingEdge.Q THEN
            nFileHandle := 0;
            bBusy := TRUE;
            eFileWriteStep := E_FileWriteStep.OPEN;
            nFileWriteSubStep := 0;
        END_IF

    E_FileWriteStep.OPEN :
        CASE nFileWriteSubStep OF
            0 :
                fbFileOpen(sPathName := sPathName, bExecute := FALSE);
                fbFileOpen(sPathName := sPathName, bExecute := TRUE);
                nFileWriteSubStep := nFileWriteSubStep + 1;
            1 :
                fbFileOpen(bExecute := FALSE);
                IF NOT fbFileOpen.bBusy THEN
                    IF fbFileOpen.bError THEN
                        bError := TRUE;
                        eFileWriteStep := E_FileWriteStep.CLEAN;
                        nFileWriteSubStep := 0;
                    ELSE
                        nFileHandle := fbFileOpen.hFile;
                        eFileWriteStep := E_FileWriteStep.WRITE;
                        nFileWriteSubStep := 0;
                    END_IF
                END_IF
            END_CASE

    E_FileWriteStep.WRITE :
        CASE nFileWriteSubStep OF
            0 :
                fbFileWrite(bExecute := FALSE);
                fbFileWrite(hFile := nFileHandle,
                            pWriteBuff := aFileData,
                            cbWriteLen := UDINT_TO_UINT(UPPER_BOUND(aFileData, 1)),
                            bExecute := TRUE);
                nFileWriteSubStep := nFileWriteSubStep + 1;
            1 :
                fbFileWrite(bExecute := FALSE);
                IF NOT fbFileWrite.bBusy THEN
                    IF fbFileWrite.bError THEN
                        bError := TRUE;
                        eFileWriteStep := E_FileWriteStep.CLEAN;
                    ELSE
                        eFileWriteStep := E_FileWriteStep.CLEAN;
                        nBytesWritten := fbFileWrite.cbWrite;
                    END_IF
                nFileWriteSubStep := 0;
                END_IF
        END_CASE

    E_FileWriteStep.CLOSE :
        CASE nFileWriteSubStep OF
            0 :
                fbFileClose(bExecute := FALSE);
                fbFileClose(hFile := nFileHandle, bExecute := TRUE);
                nFileWriteSubStep := 1;
            1 :
                fbFileClose(bExecute := FALSE);
                IF NOT fbFileClose.bBusy THEN
                    IF fbFileClose.bError THEN
                        bError := TRUE;
                    END_IF
                eFileWriteStep := E_FileWriteStep.CLEAN;
                nFileHandle := 0;
                nFileWriteSubStep := 0;
                END_IF
        END_CASE

    E_FileWriteStep.CLEAN :
        IF nFileHandle <> 0 THEN
            eFileWriteStep := E_FileWriteStep.CLOSE;
            nFileWriteSubStep := 0;
        ELSE
            eFileWriteStep := E_FileWriteStep.IDLE;
            bBusy := FALSE;
        END_IF
END_CASE

在开始时通过上升沿激活功能块。要写入的数据由字节数组 (aFileData) 提供。在此状态机的末尾，您还有一些清理代码以及最终的错误处理。在这段代码中，您还可以看到在继续下一步之前我如何确保上一步成功。

祝你好运！

于 2018-03-22T17:39:54.503 回答
0

您程序中的主要问题是您只调用了一次功能块，就好像它们是普通功能一样。您必须连续调用功能块，并检查它们何时完成其特定功能。
当连续调用它们时，您应该首先等待 Busy 标志变高，然后等待它变低（并且没有错误）。如果您有两种等待情况的状态并在两种状态下调用功能块，这将是最简单的。
请记住，这些文件操作功能块与 Windows 系统一起工作，可能需要一些时间才能完成它们的工作。

顺便说一句，如果您将“NOT fbOpenFile.bBusy”标准添加到状态 2 中的第一个 IF，那么您的代码示例实际上可能会起作用。但是，如果您使用两种状态来启动和完成每个状态，程序会更容易阅读/调试FB的。

于 2018-03-23T12:17:18.537 回答