2

给定以下类型：

type Trip = {
  From: string
  To: string
}

type Passenger = {
   Name: string
   LastName: string
   Trips: Trip list
}

我正在使用以下构建器：

type PassengerBuilder() = 
  member this.Yield(_) = Passenger.Empty

  [<CustomOperation("lastName")>]
  member __.LastName(r: Passenger, lastName: string) = 
    { r with LastName = lastName }

  [<CustomOperation("name")>]
  member __.Name(r: Passenger, name: string) = 
    { r with Name = name }

type TripBuilder() = 
  member __.Yield(_) = Trip.Empty

  [<CustomOperation("from")>]
  member __.From(t: Trip, f: string) = 
    { t with From = f }

  // ... and so on

创建类型的记录Passenger，如下所示：

let passenger = PassengerBuilder()
let trip = TripBuilder()

let p = passenger {
  name "john"
  lastName "doe"
}

let t = trip {
  from "Buenos Aires"
  to "Madrid"
}

我将如何组合 thePassengerBuilder和 theTripBuilder以便我可以实现这种用法？

let p = passenger {
    name "John"
    lastName "Doe"
    trip from "Buenos Aires" to "Madrid"
    trip from "Madrid" to "Paris"
}

返回Passenger如下记录：

{
   LastName = "Doe"
   Name = "John"
   Trips = [
       { From = "Buenos Aires"; To = "Madrid" }
       { From = "Madrid"; To = "Paris" }
   ]
}
4

2 回答 2

5

您有什么理由要使用计算表达式构建器吗？根据您的示例，您看起来不像在编写任何类似计算的东西。如果你只是想要一个很好的 DSL 来创建旅行，那么你可以很容易地定义一些让你编写的东西：

let p = 
  passenger [
    name "John"
    lastName "Doe"
    trip from "Buenos Aires" towards "Madrid"
    trip from "Madrid" towards "Paris"
  ]

这几乎正​​是您所要求的，除了它使用[ .. ]而不是{ .. }（因为它创建了一个转换列表）。我也重命名为to，towards因为to它是一个关键字，你不能重新定义它。

这方面的代码很容易编写和遵循：

let passenger ops = 
  ops |> List.fold (fun ps op -> op ps)
    { Name = ""; LastName = ""; Trips = [] } 

let trip op1 arg1 op2 arg2 ps = 
  let trip = 
    [op1 arg1; op2 arg2] |> List.fold (fun tr op -> op tr)
      { From = ""; To = "" }
  { ps with Trips = trip :: ps.Trips }

let name n ps = { ps with Name = n }
let lastName n ps = { ps with LastName = n }
let from n tp = { tp with From = n }
let towards n tp = { tp with To = n }

也就是说，我仍然会考虑使用普通的 F# 记录语法——它并不比这更难看。上述版本的一个缺点是您可以创建具有空姓名和姓氏的乘客，这是 F# 阻止您做的一件事！

于 2018-03-06T20:41:43.717 回答
4

我不确定这是你想要的，但没有什么能阻止你创建一个名为trip你的新操作PassengerBuilder：

  [<CustomOperation("trip")>]
  member __.Trip(r: Passenger, t: Trip) = 
    { r with Trips = t :: r.Trips }

然后像这样使用它：

let p = passenger {
    name "John"
    lastName "Doe"
    trip (trip { from "Buenos Aires"; to "Madrid" })
    trip (trip { from "Madrid"; to "Paris" })
}

可以说，您甚至可以通过TripBuilder完全删除以下内容来使其更清洁：

let p = passenger {
    name "John"
    lastName "Doe"
    trip { From = "Buenos Aires"; To = "Madrid" }
    trip { From = "Madrid"; To = "Paris" }
}

如果这不是您想要的，请说明如何。也就是说，此解决方案中缺少什么或多余的内容。

于 2018-03-05T19:17:01.040 回答