0

我正在为 F5 负载均衡器制作 Nagios 的 Perl 插件。我必须将池名称转换为与 SNMP 的 OID 匹配的十进制格式。

my ( $PoolName )         = $ARGV[1];
my ( $rootOIDPoolStatus ) = '1.3.6.1.4.1.3375.2.2.5.5.2.1.2';

例如，$PoolName是"/Common/Atlassian"，我需要将其转换为/.C.o.m.m.o.n./.A.t.l.a.s.s.i.a.n ，然后转换为47.67.111.109.109.111.110.47.65.116.108.97.115.115.105.97.110

一旦转换完成，它们将被拉入一个变量

my ( $PoolStatus ) = "$rootOIDPoolStatus.$OIDPoolName"

我一直在为 Nagios 反向设计其他人的 Perl 插件，这就是其他人正在做的事情，但是无论我在做什么类型的组合，我都无法让它工作。他们$name将是我的$PoolName

sub to_oid($) {
    my $oid;
    my ($name) = $_[0];
    return "" if ( ! $name );
    $oid = ( length $name ) . '.' . ( join '.', ( map { unpack 'C', $ } ( split '',$name ) ) );
    return $oid;
}

有人可以帮助我构建或理解 Perl 逻辑，以便转换$PoolName为 OID 所需的十进制格式吗？

4

3 回答 3

2 
my $poolStatus = join '.', $rootOIDPoolStatus, map ord, split //, $poolName;

不确定代码中的 length() 是什么，您的示例中没有显示类似的内容。

于 2017-10-25T20:39:43.143 回答
2

您似乎正在使用字符串作为 SNMP 表的索引。表的索引可以被认为是该表的行号或行 ID。通常，表的索引只是一个从 1 开始并随着表的每一行而增加的数字。这样的数字按原样在 OID 中编码，即如果表有 3 列和 2 行，它们将具有以下 OID：

$base.1         # table
$base.1.1       # table entry
$base.1.1.1.1   # col1, row1
$base.1.1.1.2   # col1, row2
$base.1.1.2.1   # col2, row1
$base.1.1.2.2   # col2, row2
$base.1.1.3.1   # col3, row1
$base.1.1.3.2   # col3, row2
            ^---index

有时索引是一个 IP 地址，一个 IP:port 的组合，或者两个 IP 地址的组合，特别是对于 IP 相关的表。作为索引的 IP 地址如下所示：

$base.1                 # table
$base.1.1               # table entry
$base.1.1.1.1.0.0.127   # col1, row "127.0.0.1"
$base.1.1.1.0.0.0.0     # col1, row "0.0.0.0"
$base.1.1.2.1.0.0.127   # col2, row "127.0.0.1"
$base.1.1.2.0.0.0.0     # col2, row "0.0.0.0"
$base.1.1.3.1.0.0.127   # col3, row "127.0.0.1"
$base.1.1.3.0.0.0.0     # col3, row "0.0.0.0"
            ^^^^^^^---- index

如您所见，索引的长度取决于其数据类型（有一个专用的 IPV4 数据类型）。

有时索引是一个字符串（如您的情况）。当使用字符串时，它还必须以某种方式编码以构成表格的“行号”。作为索引的字符串是按字符编码的，并以它们的长度开头，即：

$base.1                     # table
$base.1.1                   # table entry
$base.1.1.1.2.65.66         # col1, row "AB"
$base.1.1.1.3.120.121.122   # col1, row "xyz"
$base.1.1.2.2.65.66         # col2, row "AB"
$base.1.1.2.3.120.121.122   # col2, row "xyz"
$base.1.1.3.2.65.66         # col3, row "AB"
$base.1.1.3.3.120.121.122   # col3, row "xyz"
            ^^^^^^^^^^^^^---- index

所以 "AB" 变成 "2.65.66" 因为length('AB')==2and ord('A')==65, ord('B')==66. 同样，“xyz”变成“3.120.121.122”。

您的功能to_oid正是这样做的，尽管我将其简化如下：

#!/usr/bin/env perl

use strict;
use warnings;

sub to_oid
{
    my $string = shift;
    return sprintf('%d.%s', length($string), join('.', unpack('C*', $string)));
}

my $rootOIDPoolStatus = '1.3.6.1.4.1.3375.2.2.5.5.2.1.2';
my $PoolName = '/Common/Atlassian';

my $poolname_oid = to_oid($PoolName);
my $complete_oid = "$rootOIDPoolStatus.$poolname_oid";

print $complete_oid, "\n";

输出：

1.3.6.1.4.1.3375.2.2.5.5.2.1.2.17.47.67.111.109.109.111.110.47.65.116.108.97.115.115.105.97.110
|<------- rootOID ----------->|<------------ poolname_oid ----...--->|
于 2017-10-26T10:51:43.127 回答
0 
my $PoolStatus = join('.', $rootOIDPoolStatus, unpack('C*', $PoolName));

或者

my $PoolStatus = sprintf("%s.%vd", $rootOIDPoolStatus, $PoolName);
于 2017-10-25T21:15:04.863 回答