49

过去几周我一直在学习 OpenGL，但在实现 Phong 着色器时遇到了一些麻烦。smooth尽管我使用了限定符，但它似乎没有在顶点之间进行插值。我在这里错过了什么吗？为了在应得的地方给予赞扬，顶点和片段着色器的代码大量来自OpenGL SuperBible第五版。我强烈推荐这本书！

顶点着色器：

#version 330
in vec4 vVertex;
in vec3 vNormal;
uniform mat4 mvpMatrix;  // mvp = ModelViewProjection
uniform mat4 mvMatrix; // mv = ModelView
uniform mat3 normalMatrix;
uniform vec3 vLightPosition;
smooth out vec3 vVaryingNormal;
smooth out vec3 vVaryingLightDir;

void main(void) {
 vVaryingNormal = normalMatrix * vNormal;
 vec4 vPosition4 = mvMatrix * vVertex;
 vec3 vPosition3 = vPosition4.xyz / vPosition4.w;
 vVaryingLightDir = normalize(vLightPosition - vPosition3);
 gl_Position = mvpMatrix * vVertex;
}

片段着色器：

#version 330
out vec4 vFragColor;
uniform vec4 ambientColor;
uniform vec4 diffuseColor;
uniform vec4 specularColor;
smooth in vec3 vVaryingNormal;
smooth in vec3 vVaryingLightDir;

void main(void) {
 float diff = max(0.0, dot(normalize(vVaryingNormal), normalize(vVaryingLightDir)));
 vFragColor = diff * diffuseColor;
 vFragColor += ambientColor;
 vec3 vReflection = normalize(reflect(-normalize(vVaryingLightDir),normalize(vVaryingNormal)));
 float spec = max(0.0, dot(normalize(vVaryingNormal), vReflection));

 if(diff != 0) {
   float fSpec = pow(spec, 32.0);
   vFragColor.rgb += vec3(fSpec, fSpec, fSpec);
 }

}

这张来自维基百科的（公共领域）图像准确地显示了我得到的图像类型和我的目标——我得到的是“平面”图像，但我想要“Phong”图像。

任何帮助将不胜感激。谢谢！

编辑：如果有所作为，我使用的是 PyOpenGL 3.0.1 和 Python 2.6。

编辑2：

解决方案

原来问题出在我的几何学上。科斯是正确的。对于其他在 Blender 模型中遇到此问题的人，Kos 指出这样做可以解决问题Edit->Faces->Set Smooth。我发现 Wings 3D “开箱即用”。

4

2 回答 2

66

作为这个答案的补充，这里有一个简单的几何着色器，它可以让你可视化你的法线。根据您的属性位置和发送矩阵的方式，根据需要修改随附的顶点着色器。

但首先，我们的朋友斯坦福兔的巨型兔头图片作为结果示例！

斯坦福兔子的法线

主要警告：请注意，我使用模型视图矩阵而不是适当的法线矩阵来转换法线。如果您的模型视图包含非均匀缩放，这将无法正常工作。此外，法线的长度不正确，但如果您只想检查它们的方向，那无关紧要。

顶点着色器：

#version 330

layout(location = 0) in vec4 position;
layout(location = 1) in vec4 normal;
layout(location = 2) in mat4 mv;

out Data
{
    vec4 position;
    vec4 normal;
    vec4 color;
    mat4 mvp;
} vdata;

uniform mat4 projection;

void main()
{
    vdata.mvp = projection * mv;
    vdata.position = position;
    vdata.normal = normal;
}

几何着色器：

#version 330
layout(triangles) in;
layout(line_strip, max_vertices = 6) out;

in Data
{
    vec4 position;
    vec4 normal;
    vec4 color;
    mat4 mvp;
} vdata[3];

out Data
{
    vec4 color;
} gdata;

void main()
{
    const vec4 green = vec4(0.0f, 1.0f, 0.0f, 1.0f);
    const vec4 blue = vec4(0.0f, 0.0f, 1.0f, 1.0f);

    for (int i = 0; i < 3; i++)
    {
        gl_Position = vdata[i].mvp * vdata[i].position;
        gdata.color = green;
        EmitVertex();

        gl_Position = vdata[i].mvp * (vdata[i].position + vdata[i].normal);
        gdata.color = blue;
        EmitVertex();

        EndPrimitive();
    }
}

片段着色器：

#version 330

in Data
{
    vec4 color;
} gdata;

out vec4 outputColor;

void main()
{
    outputColor = gdata.color;
}
于 2011-02-28T14:18:34.973 回答
50

嗯...您将法线作为varying变量进行插值，因此片段着色器应该接收正确的每像素法线。

唯一的解释（我能想到的）你得到的结果与左图一样，是给定面上的每个片段最终都会收到相同的 normal。您可以使用片段着色器来确认它，例如：

void main() {
   vFragColor = normalize(vVaryingNormal);
}

如果是这样，问题仍然存在：为什么？顶点着色器看起来不错。

所以也许你的几何有问题？您发送到着色器的数据是什么？你确定你已经正确计算了每个顶点的法线，而不仅仅是每个面的法线吗？

法线

橙色线是对角面的法线，红线是水平面的法线。

如果您的数据看起来像上面的图像，那么即使使用正确的着色器，您也会得到平坦的着色。确保您具有正确的每个顶点法线，如下图所示。（对于一个球体来说，它们真的很容易计算。）

于 2011-01-16T14:00:38.023 回答