8

我想TParent通过使用聚合来构建一个包含多个子对象的类。有些对象是独立的，而有些对象也可以依赖于其他子对象。所有子对象都必须具有对父对象的引用。我还想尽可能使用接口。

为此，我正在使用TInterfacedObjectfor theTParent和TAggregatedObjectfor the children。由于孩子和父母都互相了解，我使用弱引用来避免循环依赖。事实上，这种行为已经在TAggregatedObject. 当我只使用独立的子对象 ( TIndependantChild) 时，一切正常。

当子对象也依赖于其他子对象时，就会出现问题，请参阅TDependantChild. 我将另一个子对象的引用存储在 fChild 变量中，该变量标有[weak]在 Delphi 10 Berlin 中引入的属性。FastMM4 在关机时报告内存泄漏：

在此处输入图像描述

访问冲突也会导致System.TMonitor.Destroy提升，但这仅在使用 FastMM4 且 ReportMemoryLeaksOnShutDown 为 True 时发生。

program Project1;

{$APPTYPE CONSOLE}

uses
  FastMM4,
  System.SysUtils;

type
  IParent = interface
  ['{B11AF925-C62A-4998-855B-268937EF30FB}']
  end;

  IChild = interface
  ['{15C19A4E-3FF2-4639-8957-F28F0F44F8B4}']
  end;

  TIndependantChild = class(TAggregatedObject, IChild)
  end;

  TDependantChild = class(TAggregatedObject, IChild)
  private
    [weak] fChild: IChild;
  public
    constructor Create(const Controller: IInterface; const AChild: IChild); reintroduce;
  end;

  TParent = class(TInterfacedObject, IParent)
  private
    fIndependantChild: TIndependantChild;
    fDependantChild: TDependantChild;
  public
    constructor Create;
    destructor Destroy; override;
  end;

{ TParent }

constructor TParent.Create;
begin
  fIndependantChild := TIndependantChild.Create(Self);
  fDependantChild := TDependantChild.Create(Self, fIndependantChild);
end;

destructor TParent.Destroy;
begin
  fDependantChild.Free;
  fIndependantChild.Free;
  inherited;
end;

{ TDependantChild }

constructor TDependantChild.Create(const Controller: IInterface; const AChild: IChild);
begin
  inherited Create(Controller);
  fChild := AChild;
end;

var
  Owner: IParent; 

begin
  ReportMemoryLeaksOnShutDown := True;
  Owner := TParent.Create;
  Owner := nil;
end.

我发现，使用 [unsafe] 而不是 [weak] 可以解决问题，但根据 delphi帮助

它（[不安全]）应该只在极少数情况下在系统单元之外使用。

因此，我不相信我应该[unsafe]在这里使用，尤其是当我不明白会发生什么时。

那么，这种情况下内存泄漏的原因是什么以及如何克服呢？

4

1 回答 1

4

使用外部 FastMM4 内存管理器时的泄漏和崩溃问题与以下有关用于跟踪弱引用的内部 HashMap 的最终确定问题有关。

[REGRESSION XE2/10.1 Berlin] 无法使用第 3 方内存管理器

由于该问题，无法在 Delphi 10.1 和更新版本中使用 3rd 方内存管理器进行泄漏检测，包括外部 FastMM4。

这就是为什么您对[weak]属性有问题而对[unsafe].

就您的代码而言，您可以安全地[unsafe]在上述情况下使用。虽然文档中有关于使用[unsafe]属性的警告，但该警告实际上并没有解释为什么[unsafe]不应该使用。

长话短说，[unsafe]当引用引用的对象实例[unsafe]的生命周期长于引用本身的生命周期时，您可以使用属性。

换句话说，您必须确保[unsafe]在它指向的对象实例已被释放后您不会访问引用，仅此而已。

[unsafe]当它们指向的对象被销毁时，引用不会清零，并且在对象消失后使用此类引用将导致访问冲突异常。

用 替换[weak]属性[unsafe]是您必须做的所有事情，以便在您呈现它时拥有正确的功能代码。

  TDependantChild = class(TAggregatedObject, IChild)
  private
    [unsafe] fChild: IChild;
于 2017-11-04T13:33:46.590 回答