1

在 proc 报告中，我很难在第二级（高级术语 1）或第三级之前获得缩进，依此类推。

在此处输入图像描述

当我使用 style(column)=[cellwidth=6.5 cm JUST=LEFT asis=on] 时，我会缩进，但由于句子长度，连续的下一行从开头开始。例如：

在此处输入图像描述

有没有办法让不同级别的缩进对齐？

这是我的 proc 报告程序：

proc report data=final nowindows  split='~' headline headskip contents='' formchar(2)='_' missing spacing=1;
    *by seq seq_c1 seq_trt;
    columns  sqn seq ord cat _c1 - _c6;

    define sqn / group order=data noprint;
    define seq / group order=data noprint;
    define ord /display order=data noprint;

    define cat     / display  order=data style(column)=[cellwidth=6.5 cm JUST=LEFT asis=on]  style(header)=[JUST=LEFT] flow ;

    define _c1  / display order = data style(column)=[cellwidth=2.8 cm JUST=LEFT] style(header)=[JUST=Center] ;
    define _c2  / display order = data style(column)=[cellwidth=2.8 cm JUST=LEFT] style(header)=[JUST=Center];
    define _c3  / display order = data style(column)=[cellwidth=2.8 cm JUST=LEFT] style(header)=[JUST=Center];
    define _c4  / display order = data style(column)=[cellwidth=2.8 cm JUST=LEFT] style(header)=[JUST=Center];
    define _c5  / display order = data style(column)=[cellwidth=2.8 cm JUST=LEFT] style(header)=[JUST=Center];
    define _c6  / display order = data style(column)=[cellwidth=2.8 cm JUST=LEFT] style(header)=[JUST=Center];

    compute cat;
        if ord=3 then  do; cat='   '||cat;  end;
        if ord=4 then do; cat='      '||cat;  end;
    endcomp;

    compute after sqn;
        line '';
    endcomp;

run;

谢谢你。

这是一个生成数据的小代码：

data check;
length sqn 8. cat $100.;
input  sqn   cat $;
datalines;
1   Uncoded
2   Uncoded
3   ABNORMAL-MENSTRUATION-DIAGNOSTIC-CURETTAGE-OF-THE-UTERINE-CAVITY.
3   ANXIETY
3   CARPAL-TUNNEL-SYNDROME
3   EXACERBATION
 ;
run;
4

1 回答 1

0

我会通过使用实际的样式元素来解决这个问题，而不是手动添加空格。这LEFTMARGIN可能是正确的方法，尽管有时有一种INDENT风格更可取；我想得到LEFTMARGIN你想要的。

你可以在http://communities.sas.com上看到一些问题，比如这个，有类似的请求和答案（我用那个问题作为这个答案的参考）。

data check;
length sqn 8. cat $100 _c1-_c6 $16;
array _c[6] $ (6*"TestingText");
input  sqn   cat $;
seq=_n_;
ord = _n_;
datalines;
1   Uncoded
2   Uncoded
3   ABNORMAL-MENSTRUATION-DIAGNOSTIC-CURETTAGE-OF-THE-UTERINE-CAVITY.
3   ANXIETY
3   CARPAL-TUNNEL-SYNDROME
3   EXACERBATION
 ;
run;
ods pdf file="c:\temp\test.pdf";
proc report data=check nowindows  split='~' headline headskip contents='' formchar(2)='_' missing spacing=1;
    *by seq seq_c1 seq_trt;
    columns  sqn seq ord cat _c1 - _c6;

    define sqn / group order=data noprint;
    define seq / group order=data noprint;
    define ord /display order=data noprint;

    define cat     / display  order=data style(column)=[cellwidth=6.5 cm JUST=LEFT asis=on]  style(header)=[JUST=LEFT] flow ;

    define _c1  / display order = data style(column)=[cellwidth=2.8 cm JUST=LEFT] style(header)=[JUST=Center] ;
    define _c2  / display order = data style(column)=[cellwidth=2.8 cm JUST=LEFT] style(header)=[JUST=Center];
    define _c3  / display order = data style(column)=[cellwidth=2.8 cm JUST=LEFT] style(header)=[JUST=Center];
    define _c4  / display order = data style(column)=[cellwidth=2.8 cm JUST=LEFT] style(header)=[JUST=Center];
    define _c5  / display order = data style(column)=[cellwidth=2.8 cm JUST=LEFT] style(header)=[JUST=Center];
    define _c6  / display order = data style(column)=[cellwidth=2.8 cm JUST=LEFT] style(header)=[JUST=Center];

    compute cat;
        if ord=3 then  call define('cat','style','style={leftmargin=0.1in}');
        if ord=4 then  call define('cat','style','style={leftmargin=0.2in}');      
    endcomp;

    compute after sqn;
        line '';
    endcomp;

run;
ods pdf close;
于 2017-10-02T21:23:08.673 回答