83

真正的现代正则表达式实际上可以识别哪一类语言?

每当存在带有反向引用(例如(.*)_\1)的无限长度捕获组时,正则表达式现在正在匹配非常规语言。但这本身并不足以匹配诸如S ::= '(' S ')' | ε匹配括号对的上下文无关语言之类的东西。

递归正则表达式(对我来说是新的,但我确信存在于 Perl 和 PCRE 中)似乎至少可以识别大多数 CFL。

有没有人做过或读过这方面的研究?这些“现代”正则表达式的局限性是什么?他们对 LL 或 LR 语法的识别比 CFG 严格多还是严格少?或者是否存在两种语言都可以被正则表达式识别但不能被 CFG 识别,反之亦然

相关论文的链接将不胜感激。

4

1 回答 1

108

模式递归

使用递归模式,您就有了一种递归下降匹配的形式。

这对于各种问题都很好,但是一旦你想真正进行递归下降解析,你需要在这里和那里插入捕获组,并且以这种方式恢复完整的解析结构很尴尬。Damian Conway 的用于 Perl 的Regexp::Grammars模块将简单模式转换为等效模式,该模式自动将所有命名捕获转换为递归数据结构,从而更容易检索已解析的结构。在这篇文章的最后,我有一个比较这两种方法的示例。

递归限制

问题是递归模式可以匹配什么样的语法。好吧,它们肯定是递归下降类型匹配器。唯一想到的是递归模式不能处理左递归这对您可以应用它们的语法种类施加了限制。有时您可以重新排序您的产品以消除左递归。

顺便说一句,PCRE 和 Perl 在允许您如何表达递归方面略有不同。请参阅pcrepattern 手册页中有关“递归模式”和“与 Perl 的递归差异”的部分。例如:Perl 可以处理^(.|(.)(?1)\2)$PCRE 需要的地方^((.)(?1)\2|.)$

递归演示

对递归模式的需求出人意料地频繁出现。一个受欢迎的示例是当您需要匹配可以嵌套的内容时,例如平衡括号、引号,甚至 HTML/XML 标记。这是平衡括号的匹配:

\((?:[^()]*+|(?0))*\)

由于其紧凑的性质,我发现阅读起来更棘手。这很容易通过/x模式解决,使空白不再重要:

\( (?: [^()] *+ | (?0) )* \)

再说一次,由于我们使用括号进行递归,一个更清晰的例子是匹配嵌套的单引号:

‘ (?: [^‘’] *+ | (?0) )* ’

您可能希望匹配的另一个递归定义的事物是回文。这个简单的模式在 Perl 中有效:

^((.)(?1)\2|.?)$

您可以使用以下方式在大多数系统上进行测试:

$ perl -nle 'print if /^((.)(?1)\2|.?)$/i' /usr/share/dict/words

请注意,PCRE 的递归实现需要更精细

^(?:((.)(?1)\2|)|((.)(?3)\4|.))

这是因为 PCRE 递归如何工作的限制。

正确解析

对我来说,上面的例子大多是玩具火柴,真的不是那么有趣。当它变得有趣时,就是当你有一个真正的语法时,你正在尝试解析。例如,RFC 5322 相当详尽地定义了一个邮件地址。这是一个与之匹配的“语法”模式:

