4

我正在编写一个 .nix 表达式，主要由 .nix 使用nix-shell。我不知道该怎么做。请注意，这不在 NixOS 上，但我认为这不是很相关。

我正在查看的特定示例是我想获得这个与版本相关的名称，如下所示：

  idea-ultimate = buildIdea rec {
    name = "idea-ultimate-${version}";
    version = "2017.2.2"; /* updated by script */
    description = "Integrated Development Environment (IDE) by Jetbrains, requires paid license";
    license = stdenv.lib.licenses.unfree;
    src = fetchurl {
      url = "https://download.jetbrains.com/idea/ideaIU-${version}-no-jdk.tar.gz";
      sha256 = "b8eb9d612800cc896eb6b6fbefbf9f49d92d2350ae1c3c4598e5e12bf93be401"; /* updated by script */
    };
    wmClass = "jetbrains-idea";
    update-channel = "IDEA_Release";
  };

我的 nix 表达式如下：

let
  pkgs = import <nixpkgs> {};
  stdenv = pkgs.stdenv;
  # idea_name = assert pkgs.jetbrains.idea-ultimate.name != ""; pkgs.jetbrains.idea-ultimate.name;
in rec {
  scalaEnv = stdenv.mkDerivation rec {
    name = "scala-env";
    builder = "./scala-build.sh";
    shellHook = ''
    alias cls=clear
    '';
    CLANG_PATH = pkgs.clang + "/bin/clang";
    CLANGPP_PATH = pkgs.clang + "/bin/clang++";
    # A bug in the nixpkgs openjdk (#29151) makes us resort to Zulu OpenJDK for IDEA:
    # IDEA_JDK = pkgs.openjdk + "/lib/openjdk";
    # PATH = "${pkgs.jetbrains.idea-ultimate}/${idea_name}/bin:$PATH";
    IDEA_JDK = /usr/lib/jvm/zulu-8-amd64;
    # IDEA_JDK = /opt/zulu8.23.0.3-jdk8.0.144-linux_x64;
    # IDEA_JDK = /usr/lib/jvm/java-8-openjdk-amd64;
    buildInputs = with pkgs; [
      ammonite
      boehmgc
      clang
      emacs
      jetbrains.idea-ultimate
      less
      libunwind
      openjdk
      re2
      sbt
      stdenv
      unzip
      zlib
    ];
  };
}

我已经注释掉了设置PATH，因为它取决于进入idea_name-let子句。作为一个有趣的旁注，如果我不加注释，这不会失败，但是在执行时会导致一个非常奇怪的错误，因为nix-shellnot able to execute bash。我也尝试过更简单的情况，let idea_name = pkgs.jetbrains.idea-ultimate.name;但后来idea_name在设置中使用时失败，PATH因为idea_name最终未定义。

更新：

我开始探索nix-instantiate，但兴趣的推导似乎是空的：

[nix-shell:/nix/store]$ nix-instantiate --eval --xml -E "((import <nixpkgs> {}).callPackage ./3hk87pqgl2qdqmskxbhy23cyr24q8g6s-nixpkgs-18.03pre114739.d0d905668c/nixpkgs/pkgs/applications/editors/jetbrains { }).idea-ultimate";  


<?xml version='1.0' encoding='utf-8'?>
<expr>
  <derivation>
    <repeated />
  </derivation>
</expr>
4

1 回答 1

4

如果您的意图是idea-ultimate进入 nix-shell 环境，那么只需将该包包含到buildInputs. 我看到它已经包含在内，所以它应该已经存在于你的PATH.

顺便说一句，您可以扩展shellHook和导出 PATH 和其他变量，而不是从那里获得完整的 bash。你为什么要从 bash 做呢？少抄袭。当您指定

IDEA_JDK = /usr/lib/jvm/zulu-8-amd64;

在 Nix 中，文件 /usr/lib/jvm/zulu-8-amd64 被复制到 nix 存储并IDEA_JDK设置为指向/nix/store. 那是你的意图吗？

关于 nix 实例化：

$ nix-instantiate --eval -E 'with import <nixpkgs>{}; idea.pycharm-community.outPath'                                                                                   
"/nix/store/71jk0spr30rm4wsihjwbb1hcwwvzqr4k-pycharm-community-2017.1"

但您仍然必须删除双引号（https://gist.github.com/danbst/a9fc068ff26e31d88de9709965daa2bd）

此外，nitpickassert pkgs.jetbrains.idea-ultimate.name != "";可以被删除，因为在 Nix 中不可能有空的派生名称。

另一个挑剔。您很快就会发现每次都从 shell 启动 IDE 非常不方便。指定某些包用于开发似乎是个好主意，但nix-shell不适用于非 cli 应用程序。更不用说 Nix GC 和nix-shell. 您最好全局或按用户安装 IDE，这是更好的长期解决方案。

[附录]

您正在寻找这个 ( dev-environment.nix)：

with import <nixpkgs> { };

buildEnv {
  name = "my-super-dev-env";
  paths = [
      #emacs
      nano
      idea.pycharm-community
  ];
  buildInputs = [ makeWrapper ];
  postBuild = ''
    for f in $(ls -d $out/bin/*); do
      wrapProgram $f \
        --set IDEA_JDK "/path/to/zulu-jdk" \
        --set CLANG_PATH ... \
        --set CLANCPP_PATH ...
    done
  '';
}

您使用nix-env -if ./dev-environment.nix. 它将使用这些环境变量包装您的程序，而不会污染您的工作区（如果nix-shell需要，您可以使用 shell 挂钩进一步污染它）。

于 2017-09-12T09:41:48.680 回答