4

我正在使用 Gradle 构建一个 java 应用程序，我想将最终的 jar 文件传输到另一个文件夹中。我想复制每个上的文件build并删除每个上的文件clean。

不幸的是，我只能完成其中一项任务，而不能同时完成。当我copyJar激活任务时，它会成功复制 JAR。当我包含clean任务时，不会复制 JAR，如果那里有文件，则会将其删除。好像有一些任务调用clean.

有什么解决办法吗？

plugins {
    id 'java'
    id 'base'
    id 'com.github.johnrengelman.shadow' version '2.0.2'
}
dependencies {
    compile project(":core")
    compile project("fs-api-reader")
    compile project(":common")
}

task copyJar(type: Copy) {
    copy {
        from "build/libs/${rootProject.name}.jar"
        into "myApp-app"
    }
}

clean {
    file("myApp-app/${rootProject.name}.jar").delete()
}

copyJar.dependsOn(build)

allprojects {
    apply plugin: 'java'
    apply plugin: 'base'

    repositories {
        mavenCentral()
    }

    dependencies {
        testCompile 'junit:junit:4.12'
        compile 'org.slf4j:slf4j-api:1.7.12'
        testCompile group: 'ch.qos.logback', name: 'logback-classic', version: '0.9.26'
    }

    sourceSets {
        test {
            java.srcDir 'src/test/java'
        }
        integration {
            java.srcDir 'src/test/integration/java'
            resources.srcDir 'src/test/resources'
            compileClasspath += main.output + test.output
            runtimeClasspath += main.output + test.output
        }
    }

    configurations {
        integrationCompile.extendsFrom testCompile
        integrationRuntime.extendsFrom testRuntime
    }

    task integration(type: Test, description: 'Runs the integration tests.', group: 'Verification') {
        testClassesDirs = sourceSets.integration.output.classesDirs
        classpath = sourceSets.integration.runtimeClasspath
    }
    test {
        reports.html.enabled = true
    }
    clean {
        file('out').deleteDir()    
    }

}
4

2 回答 2

5 
clean {
    file("myApp-app/${rootProject.name}.jar").delete()
}

这将在每次评估时删除文件，这不是您想要的。将其更改为：

clean {
    delete "myApp-app/${rootProject.name}.jar"
}

这将配置清理任务并添加要在执行时删除的 JAR。

于 2018-03-21T17:46:10.387 回答
3

@nickb 对clean任务的看法是正确的，但您还需要修复您的copyJar任务。该copy { ... }方法在配置阶段调用，因此每次调用 gradle。简单去掉方法，使用Copy任务类型的配置方法：

task copyJar(type: Copy) {
    from "build/libs/${rootProject.name}.jar"
    into "myApp-app"
}

同样的问题也适用于闭包中的clean任务。allprojects只需替换file('out').deleteDir()为delete 'out'. 查看文档中有关配置阶段和执行阶段之间差异的更多信息。

于 2018-03-21T19:26:16.223 回答