2

最初我有一个 ByteString，然后我将其解压缩并转换为 Int16，这部分过程花费的时间相对较少。然后，我使用以下行将 Int16s 列表转换为 Repa 数组，

Repa.fromListUnboxed (Z :. bytesOfDataPerImage `div` 2) listOfInts

根据分析器的说法，这条线占用了大约 40% 的 CPU 时间，这可能只是表明我正在执行的计算不保证使用 Repa。从 ByteString 到 Repa 数组时，是否有更有效的路线？

我已经尝试了 Repa fromByteString 函数，虽然转换

Array B DIM1 Word8 -> Array U DIM1 Int16

很慢。我通过首先将数组重新整形为 Word8s 的二维数组，然后折叠到 Int16s 来执行此操作。也许字节数组是正确的方法，而我的转换方法是错误的。

convertImageData :: Array B DIM1 Word8 -> Array U DIM1 Int16
convertImageData !arr = Repa.foldS convertWords 0 (Repa.map fromIntegral (splitArray arr))

splitArray :: Array B DIM1 Word8 -> Array U DIM2 Word8
splitArray !arr = computeUnboxedS $ reshape (Z :. ((size $ extent arr) `div` 2) :. 2) arr


convertWords :: Int16 -> Int16 -> Int16
convertWords !word1 !word2 = (word1 `shiftL` 8) .|. word2

在某些情况下，该程序正在针对用 C/C++ 编写的同一程序进行基准测试。

4

1 回答 1

1

您转换为列表并稍后调用的初始方法Repa.fromListUnboxed肯定非常慢，因为您所做的只是强制列表的元素，而不是将其按顺序加载到未装箱的数组中。这就是为什么转换成列表只需要很少的时间，因为它所做的只是创建一堆 thunk，但实际计算发生在您将其加载到数组中时。

您的第二种方法肯定要好得多，但是仍然有不必要的步骤，例如。不需要reshape数组，您只需将新大小传递给fromByteString函数`。所以这里有一个稍微改进的版本：

bytesToRepaOriginal :: Bytes.ByteString -> Repa.Array Repa.U Repa.DIM1 Int16
bytesToRepaOriginal bs =
  Repa.foldS
    convertWords
    0
    (Repa.map fromIntegral $
     Repa.fromByteString (Repa.Z Repa.:. (Bytes.length bs `div` 2) Repa.:. 2) bs)

fromByteString由于某种原因，Repa 中的函数和B表示并不是特别快，因此有一种更快的方法可以做到这一点，即通过直接索引来构造一个数组ByteString：

bytesToRepaP :: Monad m => Bytes.ByteString -> m (Repa.Array Repa.U Repa.DIM1 Int16)
bytesToRepaP bs =
  Repa.computeUnboxedP $
  Repa.fromFunction
    (Repa.Z Repa.:. (Bytes.length bs `div` 2))
    (\(Repa.Z Repa.:. i) ->
       let i' = i * 2
           f = Bytes.unsafeIndex bs
        in (fromIntegral (f i') `shiftL` 8) .|. fromIntegral (f (i' + 1)))

切换到顺序计算Repa.computeUnboxedS将使您减慢 x2 倍，但由于我们正在尝试优化它，我们需要一直使用并行计算。

不要从一个非常好的 Repa 库中窃取所有的雷声，我还想展示所有这些将如何与新的massiv库一起工作：

import Data.Massiv.Array as Massiv

bytesToMassiv :: Bytes.ByteString -> Massiv.Array Massiv.U Massiv.Ix1 Int16
bytesToMassiv bs =
  Massiv.makeArrayR U Par (Bytes.length bs `div` 2)
    (\i ->
       let i' = i * 2
           f = Bytes.unsafeIndex bs
        in (fromIntegral (f i') `shiftL` 8) .|. fromIntegral (f (i' + 1)))

只是为了展示一些具体的数字来显示这里的优化是一个精简的标准基准：

benchmarking fromByteString/Massiv Parallel
time                 1.114 ms   (1.079 ms .. 1.156 ms)

benchmarking fromByteString/Repa Parallel
time                 1.954 ms   (1.871 ms .. 2.040 ms)

benchmarking fromByteString/Repa Original
time                 15.80 ms   (15.67 ms .. 15.92 ms)
于 2018-08-01T09:24:42.483 回答