1

我一直在试验 ESP8266 wifi 芯片和 MPU9250 IMU 的睡眠选项。ESP 有一个深度睡眠命令，除了实时时钟之外，它基本上会关闭芯片，直到 RESET 引脚被 ESP 的 GPIO16 或外部中断拉低。

MPU9250以其WOM（运动唤醒）功能的形式提供此中断，该功能使芯片达到最低限度的功能，直到它检测到内置加速度计上的运动，此时其INT引脚被拉高（我附上了这个引脚连接到 ESP 的 RESET 引脚和 GND 之间的 NMOS 晶体管的栅极，以反转中断）。

但是，当我设置并使用以下代码时，设置会进入重置循环；两个打印语句都执行，但我不确定 ESP 是否真的有时间执行 DeepSleep 命令，因为它会在“到达这里”打印后立即重置并且不等待动作。

但是，如果我在程序运行时从 NMOS 断开并重新连接 INT 连接，它会暂时工作并休眠，直到它检测到运动，此时复位循环再次开始（即使 MPU9250 在移动后完全保持静止）。这意味着 WOM 功能正在工作，但是某些原因导致 INT 引脚在不应该的情况下 ping 为高电平，我无法弄清楚问题出在哪里。有谁知道是什么问题？我可以单独用代码修复它吗？

主要代码（loop() 为空）：

#include <quaternionFilters.h>
#include <MPU9250.h>
#include <ESP8266WiFi.h>

extern "C" {
  #include "gpio.h"
}

extern "C" {
  #include "user_interface.h"
}

MPU9250 myIMU;

void setup()
{
    Wire.begin(5, 14);
    Serial.begin(74880);
    printf("WAKE ME UP INSIDE");
    delay(500);
    sensorMpu9250WomEnable();
    printf("Got Here");
    ESP.deepSleep(0, WAKE_RF_DEFAULT);

}

在一个单独的文件中：

bool sensorMpu9250WomEnable(void)
{
  uint8_t val;
  // Clear registers
  val = 0x80;
  myIMU.writeByte(MPU9250_ADDRESS, PWR_MGMT_1, val);
  delay(10);

  // Enable accelerometer, disable gyro
  val = 0x07;
  myIMU.writeByte(MPU9250_ADDRESS, PWR_MGMT_2, val);
  delay(10);

  // Set Accel LPF setting to 184 Hz Bandwidth
  val = 0x01;
  myIMU.writeByte(MPU9250_ADDRESS, ACCEL_CONFIG2, val);
  delay(10);

  // Enable Motion Interrupt
  val = 0x40;
  myIMU.writeByte(MPU9250_ADDRESS, INT_ENABLE, val);
  delay(10);

  // Enable Accel Hardware Intelligence
  val = 0xC0;
  myIMU.writeByte(MPU9250_ADDRESS, MOT_DETECT_CTRL, val);
  delay(10);

  // Set Motion Threshold
  val = 0x40;
  myIMU.writeByte(MPU9250_ADDRESS, WOM_THR, val);
  delay(10);

  // Set Frequency of Wake-up
  val = 6;
  myIMU.writeByte(MPU9250_ADDRESS, LP_ACCEL_ODR, val);
  delay(10);


  // Enable Cycle Mode (Accel Low Power Mode)
  val = 0x20;
  myIMU.writeByte(MPU9250_ADDRESS, PWR_MGMT_1, val);
  delay(10);

  return true;
}
4

1 回答 1

1

非常感谢您提供的这些片段，它们帮助我启动并运行了我的项目。

我可以通过在开始深度睡眠之前添加延迟来解决这个问题：

Wire.begin(I2C_SDA, I2C_SCL);
Serial.begin(115200);
Serial.println("WAKE ME UP INSIDE");
delay(500);
sensorMpu9250WomEnable();
Serial.println("Got Here");

Serial.flush();
delay(1000);
esp_sleep_enable_ext0_wakeup(GPIO_NUM_27, 1);
esp_deep_sleep_start();

希望对你也有帮助。

于 2021-05-12T09:01:22.710 回答