1

我创建了一个具有不同前缀（rdf:, rdfs:, owl:, example:, car:, bike:, ...）的本体。我用它们来划分不同的领域和例子。

一小段摘录：

car:Software rdf:type demo:CyberObject.
car:Hardware rdf:type spdm:PhysicalObject.
car:Software car:hasMaturity "ten".
car:Hardware demo:isProducedIn loc:NorthPole.

有没有办法将“”更改为PREFIX例如car:“ plane:”，并保持关系：

plane:Software rdf:type demo:CyberObject.
plane:Hardware rdf:type spdm:PhysicalObject.
plane:Software plane:hasMaturity "ten".
plane:Hardware demo:isProducedIn loc:NorthPole.

我仍然需要所有的关系。带有PREFIX“ car:”的对象不必替换；PREFIX用新对象创建新对象并将旧对象保留在数据库中就足够了。

感谢您的任何建议！

4

1 回答 1

4

依次替换主语、谓语和宾语中的前缀。

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix car: <http://example.com/car/>
prefix demo: <http://example.com/demo/>
prefix spdm: <http://example.com/spdm/>
prefix loc: <http://example.com/loc/>
prefix plane: <http://example.com/plane/>

DELETE {?s ?p1 ?o} INSERT {?s ?p2 ?o} WHERE
{
?s ?p1 ?o .
FILTER (strstarts(str(?p1), str(car:)))
BIND (IRI(replace(str(?p1), str(car:), str(plane:)))  AS ?p2)
} ;

DELETE {?s1 ?p ?o} INSERT {?s2 ?p ?o} WHERE
{
?s1 ?p ?o .
FILTER (strstarts(str(?s1), str(car:)))
BIND (IRI(replace(str(?s1), str(car:), str(plane:)))  AS ?s2)
} ; 

DELETE {?s ?p ?o1} INSERT {?s ?p ?o2} WHERE
{
?s ?p ?o1 .
FILTER (strstarts(str(?o1), str(car:)) && isIRI(?o1))
BIND (IRI(replace(str(?o1), str(car:), str(plane:)))  AS ?o2)
} ;

未在 Allegrograph 中进行测试，并且可能存在 Allegrograph 特定的解决方案。

更新

我仍然需要所有的关系，带有前缀“汽车”的对象不必被替换......</p>

然后不要替换对象中的前缀。但是，请记住，一个三元组中的对象可以是另一个三元组中的主题。

…使用新的 PREFIX 创建新的对象并将旧对象保留在数据库中就足够了。

“独立”URI 不存储在三重存储中。

于 2017-12-21T07:50:46.883 回答