6

我找不到关于以下内容的解释。我制作了这个测试脚本来解决我之前的问题。

xquery version "3.0" ;
declare default function namespace 'local' ;

declare function local:is-img-only( $element as element() )  as xs:boolean {    
   ($element/child::*[1] instance of element(img)) 
   and (fn:not($element/child::*[2])) 
   and (fn:normalize-space($element) = '')
} ;

let $in-xml := <myxml>
   <p id="1">

      <img id="1"/>

   </p>
   <p id="2">
      <img id="1"/>
      hello
   </p>
   <p id="3">
      <img id="1"/>
   </p>
   <p id="4">
    <blockquote>hello</blockquote>
      <img id="1"/>
   </p>
   <p id="5">
      <img id="1"/>
      <img id="2"/>
   </p>
</myxml>

然后，以下使用if then else：

for $p in $in-xml/p
  return if (local:is-img-only($p)) 
    then $p/@id/fn:data() || ' has only an img child'
    else $p/@id/fn:data() || ' has not strictly an img child'

按预期返回：

1 has only an img child
2 has not strictly an img child
3 has only an img child
4 has not strictly an img child
5 has not strictly an img child

而以下使用switch case

for $p in $in-xml/p
  return switch ($p)
    case (local:is-img-only($p)) return $p/@id/fn:data() || ' has only an img child'
    default return $p/@id/fn:data() || ' has not strictly an img child'

未按预期返回：

1 has not strictly an img child
2 has not strictly an img child
3 has not strictly an img child
4 has not strictly an img child
5 has not strictly an img child

有什么解释吗？为什么Conditional Expressions的行为方式与Switch Expressions不同？

4

1 回答 1

4

为您的问题找到 XQuery 规范的相关部分非常棒！这是成功的一半。Switch 表达式确实与条件表达式有一些共同点，但也有一些不同之处。

关键区别在于条件表达式评估测试表达式以查看结果是真还是假，而 switch 表达式将一个表达式与一个或多个其他表达式进行比较以找到第一对相等的表达式。使用伪代码，我们可以说明差异。条件表达式中的所有逻辑都发生在一行中：

if ($EXPRESSION)

相比之下，switch 表达式的逻辑分布在多行中：

switch ($EXPRESSION_A)
    case ($EXPRESSION_B) ...
    case ($EXPRESSION_C) ...
    case ($EXPRESSION_D) ...
    default ...

switch 表达式实际上是在执行一系列比较，我们可以将其表示为更多行条件表达式：

if (deep-equal($EXPRESSION_A, $EXPRESSION_B))
then ...
else 
    if (deep-equal($EXPRESSION_A, $EXPRESSION_C))
    then ...
    else ...
        if (deep-equal($EXPRESSION_A, $EXPRESSION_D))
        then ...
        else ... (: "default" :)

规范中描述了这两个表达式之间的本质差异，从它们描述处理每个表达式的“第一步”开始。而处理条件表达式的第一步是：

找到测试表达式的有效布尔值。

... 处理 switch 表达式的第一步是：

将原子化应用于开关操作数表达式的值。

让我们回到你的具体例子，看看你的条件的测试表达式和你的开关的开关操作数表达式：

  1. 您的条件测试表达式：

    if (local:is-img-only($p))

  2. 你的开关的操作数表达式：

    switch ($p)

条件的测试表达式返回一个布尔值 -true()或false()，所以这个条件清楚地描绘了其余代码的路径。

相比之下，switch 表达式的逻辑只是从这个操作数表达式开始。首先，它找到操作数表达式的原子化值——绑定到FLWOR 表达式中<p>的变量的元素。$p由于该值取决于<p>我们正在查看的值，因此原子化值将是空字符串 ( "")、空格或"hello"（或它们的某种组合，取决于源中的空格和边界空间声明）。然后，对 switch 的第一个 case 操作数进行评估和原子化。您的第一个案例操作数如下：

case (local:is-img-only($p))

我们回想一下，这个表达式的计算结果是一个布尔值。switch 表达式执行的下一步是使用fn:deep-equal函数将 switch 操作数表达式的原子化值与 switch case 操作数的原子化值进行比较。因此，我们实际上要求 XQuery 处理器执行以下比较：

deep-equal("", true())
deep-equal("hello", false())

在这两种情况下，比较都会返回false()。因此，在我们的案例操作数中，这种比较总是失败，因此在您的 FLWOR 表达式的每次迭代中，switch 表达式都会退回到default子句。

模拟原始条件表达式结果的 switch 表达式如下：

for $p in $in-xml/p
  return switch(local:is-img-only($p))
    case (true()) return $p/@id/fn:data() || ' has only an img child'
    default return $p/@id/fn:data() || ' has not strictly an img child'

这将执行以下检查：

deep-equal(true(), true())
deep-equal(true(), false())

并返回与条件表达式相同的结果。

这不是 switch 表达式特别引人注目的用途——因为我们正在有效地评估单个测试表达式。当您有许多值要比较时，switch 表达式真的很出色。该规范为我们提供了一个很好的示例 switch 表达式来考虑：

switch ($animal)
    case "Cow" return "Moo"
    case "Cat" return "Meow"
    case "Duck" return "Quack"
    default return "What's that odd noise?"

这比等效的条件表达式更具可读性和紧凑性：

if (deep-equal($animal, "Cow")) 
then "Moo"
else 
    if (deep-equal($animal, "Cat")) 
    then "Meow"
    else
        if (deep-equal($animal, "Duck"))
        then "Quack"
        else "What's that odd noise?"

甚至更直接的解释：

if ($animal eq "Cow")
then "Moo"
else 
    if ($animal eq "Cat")
    then "Meow"
    else
        if ($animal eq "Duck")
        then "Quack"
        else "What's that odd noise?"

结果：如果您发现自己编写了一系列条件，并且比较的左侧始终相同，请考虑进行 switch。

于 2018-01-11T04:38:08.070 回答