1

我最近问了一个问题，关于在启用 OWL 推理的情况下将大约 1000 万条语句加载到三元存储库中的可行性。

这导致了一些 StackOverflow 评论以及我的研究小组内部关于我们是否真的需要 OWL 推理的讨论。

我将从一个似乎不需要OWL 推理的真实世界查询开始。

“41167-4120-0”是识别美国商业药品“盐酸非索非那定 180 MG 口服片剂 [Allegra]”的 NDC 代码。

NDC 的略微修改版本显示为药物本体中的标签（特别是文件dron-ndc.owl）：

http://purl.obolibrary.org/obo/DRON_00604430 rdfs:label "41167412000"

DrON 做出以下 OWL 断言：

http://purl.obolibrary.org/obo/DRON_00604430 is a packaged drug product 
    and is rdfs:subClass of 
    ( has_proper_part some http://purl.obolibrary.org/obo/DRON_00083688 )

http://purl.obolibrary.org/obo/DRON_00083688 
    rdfs:subClassOf http://purl.obolibrary.org/obo/DRON_00062350

http://purl.obolibrary.org/obo/DRON_00062350 has_proper_part some 
    (scattered molecular aggregate  
    and (is bearer of some active ingredient) 
    and (is bearer of some (mass and 
    (has measurement unit label value milligram) 
    and (has specified value <value> ))) 
    and (has granular part some fexofenadine))

ChEBI 说：

http://purl.obolibrary.org/obo/CHEBI_5050 rdfs:label "fexofenadine"
    subClassOf (has role some anti-allergic agent)

和

http://purl.obolibrary.org/obo/CHEBI_50857 rdfs:label "anti-allergic agent"

因此，为了将 NDC 代码和治疗角色联系起来，我可以编写如下查询

PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
select distinct 
?ndcval ?packdrugprod ?drugbrand ?brandlab ?drugform  ?api ?apilab ?drugrole
where {
    values ?ndcval {
        "41167412000" 
    }
    ?packdrugprod rdfs:subClassOf ?hasproppart ;
                  rdfs:label ?ndcval .
    ?hasproppart a owl:Restriction ;
                 owl:onProperty <http://www.obofoundry.org/ro/ro.owl#has_proper_part> ;
                 owl:someValuesFrom ?drugbrand .
    ?drugbrand rdfs:subClassOf ?drugform ;
               rdfs:label ?brandlab .
    ?drugform rdfs:subClassOf ?proppart .
    ?proppart a owl:Restriction ;
              owl:onProperty <http://www.obofoundry.org/ro/ro.owl#has_proper_part> ;
              owl:someValuesFrom ?valSource1 .
    ?valSource1 owl:intersectionOf ?intsect1 .
    # scat mol agg
    ?intsect1 rdf:first obo:OBI_0000576 .
    ?intsect1 rdf:rest ?scatmolag .
    ?scatmolag rdf:first ?bearacting .
    ?scatmolag rdf:rest ?intsect3 .
    # bearer of active ingredient
    ?bearacting a owl:Restriction ;
                owl:onProperty obo:BFO_0000053 ;
                owl:someValuesFrom obo:DRON_00000028 .
    ?intsect3 rdf:first ?granpart .
    ?intsect3 rdf:rest ?r .
    # has granular part fexofenadine
    ?granpart a owl:Restriction ;
              owl:onProperty obo:BFO_0000071 ;
              owl:someValuesFrom ?api .
    ?api rdfs:subClassOf ?rolerestr ;
         rdfs:label ?apilab .
    # has anti allergic role
    ?rolerestr a owl:Restriction ;
               owl:onProperty obo:RO_0000087 ;
               owl:someValuesFrom ?drugrole  .
    ?drugrole rdfs:label ?drlab .
    values ?drugrole {
        obo:CHEBI_50857 
    }
}

关注点：

如果不进行推理访问嵌套的子类关系呢？

上面的例子很简单，因为非索非那定被直接断言具有“抗过敏”作用

如果我对服用硝酸酯的人感兴趣怎么办？硝酸甘油是一种硝酸甘油，它又是一种硝酸酯。如果我使用没有启用推理的存储库，我将不得不显式使用属性路径来查找正在服用任何硝酸酯的患者，使用这样的片段（对吗？）

?s rdfs:subClassOf* <http://purl.obolibrary.org/obo/CHEBI_51080> .

那么推断个人所属的类别呢？

如果我的本体说类似

:ViagraPill owl:equivalentClass ( :pill 
    and (:hasColor some :blue ) 
    and (:hasShape some :diamond))
:steelBlue rdfs:subClassOf :blue

我有数据三元组，说的是

:patient1 :consumed :pill1 .
:pill1 :hasColor :steelBlue1 ;
    :hasShape :diamond1 .
:steelBlue1 a :steelBlue .
:diamond1 a :diamond.

我想为服用伟哥药片的患者写一个查询：

?patient a :patient ;
    :consumed ?pill .
?pill a :ViagraPill .

我需要某种形式的 OWL 推理，对吧？

4

1 回答 1

2

我一直认为 OBO 和其他生物、生命科学和农业本体使用数百万个课程但很少有人使用的趋势是错误的。

上述建模意味着对于 Allegra 的每个实例（每一个药丸、一个盒子或其他包装），您需要推断诸如“它是一个分散的分子聚集体”和“是某种活性成分的载体”和“有一些非索非那定的颗粒状部分”之类的陈述”。我觉得这很浪费。

最好将这些声明直接附加到药物定义中：作为简单声明，而不是作为限制。您可以通过两种方式做到这一点：

  1. 仍然将 Allegra 视为一个类，但使用双关语将道具直接附加到它
  2. 以 Allegra 为例，如果您需要描述单个药丸，请使用如下语句pill dct:type Allegra

然后您可以简单地通过其药物（类或非类）访问药丸属性：

?pill rdf:type ?drug. # or in Variant2: dct:type
?drug obo:RO_0000087 obo:CHEBI_50857. # has anti allergic role

它与您的查询类似，但更简单、更快，因为它会避免限制。

（至于需要解析rdf:Lists，这对本体创作者的意识来说一定是个沉重的负担）：

    ?intsect1 rdf:first obo:OBI_0000576 .
    ?intsect1 rdf:rest ?scatmolag .
    ?scatmolag rdf:first ?bearacting .
    ?scatmolag rdf:rest ?intsect3 .
    # bearer of active ingredient

这是您的 Viagram 示例的简化形式。我已经将命名法值变成了个体（ ） :blue，因为我认为它们没有理由成为类（对我来说毫无意义）。:diamondskos:Concept:steelBlue1

:ViagraPill a DrugForm;
  :hasColor :blue;
  :hasShape :diamond.
:steelBlue a skos:Concept;
  skos:broader :blue.

:patient1 :consumed :pill1.
:pill1 :hasColor :steelBlue; :hasShape :diamond.

颜色和形状是鉴别药物的必要条件但不是充分条件，因此?drugForm以下是该药丸的可能药物但不确定：

select ?patient ?drugForm {
  ?patient a :patient; :consumed ?pill.
  ?pill :hasColor ?color; :hasShape ?shape.
  ?drugForm :hasColor ?color1; :hasShape ?shape.
  ?color skos:broaderTransitive? ?color1
}

在这里，我使用了传递推理： pathskos:broaderTransitive?比 path 快skos:broader*。

推理不是全有或全无的事情：您可以从内置规则集中挑选您需要的规则。例如，如果您包含 RDFS 推理，那么您可以简化：

?x a ?s. ?s rdfs:subClassOf* :CHEBI_51080

只是

?x a :CHEBI_51080

默认的内置规则集 RDFS-Plus-optimized 包括 RDFS、逆和传递。有关更多建议，请参阅http://graphdb.ontotext.com/documentation/enterprise/rules-optimisations.html。

你可能会反对：“你不是说你会直接将道具附加到药物（类）上吗？你怎么也将它们附加到:pill1上面？”。

我认为这很好：我们可以将这些道具声明为具有 domain :DrugIndividual or :DrugForm or :Drug，并将它们解释为:DrugIndividual对于:DrugForm and :Drug. 顺便说一句，我喜欢使用schema:domainIncludes ...而不是声明多态域rdfs:range [a owl:Class; owl:unionOf (...)]。

如果您不想将道具附加到吸毒者（实例），那么您必须对药丸使用“未知类”，例如：

:patient1 :consumed :pill1.
:pill1 a [:hasColor :steelBlue; :hasShape :diamond].

在查询中具有相应的轻微复杂性：

select ?patient ?drugForm {
  ?patient a :patient; :consumed ?pill.
  ?pill a [:hasColor ?color; :hasShape ?shape].
  ?drugForm :hasColor ?color1; :hasShape ?shape.
  ?color skos:broaderTransitive? ?color1
}

总结一下：

  • GraphDB 不支持 OWL DL，它支持 QL 和 RL。
  • OBO 风格的本体使用数百万个类，它规定了从类限制到个体的一大堆道具的推理；我觉得这很浪费。
于 2020-09-18T06:43:05.180 回答