2

我目前有以下断言脚本来检查三个字段的值。

import org.junit.Assert

def response = messageExchange.getResponseContent() 
def xml = new XmlSlurper().parseText(response)              
def nodelist = xml.'**'.findAll{ it.name() == 'premium' } 
def assertions = [6.19, 6.47, 6.90]
def i=0

for (node in nodelist) assert node.toString().matches(assertions[i++].toString())

我试图得到它，以便断言将传递实际值在预期值的任一侧的 0.05 范围内。

以下脚本在只有一个值时有效，但我正在努力使用上面的断言来实现它。

import org.junit.Assert 
// get the xml response     
def response = messageExchange.getResponseContent()     
// parse it     
def xml = new XmlSlurper().parseText(response)      
// find your node by name   
def node = xml.'**'.find { it.name() == 'premium' }     
// assert       
if(node.toDouble() != 0.0)  
    Assert.assertEquals(0.00, node.toDouble(), 0.05)

编辑

示例响应： 

<b:quote-data>
    <b:quote-data>
      <b:premium>6.13</b:premium>
    </b:quote-data>
    <b:quote-data>
      <b:premium>6.45</b:premium>
    </b:quote-data>
    <b:quote-data>
      <b:premium>6.91</b:premium>
    </b:quote-data>
 </b:quote-data>
4

1 回答 1

3

在您的情况下，这里有几件事会导致失败。

  • 当您定义如下列表时，它会将每个值类型视为BigDecimal类型。
  • 在比较之前，应将提取的值强制为相同的类型。

这是实现上述目标的示例：

def expectedPremiums = [6.19, 6.47, 6.90]
def xmlString = """<root xmlns:b="test">
 <b:quote-data>
       <b:premium>6.13</b:premium>
     </b:quote-data>
     <b:quote-data>
       <b:premium>6.45</b:premium>
     </b:quote-data>
     <b:quote-data>
       <b:premium>6.91</b:premium>
    </b:quote-data>
</root>"""
def xml = new XmlSlurper().parseText(xmlString)
def premiums = xml.'**'.findAll {it.name() == 'premium'}*.toBigDecimal()
println premiums

请注意，使用示例固定 xml，您可以使用 to 进行动态响应，就像您已经在做的那样。

如果您还需要使用容差进行验证的逻辑，请使用下面的脚本和上面的脚本。

def tolerance = 0.05
def failurePremiums = [:]
expectedPremiums.eachWithIndex { expected, index ->
   if ((expected-tolerance) <= premiums[index] && premiums[index] <= (expected+tolerance)) {
     println "${premiums[index]} is in range"
   } else {
      println "${premiums[index]} is not falling in range, failed"
      failurePremiums[expected] = premiums[index]
   }
}
assert !failurePremiums, "Not matched data(expected vs actual) :  ${failurePremiums}"

您可以在线快速试用demo

编辑：另一个建议

当您使用脚本断言时，您可以更改如下：

从：

def response = messageExchange.getResponseContent() 
def xml = new XmlSlurper().parseText(response)

至：

def xml = new XmlSlurper().parseText(context.response)
于 2017-11-16T11:33:33.517 回答