$rfc5322 = qr{

   (?(DEFINE)

     (?<address>         (?&mailbox) | (?&group))
     (?<mailbox>         (?&name_addr) | (?&addr_spec))
     (?<name_addr>       (?&display_name)? (?&angle_addr))
     (?<angle_addr>      (?&CFWS)? < (?&addr_spec) > (?&CFWS)?)
     (?<group>           (?&display_name) : (?:(?&mailbox_list) | (?&CFWS))? ; (?&CFWS)?)
     (?<display_name>    (?&phrase))
     (?<mailbox_list>    (?&mailbox) (?: , (?&mailbox))*)

     (?<addr_spec>       (?&local_part) \@ (?&domain))
     (?<local_part>      (?&dot_atom) | (?&quoted_string))
     (?<domain>          (?&dot_atom) | (?&domain_literal))
     (?<domain_literal>  (?&CFWS)? \[ (?: (?&FWS)? (?&dcontent))* (?&FWS)?
                                   \] (?&CFWS)?)
     (?<dcontent>        (?&dtext) | (?&quoted_pair))
     (?<dtext>           (?&NO_WS_CTL) | [\x21-\x5a\x5e-\x7e])

     (?<atext>           (?&ALPHA) | (?&DIGIT) | [!#\$%&'*+-/=?^_`{|}~])
     (?<atom>            (?&CFWS)? (?&atext)+ (?&CFWS)?)
     (?<dot_atom>        (?&CFWS)? (?&dot_atom_text) (?&CFWS)?)
     (?<dot_atom_text>   (?&atext)+ (?: \. (?&atext)+)*)

     (?<text>            [\x01-\x09\x0b\x0c\x0e-\x7f])
     (?<quoted_pair>     \\ (?&text))

     (?<qtext>           (?&NO_WS_CTL) | [\x21\x23-\x5b\x5d-\x7e])
     (?<qcontent>        (?&qtext) | (?&quoted_pair))
     (?<quoted_string>   (?&CFWS)? (?&DQUOTE) (?:(?&FWS)? (?&qcontent))*
                          (?&FWS)? (?&DQUOTE) (?&CFWS)?)

     (?<word>            (?&atom) | (?&quoted_string))
     (?<phrase>          (?&word)+)

     # Folding white space
     (?<FWS>             (?: (?&WSP)* (?&CRLF))? (?&WSP)+)
     (?<ctext>           (?&NO_WS_CTL) | [\x21-\x27\x2a-\x5b\x5d-\x7e])
     (?<ccontent>        (?&ctext) | (?&quoted_pair) | (?&comment))
     (?<comment>         \( (?: (?&FWS)? (?&ccontent))* (?&FWS)? \) )
     (?<CFWS>            (?: (?&FWS)? (?&comment))*
                         (?: (?:(?&FWS)? (?&comment)) | (?&FWS)))

     # No whitespace control
     (?<NO_WS_CTL>       [\x01-\x08\x0b\x0c\x0e-\x1f\x7f])

     (?<ALPHA>           [A-Za-z])
     (?<DIGIT>           [0-9])
     (?<CRLF>            \x0d \x0a)
     (?<DQUOTE>          ")
     (?<WSP>             [\x20\x09])
   )

   (?&address)

}x;

如您所见,这非常类似于 BNF。问题是它只是匹配,而不是捕获。而且你真的不想用捕获括号包围整个事情,因为这并不能告诉你哪个产品与哪个部分匹配。使用前面提到的 Regexp::Grammars 模块,我们可以。

#!/usr/bin/env perl

use strict;
use warnings;
use 5.010;
use Data::Dumper "Dumper";

my $rfc5322 = do {
    use Regexp::Grammars;    # ...the magic is lexically scoped
    qr{

    # Keep the big stick handy, just in case...
    # <debug:on>

    # Match this...
    <address>

    # As defined by these...
    <token: address>         <mailbox> | <group>
    <token: mailbox>         <name_addr> | <addr_spec>
    <token: name_addr>       <display_name>? <angle_addr>
    <token: angle_addr>      <CFWS>? \< <addr_spec> \> <CFWS>?
    <token: group>           <display_name> : (?:<mailbox_list> | <CFWS>)? ; <CFWS>?
    <token: display_name>    <phrase>
    <token: mailbox_list>    <[mailbox]> ** (,)

    <token: addr_spec>       <local_part> \@ <domain>
    <token: local_part>      <dot_atom> | <quoted_string>
    <token: domain>          <dot_atom> | <domain_literal>
    <token: domain_literal>  <CFWS>? \[ (?: <FWS>? <[dcontent]>)* <FWS>?

    <token: dcontent>        <dtext> | <quoted_pair>
    <token: dtext>           <.NO_WS_CTL> | [\x21-\x5a\x5e-\x7e]

    <token: atext>           <.ALPHA> | <.DIGIT> | [!#\$%&'*+-/=?^_`{|}~]
    <token: atom>            <.CFWS>? <.atext>+ <.CFWS>?
    <token: dot_atom>        <.CFWS>? <.dot_atom_text> <.CFWS>?
    <token: dot_atom_text>   <.atext>+ (?: \. <.atext>+)*

    <token: text>            [\x01-\x09\x0b\x0c\x0e-\x7f]
    <token: quoted_pair>     \\ <.text>

    <token: qtext>           <.NO_WS_CTL> | [\x21\x23-\x5b\x5d-\x7e]
    <token: qcontent>        <.qtext> | <.quoted_pair>
    <token: quoted_string>   <.CFWS>? <.DQUOTE> (?:<.FWS>? <.qcontent>)*
                             <.FWS>? <.DQUOTE> <.CFWS>?

    <token: word>            <.atom> | <.quoted_string>
    <token: phrase>          <.word>+

    # Folding white space
    <token: FWS>             (?: <.WSP>* <.CRLF>)? <.WSP>+
    <token: ctext>           <.NO_WS_CTL> | [\x21-\x27\x2a-\x5b\x5d-\x7e]
    <token: ccontent>        <.ctext> | <.quoted_pair> | <.comment>
    <token: comment>         \( (?: <.FWS>? <.ccontent>)* <.FWS>? \)
    <token: CFWS>            (?: <.FWS>? <.comment>)*
                             (?: (?:<.FWS>? <.comment>) | <.FWS>)

    # No whitespace control
    <token: NO_WS_CTL>       [\x01-\x08\x0b\x0c\x0e-\x1f\x7f]
    <token: ALPHA>           [A-Za-z]
    <token: DIGIT>           [0-9]
    <token: CRLF>            \x0d \x0a
    <token: DQUOTE>          "
    <token: WSP>             [\x20\x09]
    }x;
};

while (my $input = <>) {
    if ($input =~ $rfc5322) {
        say Dumper \%/;       # ...the parse tree of any successful match
                              # appears in this punctuation variable
    }
}

如您所见,通过在模式中使用一个非常不同的表示法,您现在可以在%/变量中为您存储整个解析树,并且所有内容都被整齐地标记。转换的结果仍然是一个模式,正如您在=~操作员所看到的那样。这有点神奇。

于 2011-01-30T15:07:51.817 回答