29

我想知道在 dunit 中测试异常的最佳实践是什么。我对 Delphi 中的方法指针不是很熟悉。是否有可能将参数绑定到方法指针，以便可以在没有参数的情况下调用它。目前我总是写一个额外的方法来手动执行这个“绑定”。如果 SUT 有很多投掷方法，这会很烦人。

// What i did before i knew abput CheckExcepion
procedure MyTest.MyMethod_BadInput_Throws;
var
    res: Boolean;
begin
    res := false;
    try
        sut.MyMethod('this is bad');
    except
        on e : MyExpectedException do:
            res := true;
    end;
    CheckTrue(res);
end;

// What i do now
procedure MyTest.MyMethodWithBadInput;
begin
    sut.MyMethod('this is bad');
end;

procedure MyTest.MyMethod_BadInput_Throws;
begin
    CheckException(MyMethodWithBadInput, MyExpectedException);
end;

// this would be nice
procedure MyTest.MyMethod_BadInput_Throws;
begin
    CheckException(
        BindArguments(sut.MyMethod, 'this is bad'),  // <-- how to do this
        MyExpectedException);
end;
4

5 回答 5

45

您可以使用StartExpectingException来包围您的方法调用）。

StartExpectingException(MyException);
MyMethod(MyParam);
StopExpectingException();
于 2011-01-06T10:12:14.833 回答
3

我不知道 DUnit 是否支持它，但这是 Delphi 2010 中引入的匿名方法的完美用例。如果 DUnit 不支持它，那么您可以轻松地自己修改源代码。

于 2011-01-06T09:25:56.793 回答
3

如前所述，这是匿名方法的好地方。

这是我的做法。我从 Alex Ciobanu 那里“借用”了这个：

procedure TestTMyClass.CheckException(aExceptionType: TClassOfException; aCode: TTestCode; const aMessage: String);
var
  WasException: Boolean;
begin
  WasException := False;
  try
    aCode;
  except
    on E: Exception do
    begin
      if E is aExceptionType then
      begin
        WasException := True;
      end;
    end;
  end;
  Check(WasException, aMessage);
end;

然后用类似的东西调用它：

CheckException(ETestingException, 
             procedure begin FMyClass.RaiseTestingException end,      
             'The ETestingException exception didn''t get raised.  That is impossible!');
于 2011-04-10T23:58:01.530 回答
2

StartExpectingException()如果您想测试一个以上的异常情况，使用并不是最好的方法。为了在我的测试过程中测试所有可能的情况，除了例外，我使用这个算法：

uses
  Dialogs;
procedure MyTest.MyMethod_Test;
begin
  // Test for Exceptions
  try
    MyMethod(MyParam1CreatingException1);
    ShowMessage('Error! There should have been exception: Exxx here!');
    Check(false);
  except on E: Exception do Check(E is  ExceptionType1); end; // This exception is OK
  try
    MyMethod(MyParam2CreatingException2);
    ShowMessage('Error! There should have been exception: Exxx here!');
    Check(false);
  except on E: Exception do Check(E is  ExceptionType2); end; // This exception is OK
  // ... test other exceptions ...

  // Test other parameters
  CheckEquals('result1', MyMethod(MyParam1));
  CheckEquals('result2', MyMethod(MyParam2));
  // ... other tests ...
end;

我使用ShowMessage('Error! There should be exception: Exxx here!'); 而不是提供的Check(false, 'There should have been an EListError.');方法的原因是在我的情况下（Delphi6）Check(boolean, 'Message')不起作用 - 如果 Check 在try...except块内（不知道为什么），它不会显示消息。

于 2013-08-05T04:17:24.970 回答
0

这是尼克霍奇斯答案的工作和改进版本，它是 DUnit 的子类TestFramework.TTestCase：

uses
  TestFramework, System.SysUtils;
type
  TTestCode = reference to procedure;

  TTestCasePlus = class(TestFramework.TTestCase)
    procedure CheckException(
      ExceptionType: TClass; Code: TTestCode; const Message: String = '');
  end;

implementation

procedure TTestCasePlus.CheckException(
  ExceptionType: TClass; Code: TTestCode; const Message: String = '');
{ Check whether some code raises a specific exception type.

Adapted from http://stackoverflow.com/a/5615560/797744

Example:

  Self.CheckException(EConvertError,
                      procedure begin UnformatTimestamp('invalidstr') end);

@param ExceptionType: The exception class which we check if it was raised.
@param Code: Code in the form of an anonymous method that should raise the
  exception.
@param Message: Output message on check failure. }
var
  WasRaised: Boolean;
begin
  WasRaised := False;
  try
    Code;
  except
    on E: Exception do
      if E is ExceptionType then
        WasRaised := True;
  end;
  Check(WasRaised, Message);
end;

这种检查是否引发异常的方法的一个不错的好处Start/StopExpectingException()是，您可以在调试版本中运行测试运行程序，并且它不会一直困扰您“引发异常。中断？继续？” 每次引发异常时——即使它已被处理。

于 2016-03-17T11:38:22.203 回答