pari - 在 Pari 中绘制多个列表

Question

我有两个（对）要绘制的列表。我知道，我可以使用 plothraw 函数分别绘制每个图。但是我怎样才能将它们绘制在同一张图片中，这样我最终会得到两条不同颜色的曲线呢？

Answer 1

作为参考，以下是使用 将两个数据集绘制在两个单独的图中的方法plothraw：

\\ As two separate plots using plothraw
plothraw([0..200], apply(i->sin(i*3*Pi/200), [0..200]), 0);
plothraw([0..200], apply(i->cos(i*3*Pi/200), [0..200]), 0);

第一个解决方案使用ploth：

 {ploth(i=0, 200, [i, sin(i*3*Pi/200), i, cos(i*3*Pi/200)], "Parametric|no_Lines", 200);}

使用低级函数的第二种解决方案，但我无法使颜色正常工作（显然在 X-windows 上受支持，但在 Windows 上不支持）：

{my(s=plothsizes());plotinit(0,s[1]-1,s[2]-1);}
plotscale(0, 0, 200, -1, 1);
plotcolor(0, 2); \\ blue
plotrecthraw(0, [ [0..200], apply(i->sin(i*3*Pi/200), [0..200]) ], 0);
plotcolor(0, 4); \\ red
plotpoints(0, [0..200], apply(i->cos(i*3*Pi/200), [0..200]));
plotdraw([0,0,0]); \\ draws window 0 at (0,0)
plotkill(0); \\ frees memory of window 0

可能第一个解决方案是最容易使用的（特别是如果您不希望所有东西都使用相同的颜色）。如果您有 4 个向量中的数据，例如vx, vy, ux，uy所有这些向量的长度都相同，#vx == #vy == #ux == #uy那么正确的形式是：

\\ first 2 lines just create test vectors
vx=[0..200]; vy=apply(i->sin(i*3*Pi/200), [0..200]);
ux=[0..200]; uy=apply(i->cos(i*3*Pi/200), [0..200]);
\\ the actual plot - the \1's just round to integer index
{ploth(i=1, #vx, [vx[i\1], vy[i\1], ux[i\1], uy[i\1]], "Parametric|no_Lines", #vx);}