2

我试图在 F# 中表达 Free monad 的 Church 编码。Free专门用于特定的函子，Effect.

我可以同时写return_ : 'T -> Free<'T>，bind: ('T -> Free<'U>) -> Free<'T> -> Free<'U>没有任何问题。

下面给出了我的实现草图。

type Effect<'T>
    = GetStr of (string -> 'T)
    | PutStr of string * 'T


module Effect = 

    let map (f: 'a -> 'b) : Effect<'a> -> Effect<'b> = function
        | GetStr k -> 
            GetStr(f << k)

        | PutStr (s,t) -> 
            PutStr(s, f t)


type Free<'T> =
    abstract Apply : ('T -> 'R) -> (Effect<'R> -> 'R) -> 'R

module Free = 
    let inline runFree (f:Free<'T>) (kp: 'T -> 'R) (kf: Effect<'R> -> 'R) : 'R = 
        f.Apply kp kf

    let return_ (x: 'a) : Free<'a> = 
        { new Free<'a>
            with
                member __.Apply kp _ = 
                    kp x
        }

    let bind (f: 'a -> Free<'b>) (m: Free<'a>) : Free<'b> = 
        { new Free<'b>
            with
                member __.Apply kp kf = 
                    runFree m
                        (fun a -> 
                            runFree (f a) kp kf
                        )
                        kf
        }

当我尝试为这种编码编写解释器时，我遇到了一个问题。

给定以下代码：

module Interpret = 

    let interpretEffect = function 
        | GetStr k -> 
            let s = System.Console.ReadLine()             
            (k s , String.length s)

        | PutStr(s,t) -> 
            do System.Console.WriteLine s 
            (t , 0) 

    let rec interpret (f: Free<string * int>) = 
        Free.runFree
            f
            (fun (str,len) -> (str,len))
            (fun (a: Effect<Free<string*int>>) -> 
                let (b,n) = interpretEffect a 
                let (c,n') = interpret b 
                (c, n + n')
            )

Free.runFree我在函数内的第三个参数中收到类型错误interpret：

...

(fun (a: Effect<Free<string*int>>) -> 
      ^^^^^^^^^^^^^^^^^^ ------ Expecting a Effect<string * int> but given a Effect<Free<string*int>>

我理解为什么会发生这种情况（第一个函数的结果类型确定'R === string*int）并怀疑可以使用 rank-2 函数来解决（可以在 F# 中编码，例如http://eiriktsarpalis.github.io/typeshape/#/ 33 ) 但我不知道如何应用它。

任何指针将不胜感激。

迈克尔

4

1 回答 1

1

你不需要在那里做任何事情，编译器建议的类型实际上是正确的（并且符合 的类型runFree）。

看来您正在考虑的是 Scott 编码（从这个 Haskell 问题中提取）：

runFree :: Functor f => (a -> r) -> (f (F f a) -> r) -> F f a -> r

F f a你的Effect-specialised会在哪里Free<'a>，并且f (F f a)会Effect<Free<'a>>是你想要使用的东西。

而 Church 编码将是：

runFree :: Functor f => (a -> r) -> (f r -> r) -> F f a -> r

where f ris Effect<'a>- 从而更容易在 F# 中表达（这就是为什么我假设您首先使用它的原因。

这就是我想要的interpret：

let rec interpret (f: Free<string * int>) = 
    Free.runFree
        f
        (fun (str,len) -> (str,len))
        (fun (a: Effect<_>) -> 
            let (b,n) = interpretEffect a 
            let (c,n') = interpret (Free.pureF b)
            (c, n + n')
        )

pureF在哪里

let pureF (x: 'a) : Free<'a> = 
    { new Free<'a> with member __.Apply kp _ = kp x }

即你的return_功能。

我认为定义相应的freeF函数会清除一些事情（比如为什么是Effect<'a>函子——你没有在你粘贴的代码中的任何地方使用这个事实）。

于 2017-10-22T16:54:10.677 回答