3

我正在尝试从 Wikidata 的 SPARQL 端点获取多种语言的标签。此处给出了以下示例：

SELECT ?country ?country_EN ?country_DE ?country_FR
   WHERE {
     ?country wdt:P31 wd:Q185441. # member state of the European Union
     SERVICE wikibase:label { bd:serviceParam wikibase:language "en".
            ?country rdfs:label ?country_EN.
     }
     SERVICE wikibase:label { bd:serviceParam wikibase:language "de".
            ?country rdfs:label ?country_DE.
     }
     SERVICE wikibase:label { bd:serviceParam wikibase:language "fr".
            ?country rdfs:label ?country_FR.
     }
}

在这里试试

但是，这会返回以下错误：

未知错误：任何组中只能有一个“最后运行”加入

有没有一种解决方案可以用一种以上的语言获取标签？

4

2 回答 2

5

rdfs:label无需服务即可直接使用wikibase:label：

SELECT ?country ?country_en ?country_de ?country_fr
   WHERE {
     ?country wdt:P31 wd:Q185441. # member state of the European Union
     OPTIONAL {?country rdfs:label ?country_en filter (lang(?country_en) = "en")}.
     OPTIONAL {?country rdfs:label ?country_de filter (lang(?country_de) = "de")}.
     OPTIONAL {?country rdfs:label ?country_fr filter (lang(?country_fr) = "fr")}.
}

在这里试试

于 2018-03-05T20:50:19.240 回答
5

除非有另一个显式提示，否则标签服务优化器会向标签服务添加hint:Prior hint:runLast true 提示：

LabelServiceUtils.getLabelServiceNodes(op).forEach(service -> {
    if (service.getProperty(QueryHints.RUN_LAST)  != null ||
        service.getProperty(QueryHints.RUN_FIRST) != null) {
        return;
    }
    service.setProperty(QueryHints.RUN_LAST, TRUE);
});

应该只添加hint:Prior hint:runLast false到第一个之后的所有标签服务调用。

您的查询应该是：

SELECT ?country ?country_EN ?country_DE ?country_FR
   WHERE {
     ?country wdt:P463 wd:Q458. # member state of the European Union
     SERVICE wikibase:label { bd:serviceParam wikibase:language "en".
            ?country rdfs:label ?country_EN.
     }
     SERVICE wikibase:label { bd:serviceParam wikibase:language "de".
            ?country rdfs:label ?country_DE.
     } hint:Prior hint:runLast false.
     SERVICE wikibase:label { bd:serviceParam wikibase:language "fr".
            ?country rdfs:label ?country_FR.
     } hint:Prior hint:runLast false.
}

尝试一下！

显然，可以使用常规的 SPARQL 获取多种语言的标签，而且不那么冗长。然而，标签服务提供语言回退，包括 Q-id 的最后一个。

来源：

于 2018-03-06T11:03:25.873 回答