3

这是一个新手问题。假设我想将文件和目录列表分成文件列表和目录列表：

getFilesAndDirs :: [FilePath] -> ([FilePath], [FilePath])
getFilesAndDirs paths =
  let ...
  in (dirs, files)

可能这是一个无可救药的重复，我只是错过了正确的关键字。做（和调用）这个的正确方法是什么？

文件和目录随机出现。

4

3 回答 3

2

该Data.List包具有根据谓词将 spartition :: (a -> Bool) -> [a] -> ([a],[a])列表拆分a为两个 s 列表的元组的功能。a

然而问题是当我们检查一个文件是否是一个目录时，我们可能会使用isDirectory :: FilePath -> IO Bool所以我们不能直接使用它作为谓词（因为IO Bool不等于Bool）。

但是，我们可以编写自己的partitionM，并使用它：

import Data.Bool(bool)
import Data.Foldable(foldrM)

partitionM :: (Foldable t, Monad m) => (a -> m Bool) -> t a -> m ([a], [a])
partitionM p = foldrM (selectM p) ([],[])

selectM :: Monad m => (a -> m Bool) -> a -> ([a], [a]) -> m ([a], [a])
selectM p x (ts,fs) = p x >>= return . bool (ts, x:fs) (x:ts,fs)

然后我们可以像这样使用它：

import System.Directory(isDirectory)

getFilesAndDirs :: [FilePath] -> IO ([FilePath], [FilePath])
getFilesAndDirs = partitionM isDirectory

请注意，它是IO ([FilePath], [FilePath])，因为我们需要执行 I/O 来检查路径是否确实是目录（而不是文件）。

于 2017-12-11T14:40:05.637 回答
2

您可以使用do符号来编排程序的不纯部分，然后使用内置（纯）函数partition来完成实际工作。这是一个例子：

module Q47755054 (getFilesAndDirs) where

import Data.List (partition)
import Data.Bifunctor (bimap)
import System.Directory (doesDirectoryExist)

tagPath :: FilePath -> IO (FilePath, Bool)
tagPath path = do
  isDirectory <- doesDirectoryExist path
  return (path, isDirectory)

getFilesAndDirs :: [FilePath] -> IO ([FilePath], [FilePath])
getFilesAndDirs paths = do
  taggedPaths <- mapM tagPath paths
  return $ bimap (fmap fst) (fmap fst) $ partition snd taggedPaths

请注意，这使用内置mapM函数来获取不纯的值列表 ( IO [(FilePath, Bool)])，但由于do语法和<-绑定，taggedPaths“看起来”像纯值 ( [(FilePath, Bool)])，因此您可以将其传递给partition.

另外请注意，这tagPath只是一个模块级的辅助函数，它不是由模块导出的。

于 2017-12-11T15:04:48.213 回答
0 
module SeparateFiles where
    import Data.String
    import System.FilePath.Posix


    type Path = FilePath
    getFilesAndDirs :: Path -> [(Path,Path)]
    getFilesAndDirs path = [splitFileName path]

我了解您想将提取的 FilePath 拆分为文件和目录。我给你一个非常简短的例子。

于 2017-12-11T14:59:14.050 回答