0

我尝试运行一个为特定数据库的每个表创建视图的脚本。我找到了这个链接： 如何为数据库中的所有表创建视图？

显然，为了工作，我需要添加“GO”语句和回车。所以这就是我所做的

DECLARE @SQL NVARCHAR(MAX)
SET @SQL = ''

SELECT
    @SQL = @SQL+
    N'CREATE VIEW [v2_' + t.name + N'] AS SELECT ' + 
        STUFF(
            (SELECT N',' + c.name
               FROM
                  sys.columns AS c
               WHERE 
                 c.OBJECT_ID = t.OBJECT_ID
               ORDER BY
                 column_id
               FOR XML PATH(''), TYPE).value('.',N'nvarchar(max)')
        ,1,1,N'')
        + N' FROM [' + t.name + N'] [\r\n]go[\r\n]'

FROM
    sys.tables AS t
WHERE
    t.schema_id ='1'

SET @SQL = REPLACE(@SQL,'[\r\n]',CHAR(13)+CHAR(10))
PRINT @SQL

EXECUTE (@SQL)

所以打印结果是我所期望的：

CREATE VIEW ***** AS SELECT Parent_Path,id,a2ea,userLabel,DATE,HEURE,REF_EQT,COMMANDE_REF,LOG FROM ***** 
go
CREATE VIEW ***** AS SELECT AlarmIdentifier,Class,Category,Time,ObjectOfReference,AlarmText,DATE,HEURE,REF_EQT,SS_EQT,Carte_EQT,COMMANDE_REF,LOG FROM ***** 
go
CREATE VIEW ***** AS SELECT CELL,MCC,MNC,LAC,CID,BSC,CO,EA,RO,NCS,DATE,HEURE,REF_EQT,SS_EQT,Carte_EQT,COMMANDE_REF,LOG FROM ***** 
go
CREATE VIEW ***** AS SELECT RNC,RNCID,R1,R2,GLCNID,RNCCODEC,TB,DATE,HEURE,REF_EQT,SS_EQT,Carte_EQT,COMMANDE_REF,LOG FROM ***** 
go
CREATE VIEW ***** AS SELECT MGG,MG,RESTRICTED,DEFAULT,MISC,MGP,WF,DATE,HEURE,REF_EQT,SS_EQT,Carte_EQT,COMMANDE_REF,LOG FROM [NRGGP] 
go
CREATE VIEW ***** AS SELECT SNT,SNTV,SNTP,DIP,DEV,DEVP,SNTINL,EQLEV,PROT,SDIP,SUBSNT,DEFPST,EXTP,MG,DATE,HEURE,REF_EQT,COMMANDE_REF,LOG FROM *****
go
CREATE VIEW ***** AS SELECT RefreshLog_Id,Date,Etat,DateTransfert,Transfert FROM ***** 
go

但 exec 行返回：

消息 156，级别 15，状态 1，过程 *****，第 3 行 [批处理开始行 0]
关键字“CREATE”附近的语法不正确。

消息 111，级别 15，状态 1，过程 *****，第 3 行 [批处理开始第 0 行]
“CREATE VIEW”必须是查询批处理中的第一个语句。

消息 111，级别 15，状态 1，过程 *****，第 5 行 [批处理开始第 0 行]
“CREATE VIEW”必须是查询批处理中的第一个语句。

消息 111，级别 15，状态 1，程序 *****，第 7 行 [批处理开始第 0 行]

我应该创建一个架构吗？我的问题有什么解决办法吗？

非常感谢

4

3 回答 3

0

好的，所以最后我按照你们的建议做了，我创建了一个光标，它可以工作。谢谢你。

DECLARE @TableName as NVARCHAR(50)
DECLARE @TableCursor as CURSOR

SET @TableCursor = CURSOR FOR
SELECT TABLE_NAME 
FROM INFORMATION_SCHEMA.TABLES 
WHERE TABLE_TYPE='BASE TABLE' and TABLE_SCHEMA = 'dbo';

OPEN @TableCursor;

FETCH NEXT FROM @TableCursor INTO @TableName;

While @@FETCH_STATUS = 0

BEGIN
    EXEC ('create view '+ @TableName+'_V2 
    as select * from ' +@TableName +';')
    FETCH NEXT FROM @TableCursor INTO @TableName;
END

CLOSE @TableCursor
DEALLOCATE @TableCursor
于 2017-12-15T11:01:33.780 回答
0

使用游标和 EXECUTE sp_executesql似乎有效

DECLARE @SQL NVARCHAR(MAX)
       , @table_id INT
SET @SQL = ''

DECLARE CUR CURSOR LOCAL FAST_FORWARD FOR
SELECT t.object_id FROM sys.tables AS t
WHERE t.schema_id ='1'

OPEN CUR

FETCH NEXT FROM cur INTO @table_id
WHILE @@FETCH_STATUS = 0
BEGIN

    SELECT @SQL = N'CREATE VIEW [v2_' + t.name + N'] AS SELECT ' + 
            STUFF(
                (SELECT N',' + c.name
                   FROM
                      sys.columns AS c
                   WHERE 
                     c.OBJECT_ID = t.OBJECT_ID
                   ORDER BY
                     column_id
                   FOR XML PATH(''), TYPE).value('.',N'nvarchar(max)')
            ,1,1,N'')
            + N' FROM [' + t.name + N'];'
    FROM
        sys.tables AS t
    WHERE t.object_id = @table_id 

    PRINT @SQL
    --EXECUTE sp_executesql @SQL
    FETCH NEXT FROM cur INTO @table_id
END

CLOSE CUR

DEALLOCATE CUR
于 2017-12-14T19:54:08.933 回答
0

你应该使用这样的语法：

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

CREATE VIEW [schema].[viewname] AS
SELECT * FROM schema.table

GO

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

CREATE VIEW [schema].[viewname] AS
SELECT * FROM schema.table

GO

例如 ：

SELECT 
'SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
CREATE VIEW ' + TABLE_SCHEMA + '.' + TABLE_NAME + ' AS 
SELECT * FROM ' + TABLE_SCHEMA + '.' + TABLE_NAME + ' 

GO 
'
FROM INFORMATION_SCHEMA.TABLES WHERE TABLE_TYPE='BASE TABLE'

不要忘记将结果输出为文本格式（SQL server Mgmt studio 中的 CTRL + T。），因为它会保留回车。

对于这种情况，您可以生成一个脚本来检查 SQL Server 如何处理您的脚本。只需右键单击您的数据库、任务、生成脚本并跟随助手。它会在 SQL Server 等待时向您输出一个文件。

于 2019-02-07T12:51:32.540 回答