json - 解析 JSON haskell

Question

我正在尝试访问Object我的请求中的内部。这是我的代码：

{-# LANGUAGE OverloadedStrings #-}


import Network.Wreq
import Control.Lens
import Data.Aeson

import Data.Map as Map

type Resp = Response (Map String Value)


main = do
    r <- asJSON =<< get "https://bittrex.com/api/v1.1/public/getticker?market=BTC-LTC" :: IO Resp
    let result = (r ^. responseBody)    
    print result

这是我的结果：

fromList [("message",String ""),("result",Object (fromList [("Bid",Number 1.441e-2),("Ask",Number 1.44101e-2),("Last",Number 1.441e-2)])),("success",Bool True)]

我正在尝试访问“结果”键的对象，然后访问其中的值。我不知道该怎么做，我已经搞砸了 AESON 和提供的^?运营商，wreq但它对我不起作用。

Answer 1

{-# LANGUAGE OverloadedStrings #-}

import Control.Lens
import Network.Wreq
import Data.Aeson.Lens

import Data.HashMap.Lazy (HashMap)
import Data.Text (Text)

main = do
  r <- asValue =<< get "https://bittrex.com/api/v1.1/public/getticker?market=BTC-LTC"
  let result =
        (r :: Response Value)
          -- get the Value out of the Response
          ^? responseBody
          -- The Value must be an Object, then unwrap the contained (HashMap Text Value)
          . _Object
          -- In the map {"message": ..., "result": ...}, get the "result".
          . ix "result"
          -- This must be an Object, unwrap the (HashMap Text Value)
          . _Object
  print (result :: HashMap Text Value)

-- How types line up:
--
-- responseBody . _Object . ix "result" . _Object
--         :: Traversal' (Response Value)                                  (HashMap Text Value)

--
-- responseBody :: Lens' (Response Value) Value
-- _Object      ::             Traversal' Value (HashMap Text Value)
-- ix "result"  ::                   Traversal' (HashMap Text Value) Value
-- _Object      ::                                        Traversal' Value (HashMap Text Value)