oracle - 如何在 plsql 函数中使用绑定变量

Question

我有这样的功能：

create or replace function params
(
    p_pr     varchar2,
    p_qu_id  varchar2,
    p_date   date := sysdate,
    p_param  varchar2 := null
)
    return   varchar2
as
    ...
    sql_stmt varchar2(4000);
    rc       sys_refcursor;
    ...
BEGIN
    sql_stmt := 'select parameter_name, parameter_value from ' || p_pr | '.v_view where query_id = ''' || p_qu_id || '''';

    IF p_param IS NOT NULL
    THEN
        sql_stmt := sql_stmt || ' and parameter_value=''' || p_param || '''';
    END IF;

    OPEN rc FOR sql_stmt;
    LOOP
        FETCH rc
            INTO v_param_name, v_param_value;
        EXIT WHEN rc%NOTFOUND;
        EXIT WHEN v_param_value is NULL;

        ....

DBA 说这个函数使用硬解析，我必须在这个函数中使用绑定变量。我怎样才能做到这一点？

谢谢。

Answer 1

我必须在这个函数中使用绑定变量。

解决方案是在模板 SQL 中使用占位符...

sql_stmt := sql_stmt || ' and parameter_value= :p1';

...然后在打开引用游标时使用 USING 子句传递实际值。

事情有点棘手，因为您正在执行不同的语句，具体取决于是否填充了参数。所以你需要做这样的事情：

sql_stmt := 'select parameter_name, parameter_value from ' || p_pr 
     || '.v_view where query_id =:p1';

IF p_param IS NOT NULL
THEN
    sql_stmt := sql_stmt || ' and parameter_value= :p2';
    OPEN rc FOR sql_stmt using p_qu_id, p_param;
else
   OPEN rc FOR sql_stmt using p_qu_id;
END IF;

LOOP

请注意p_pr- 模式名称 - 不能用绑定变量替换。