2

我有一个使用 fable-elmish 的模型更新视图架构的项目。而且我必须每分钟下载文件并阅读这些文件。如何在更新功能中下载，如何读取并解析为 Json？

我也需要使用 Fable 创建动态图表。有人知道怎么做吗？

我的部分代码在这里：

let update (msg : Msg) (model : Model) =
  match msg with
  | GetData -> 
    model, 
    Cmd.ofPromise 
      (fun () -> 
        promise {
          let wc = new WebClient()
          wc.DownloadData("https://www.quandl.com/api/v1/datasets/LBMA/SILVER.json", "SILVER.json")
          wc.DownloadData("https://www.quandl.com/api/v1/datasets/LBMA/GOLD.json", "GOLD.json")
          // Read 2 files
          // Return 2 Json.Object
        })
      ()
      (fun silver gold -> GotData silver gold)
      (fun e -> GotError e.Message)
  | GotData silver gold -> 
    (Model.SilverData silver, Model.GoldData gold), // I think this doesn't work
    Cmd.ofPromise 
      (fun () -> Promise.sleep 60000)
      ()
      (fun () -> GetData)
      (fun e -> GetData)
4

1 回答 1

1

如果您有一个周期性事件应该在您的 Elmish 应用程序中引起一些操作，我会使用订阅。以下代码片段显示了一个函数，该函数设置了一个间隔，该间隔会导致每 10 分钟一次命令调度。

let timer initial =
    let sub dispatch =
        window.setInterval(fun _ -> dispatch LoadDataSet; console.log("Timer triggered")
            , 1000 * 60 * 10) |> ignore

    Cmd.ofSub sub

您将使用该Program.withSubscription函数将订阅添加到您的主调度循环。

我会使用Fable PowerPack包fetch来promise获取数据集。以下代码将从您指定的端点获取文档，将它们解析为DataSet类型的值，并将它们作为SilverAndGold模型类型的值返回到 promise 的成功路径上。

type DataSet =
    { column_names : string list
      data : (string * float * float * float) list }

type SilverAndGold =
    { Silver : DataSet
      Gold : DataSet }

...

let fetchDataSets () = promise {
    let! silverData = Fetch.fetchAs<DataSet> "https://www.quandl.com/api/v1/datasets/LBMA/SILVER.json" []
    let! goldData = Fetch.fetchAs<DataSet> "https://www.quandl.com/api/v1/datasets/LBMA/GOLD.json" []

    return { Silver = silverData; Gold = goldData }
}

在 Elmish 应用程序的更新功能中，您可以看到如何触发承诺执行。在我们的订阅发送的每条LoadDataSet消息上，我们都会创建一个 promise 命令，该命令会导致DataSetLoaded包含数据集的消息或错误。

let update (msg:Msg) (model:Model) =
    match msg with
    | LoadDataSet ->
        model, Cmd.ofPromise fetchDataSets () DataSetLoaded Error
    | DataSetLoaded silverGold ->
        // here you could process you silver and gold datasets
        console.log silverGold
        Some silverGold, Cmd.none
    | Error e -> model, Cmd.none

我们可以使用Recharts库的Fable 绑定来绘制我们的数据集。下面的代码展示了我们如何转换和修剪数据集（在浏览器中渲染所有数据点会非常麻烦）并将它们显示为函数中的折线图。view

type ChartDataPoint =
    { Date : string
      Usd : float
      Gbp : float
      Euro : float }

let toChartData (dataSet : DataSet) =
    dataSet.data
    |> List.map (fun (dt, usd, gbp, eur) ->
        { Date = dt; Usd = usd; Gbp = gbp; Euro = eur } )
    |> Array.ofList
    |> Array.take 1000
    |> Array.rev

let priceChart (chartData : ChartDataPoint[]) =
    lineChart
        [ Chart.Data chartData
          Chart.Width 600.
          Chart.Height 500. ] [
        xaxis [ Cartesian.DataKey "Date" ] []
        yaxis [] []
        tooltip [] []
        legend [] []
        line [ Cartesian.Type "monotone"; Cartesian.DataKey "Gbp" ] []
        line [ Cartesian.Type "monotone"; Cartesian.DataKey "Euro" ] []
        line [ Cartesian.Type "monotone"; Cartesian.DataKey "Usd" ] []
    ]

let view (model : SilverAndGold option ) dispatch =
  div [ ] [
        match model with
        | Some sets ->
            yield h2 [] [ str "Silver" ]
            yield priceChart (toChartData sets.Silver)
            yield h2 [] [ str "Gold" ]
            yield priceChart (toChartData sets.Gold)
        | None ->
            yield h2 [] [ str "No data :("]
    ]

我制作了一个非常小的 Elmish 应用程序，其中包含所有这些主题。您可以在这里找到它并根据您的需要进行调整。

于 2018-08-15T15:08:32.620 回答