haskell - 使用 DuplicateRecordFields 消除记录更新的歧义

Question

我正在使用 DuplicateRecordFields (+OverloadedLabels) 扩展，我遇到了一种情况，我无法弄清楚如何在记录更新中消除歧义。

这是一个简化的示例：

data A = A { name :: String }
data B = B { name :: String }

combine :: A -> B -> A
combine a b = a { name = name b }

有什么办法可以使这项工作？

Answer 1

或者，您可以机械地使用getFieldfromGHC.Records来消除歧义，如下所示：

{-# LANGUAGE DataKinds #-}                                                                                                                                                         
{-# LANGUAGE DuplicateRecordFields #-}
{-# LANGUAGE TypeApplications #-}

module DRF where

import GHC.Records (getField)

data A = A { name :: String } deriving Show
data B = B { name :: String }

combine :: A -> B -> A
combine a b = a { name = getField @"name" b }

{- in ghci

Prelude DRF> a = A "Alice"  
Prelude DRF> b = B "Bob"    
Prelude DRF> DRF.combine a b
A {name = "Bob"}

-}

参考：

• https://www.reddit.com/r/haskell/comments/8693a3/usefulness_of_duplicaterecordfields/dw3fe8u/
• https://hackage.haskell.org/package/base-4.12.0.0/docs/GHC-Records.html

Answer 2

我在之前的一个问题中回答了关于-XDuplicateRecordFields当前 GHC 不会从其参数中推断记录字段类型的问题：

• 愚蠢的重复记录字段错误

您现在可以做的是name明确指定提取器的类型，如下所示：

{-# LANGUAGE DuplicateRecordFields #-}

data A = A { name :: String }
data B = B { name :: String }

combine :: A -> B -> A
combine a b = a { name = (name :: B -> String) b }

Answer 3

您可以匹配模式中的名称：

data A = A { name :: String }
data B = B { name :: String }

combine :: A -> B -> A
combine a B{name = nb} = a { name = nb }

虽然我不喜欢DuplicateRecordFields。为什么不走镜头路线呢？

{-# LANGUAGE TemplateHaskell, FlexibleInstances, FunctionalDependencies #-}

import Control.Lens
import Control.Lens.TH

data A = A { _aName :: String }
makeFields ''A
data B = B { _bName :: String }
makeFields ''B

combine :: A -> B -> A
combine a b = a & name .~ b^.name