0

我是fortran的新手。我正在尝试使用 fortran 95 以 CGNS 格式编写 Flow 解决方案。我编写了 fortran 代码并为 python 创建了这个 fortran 代码的库。我想使用这个库来编写*.npy格式*.cgns格式的网格和流数据。我的fortran代码片段如下

subroutine un_2d_tr(filename, zoneName)
 implicit none
 include 'cgnslib_f.h'

 character(*) fileName, zoneName 
 integer :: ier, cellDim, physDim, nelem_start, nelem_end, nbdyelem   
 integer :: iFile, iB, iCoordX, iCoordY, iSection, iFlow, iu, iv 
 integer, dimension(1,3) :: isize  
 character(len=32) :: basename, solname

 ! --------------------------------------------------------------------  
 ! open CGNS file to write OR edit and create/read base  
 basename = 'Base'  

 ! In 2D unstr.  
 cellDim=2
 physDim=2

 call cg_open_f(fileName,cg_mode_write,iFile,ier)   
 call check_cg_error_f(ier)

 ! write base    
 call cg_base_write_f(iFile,basename,cellDim,physDim, iB,ier)    
 call check_cg_error_f(ier)
 ...

我继续脚本将网格和流速写入 cgns 文件。使用 to write 打开新文件没有错误cg_open_f()（错误状态 ier 为 0）。但是，当我尝试在打开的文件中使用cg_write_f()或（用于编写基本流程）编写内容时，出现以下错误cg_base_write_f()

CGNS file 0 is not open

如果需要，我可以发布完整的 fortran 子例程。有没有人对如何纠正这个错误有任何建议？这可能是我的 linux 发行版的问题吗？如果有帮助，我使用的是 Ubuntu 17.10。我已包括check_cg_error_f()以下内容。

subroutine check_cg_error_f(ier)

 implicit none
 include 'cgnslib_f.h'
 integer ier

 if (ier .ne. CG_OK) then
   call cg_error_exit_f
 endif

end

我用来搭建cgns库的cmake文件如下

BUILD_CGNSTOOLS                  OFF
CGNS_BUILD_SHARED                ON
CGNS_USE_SHARED                  ON
CMAKE_BUILD_TYPE                 Release
CMAKE_INSTALL_PREFIX             /home/adhitya/.local/cgns/3.1.4
ENABLE_64BIT                     ON
ENABLE_FORTRAN                   ON
ENABLE_HDF5                      ON
ENABLE_SCOPING                   OFF
ENABLE_TESTS                     OFF
FORTRAN_NAMING                   LOWERCASE_
HDF5_INCLUDE_PATH                /home/adhitya/.local/hdf5/1.8.16/include
HDF5_LIBRARY                     /home/adhitya/.local/hdf5/1.8.16/lib/libhdf5.so
HDF5_NEED_MPI                    OFF
HDF5_NEED_SZIP                   ON
HDF5_NEED_ZLIB                   ON
SZIP_LIBRARY                     /home/adhitya/.local/szip/lib/libsz.so
ZLIB_LIBRARY                     /home/adhitya/.local/zlib/lib/libz.so

cmake 构建版本 3.3.1

CGNS_BUILD_CGNSTOOLS             OFF                                          
CGNS_BUILD_SHARED                ON                                           
CGNS_BUILD_TESTING               OFF                                          
CGNS_ENABLE_64BIT                ON                                           
CGNS_ENABLE_BASE_SCOPE           OFF                                          
CGNS_ENABLE_FORTRAN              ON                                           
CGNS_ENABLE_HDF5                 ON                                           
CGNS_ENABLE_MEM_DEBUG            OFF                                          
CGNS_ENABLE_SCOPING              OFF                                          
CGNS_ENABLE_TESTS                OFF                                          
CGNS_USE_SHARED                  ON                                           
CMAKE_BUILD_TYPE                 Release                                      
CMAKE_INSTALL_PREFIX             /home/adhitya/.local/cgns/3.3.1              
HDF5_C_LIBRARY_dl                /usr/lib/x86_64-linux-gnu/libdl.so           
HDF5_C_LIBRARY_hdf5              /home/adhitya/.local/hdf5/lib/libhdf5.so     
HDF5_C_LIBRARY_m                 /usr/lib/x86_64-linux-gnu/libm.so            
HDF5_C_LIBRARY_sz                /usr/lib/x86_64-linux-gnu/libsz.so 
HDF5_C_LIBRARY_z                 /usr/lib/x86_64-linux-gnu/libz.so            
HDF5_DIR                         HDF5_DIR-NOTFOUND                            
HDF5_NEED_MPI                    OFF                                          
HDF5_NEED_SZIP                   ON                                           
HDF5_NEED_ZLIB                   ON                                           
SZIP_LIBRARY                     /home/adhitya/.local/szip/lib/libsz.so       
ZLIB_LIBRARY                     /usr/lib/x86_64-linux-gnu/libz.so
4

2 回答 2

1

我不完全知道你的错误是什么。但是我怀疑这是某种类型不匹配。我强烈推荐 use cgns而不是include. 现在是 2018 年！让编译器告诉您是否正确调用了例程。

CGNS测试程序

Fortran

