2

C++ 17 引入了许多新算法来支持并行执行，特别是std::reduce是std::accumulate的并行版本，它允许操作non-deterministic行为non-commutative，例如浮点加法。我想使用 OpenCL 2 实现减少算法。

英特尔在这里有一个示例，它使用 OpenCL 2work group内核函数来实现std::exclusive_scan OpenCL 2 内核。以下是基于英特尔exclusive_scan示例的内核对浮点数求和：

kernel void sum_float (global float* sum, global float* values)
{
  float sum_val = 0.0f;

  for (size_t i = 0u; i < get_num_groups(0); ++i)
  {
    size_t index = get_local_id(0) + i * get_enqueued_local_size(0);
    float value = work_group_reduce_add(values[index]);
    sum_val += work_group_broadcast(value, 0u);
  }

  sum[0] = sum_val;
}

上面的内核工作（或似乎！）。但是，exclusive_scan需要work_group_broadcast函数将 one 的最后一个值传递work group给下一个，而这个内核只需要将 work_group_reduce_add 的结果添加到sum_val，因此atomic add更合适。

OpenCL 2 提供了一个atomic_int支持atomic_fetch_add. 上面使用 atomic_int 的内核的整数版本是：

kernel void sum_int (global int* sum, global int* values)
{
  atomic_int sum_val;
  atomic_init(&sum_val, 0);

  for (size_t i = 0u; i < get_num_groups(0); ++i)
  {
    size_t index = get_local_id(0) + i * get_enqueued_local_size(0);
    int value = work_group_reduce_add(values[index]);
    atomic_fetch_add(&sum_val, value);
  }

  sum[0] = atomic_load(&sum_val);
}

OpenCL 2 也提供了一个，atomic_float但它不支持atomic_fetch_add.

实现 OpenCL2 内核对浮点数求和的最佳方法是什么？

4

1 回答 1

1 
kernel void sum_float (global float* sum, global float* values)
{
  float sum_val = 0.0f;

  for (size_t i = 0u; i < get_num_groups(0); ++i)
  {
    size_t index = get_local_id(0) + i * get_enqueued_local_size(0);
    float value = work_group_reduce_add(values[index]);
    sum_val += work_group_broadcast(value, 0u);
  }

  sum[0] = sum_val;
}

这有一个竞争条件将数据写入 sum 的零索引元素，所有工作组都在做相同的计算，这使得这个 O(N*N) 而不是 O(N) 并且需要超过 1100 毫秒来完成一个 1M 元素数组和.

对于相同的 1-M 元素数组， this(global=1M, local=256)

kernel void sum_float2 (global float* sum, global float* values)
{
      float sum_partial = work_group_reduce_add(values[get_global_id(0)]);
      if(get_local_id(0)==0)
        sum[get_group_id(0)] = sum_partial; 
}

其次是这个（全局=4k，本地=256）

kernel void sum_float3 (global float* sum, global float* values)
{
  float sum_partial = work_group_reduce_add(sum[get_global_id(0)]);
  if(get_local_id(0)==0)
    values[get_group_id(0)] = sum_partial; 
}

除了第三步之外，在几毫秒内完成同样的事情。第一个将每个组的总和放入他们的 group-id 相关项，第二个内核将这些总和成 16 个值，这 16 个值可以很容易地由 CPU 求和（微秒或更短）（作为第三步）。

程序是这样工作的：

values: 1.0 1.0 .... 1.0 1.0 
sum_float2
sum: 256.0 256.0 256.0
sum_float3
values: 65536.0 65536.0 .... 16 items total to be summed by cpu

如果你需要使用原子，你应该尽可能少地使用它。最简单的例子可以是使用局部原子对每个组的许多值求和，然后使用每个组的单个全局原子函数来执行最后一步以将所有值相加。我目前还没有为 OpenCL 准备好 C++ 设置，但我猜当您使用具有相同内存资源的多个设备（可能是流模式或在 SVM 中）和/或使用 C++17的CPU时，OpenCL 2.0 atomics 会更好职能。如果您没有多个设备同时在同一区域进行计算，那么我认为这些新的原子只能是在已经工作的 OpenCL 1.2 原子之上的微优化。我没有使用这些新的原子，所以把所有这些当成一粒盐。

于 2017-10-21T12:06:09.973 回答