2

如果我的 XSL 文件中有以下元素：

<xsl:value-of select="replace(lower-case(@name), '_([a-z0-9])', '$1')" />

例如，从“get_polygene_lubricants”中可以生成“getpolygenelubricants”。

我想要做的是用字母的大写变体替换“_”之后的第一个字母。我用谷歌搜索，阅读文档，但我无法在 XSLT 中找到任何解决方案来进行简单的替换。

也许有人知道在 XSLT 2.0 中是否可行？

4

3 回答 3

6

已编辑：根据原始海报的说明，由下划线分隔的第一个字符串不应将其首字母大写。

此解决方案不使用递归，应该更有效。

这是新的解决方案：

string-join(
            (for  $i in 1 to count(tokenize(.,'_')),
                  $s in tokenize(.,'_')[$i],
                  $fl in substring($s,1,1),
                  $tail in substring($s,2)
               return
                  if($i eq 1)
                   then $s
                   else concat(upper-case($fl), $tail)
             ),
                        ''
           )

结果现在完全符合要求：

underLinedString

下面是旧的解决方案。

replace() 函数假设你有一个固定的替换——因此它不是解决这个问题的最佳工具。

这是一个单行 XPath 2.0 解决方案（它当然可以用作 XSLT 2.0 转换的一部分:)）：

string-join(
            (for $s in tokenize(.,'_'),
                 $fl in substring($s,1,1),
                 $tail in substring($s,2)
               return
                 concat(upper-case($fl), $tail)
             ),
            ''
           )

当我们在这样的 XSLT 2.0 转换中使用上述表达式时：

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xsl:template match="/">
     <xsl:sequence select=
      "string-join(
                   (for $s in tokenize(.,'_'),
                    $fl in substring($s,1,1),
                    $tail in substring($s,2)
                  return
                concat(upper-case($fl), $tail)
                   ),
                   ''
                  )

      "/>
    </xsl:template>
</xsl:stylesheet>

并将其应用于此 XML 文档：

<t>under_lined_String</t>

the wanted result is produced:

UnderLinedString
于 2009-01-28T21:09:43.020 回答
1

您可以使用模板执行此操作，递归调用自身以遍历字符串中的字符。这个模板应该有一个位置参数，从 1 开始，每次调用模板都会增加。找到 '_' 时，使用 translate(1.0) 或 upper-case(2.0) 将下一个字符转换为大写

于 2009-01-28T20:47:07.903 回答
0

Although already answered, here's my solution:

<xsl:template name="camel-case">
  <xsl:param name='value'/>
  <xsl:analyze-string regex="^(.)" select="$value">
    <xsl:matching-substring><xsl:value-of select="upper-case(regex-group(1))"/></xsl:matching-substring>
    <xsl:non-matching-substring>
      <xsl:analyze-string regex="[_-](.)" select=".">
        <xsl:matching-substring><xsl:value-of select="upper-case(regex-group(1))"/></xsl:matching-substring>
        <xsl:non-matching-substring><xsl:value-of select="."/></xsl:non-matching-substring>
      </xsl:analyze-string>
    </xsl:non-matching-substring>          
  </xsl:analyze-string>
</xsl:template>

Use:

<xsl:call-template name="camel-case">
  <xsl:with-param name='value' select="."/>
</xsl:call-template>
于 2011-08-01T03:53:36.877 回答