program test_cgns

    use, intrinsic :: iso_fortran_env, only: error_unit
    use cgns

    implicit none

    integer                             :: ierr      ! error status
    integer                             :: fid       ! file id
    integer                             :: bid       ! base id
    character(len=256)                  :: filename  ! file name
    character(len=256), parameter       :: base ='Base'
    integer,            parameter       :: dims(3) = [10, 10, 10]
    integer                             :: ndims

    call get_command_argument(1, filename)
    if (len_trim(filename) == 0) then
        write(error_unit, *) 'ERROR: Must supply a filename.'
    end if

    call cg_set_file_type_f(CG_FILE_HDF5, ierr)
    if (ierr /= CG_OK) then
        write(error_unit, *) 'Unable to set file type to HDF5'
        call cg_error_print_f
        stop
    end if

    call cg_open_f(filename, CG_MODE_WRITE, fid, ierr)
    if (ierr /= CG_OK) then
        write(error_unit, *) 'Unable to open: ' // trim(filename)
        call cg_error_print_f
        stop
    end if

    ndims = size(dims)    
    call cg_base_write_f(fid, base, ndims, ndims, bid, ierr)
    if (ierr /= CG_OK) then
        write(error_unit, *) 'Unable to create base: ' // trim(base)
        call cg_error_print_f
        stop
    end if

    call cg_close_f(fid, ierr)
    if (ierr /= CG_OK) then
        write(error_unit, *) 'Unable to close data file'
        call cg_error_print_f
    end if

end program test_cgns

C

#include <stdlib.h>
#include <stdio.h>
#include <err.h>
#include <cgnslib.h>

int
main(int argc, char **argv)
{
    int fid = 0;
    int bid = 0;
    int ndims = 3;
    char *filename = NULL;
    char *base = "Base";

    if (argc != 2) {
        errx(EXIT_FAILURE, "Must supply a filename");
    }
    filename = argv[1];

    if (cg_set_file_type(CG_FILE_HDF5)) {
        warnx("Unable to set file type to HDF5");
        cg_error_exit();
    }

    if (cg_open(filename, CG_MODE_WRITE, &fid)) {
        warnx("Unable to open file: %s", filename);
        cg_error_exit();
    }

    if (cg_base_write(fid, base, ndims, ndims, &bid)) {
        warnx("Unable to create base: %s", base);
        cg_error_exit();
    }

    if (cg_close(fid)) {
        warnx("Unable to close data file");
        cg_error_exit();
    }

    return(EXIT_SUCCESS);
}

然后编译它，（请注意，您可能必须添加 -I 和 -L 标志来告诉编译器cgns.mod和在哪里libcgns.so）：

$ gfortran -o test_cgns test_cgns.f90 -lcgns

或者

$ gcc -o test_cgns test_cgns.c -lcgns

运行测试并查看输出文件：

$ ./test_cgns foo.h5
$ echo $?
 0
$ h5dump foo.h5
HDF5 "foo.h5" {
GROUP "/" {
   ATTRIBUTE "label" {
      DATATYPE  H5T_STRING {
         STRSIZE 33;
         STRPAD H5T_STR_NULLTERM;
         CSET H5T_CSET_ASCII;
         CTYPE H5T_C_S1;
      }
      DATASPACE  SCALAR
      DATA {
      (0): "Root Node of HDF5 File"
      }
   }
 ....

你能编译和运行这个简单的测试程序吗？

建设CGNS

我刚刚获取了源代码并在另一个集群上进行了安装。请注意，我使用的是英特尔编译器套件而不是 GCC。

 CGNS_BUILD_CGNSTOOLS             OFF                                                                                                                     
 CGNS_BUILD_SHARED                ON                                                                                                                      
 CGNS_BUILD_TESTING               OFF                                                                                                                     
 CGNS_ENABLE_64BIT                ON                                                                                                                      
 CGNS_ENABLE_BASE_SCOPE           OFF                                                                                                                     
 CGNS_ENABLE_FORTRAN              ON                                                                                                                      
 CGNS_ENABLE_HDF5                 ON                                                                                                                      
 CGNS_ENABLE_MEM_DEBUG            OFF                                                                                                                     
 CGNS_ENABLE_SCOPING              OFF                                                                                                                     
 CGNS_ENABLE_TESTS                OFF                                                                                                                     
 CGNS_USE_SHARED                  ON                                                                                                                      
 CMAKE_BUILD_TYPE                 Release                                                                                                                 
 CMAKE_INSTALL_PREFIX             /home/tibr1099/cgns/3.3.1                                                                                               
 HDF5_C_LIBRARY_dl                /usr/lib64/libdl.so                                                                                                     
 HDF5_C_LIBRARY_hdf5              /curc/sw/hdf5/1.8.18/intel/17.4/lib/libhdf5.so                                                                          
 HDF5_C_LIBRARY_m                 /usr/lib64/libm.so                                                                                                      
 HDF5_C_LIBRARY_sz                /curc/sw/szip/2.1.1/intel/17.4/lib/libsz.so                                                                             
 HDF5_C_LIBRARY_z                 /curc/sw/zlib/1.2.11/intel/17.4/lib/libz.so                                                                             
 HDF5_NEED_MPI                    OFF                                                                                                                     
 HDF5_NEED_SZIP                   OFF                                                                                                                     
 HDF5_NEED_ZLIB                   OFF

接下来是通常的make install，然后在安装的包含目录中查找：

$ ls ~/cgns/3.3.1/include/
cgns.mod  cgnsBuild.defs  cgns_io.h  cgnsconfig.h  cgnslib.h  cgnstypes.h  cgnstypes_f.h  cgnstypes_f03.h  cgnswin_f.h

如果没有看到您的构建日志，我敢说删除您的安装并重新开始。也不3.1.4是最新的稳定版。抢3.3.1怎么样。

于 2018-01-26T15:36:37.557 回答
0

我不熟悉 CGNS，但作为第一次检查，我建议在执行 cg_open_f() 后验证是否为 iFile 变量分配了一个合理的值。只是另一个想法，您是否要在预先存在的文件上写入？

于 2018-01-26T09:41:29.617 回答