2

我是 prolog 的新手,为了提高我的技能,我正在尝试做一些锻炼。目前我被 BFS 困住了,假设树是这样的:

[tree(tree(tree(nil,b,nil),a,tree(tree(nil,d,nil),c,tree(nil,e,nil)))]

在我的查询之后,我有类似的东西

X=a;

X=b;

X=c;

X=d;

X=e;

或者至少:

X=a,b,c,d,e;

我想知道如何将结果按深度级别排序为输出,例如:

X=[a];

X=[b,c];

X=[d,e];

或者,在最好的情况下,类似:

X=[ [a] , [b,c] , [d,e] ];

帮助!

4

2 回答 2

1

我有一个解决方案,但它不是特别有效。我将树实现为一组三个元素列表,如 [Element, Left, Right],但它应该工作相同。

% returns a list of nodes at the given level of the tree
level( [], _, [] ).
level( [Element, _, _], 0, [Element] ) :- !.
level( [_, Left, Right], N, Result ) :-
    NewN is N - 1,
    level( Left, NewN, LeftResult ),
    level( Right, NewN, RightResult ),
    append( LeftResult, RightResult, Result ).

% does a bfs, returning a list of lists, where each inner list
% is the nodes at a given level
bfs( Tree, Result ) :-
    level( Tree, 0, FirstLevel ), !,
    bfs( Tree, 1, FirstLevel, [], BFSReverse ),
    reverse( BFSReverse, Result ).
bfs( _, _, [], Accum, Accum ) :- !.
bfs( Tree, Num, LastLevel, Accum, Result ) :-
    level( Tree, Num, CurrentLevel ), !,
    NewNum is Num + 1,
    bfs( Tree, NewNum, CurrentLevel, [LastLevel|Accum], Result ).

应该可以在 O(n) 中执行此操作,但这是 O(n^2)。我开始研究另一种解决方案,该解决方案返回 O(n) 中每个元素的级别,但我不确定如何将该列表转换为 O(n) 中的解决方案格式而不诉诸断言/撤回。

于 2011-01-06T07:28:31.520 回答
0

更好的解决方案,这次是 O(n)。它仍然有点难看,因为我将实际的 BFS 与解决方案处理分开,但应该这样做。

bfs2( Tree, Result ) :-
    bfs_queue( [[Tree, 0]], Queue ),
    queue_to_result( Queue, Result ).
bfs_queue( [], [] ) :- !.
bfs_queue( [[[],_]|Rest], RestResult ) :-
    !, bfs_queue( Rest, RestResult ).
bfs_queue( [[[Element, Left, Right], Level]|Rest], [[Element,Level]|RestResult] ) :-
    NextLevel is Level + 1,
    append( Rest, [[Left, NextLevel], [Right, NextLevel]], NewQueue ), !,
    bfs_queue( NewQueue, RestResult ).

process_level( [[Item, Level]|Rest], Level, [Item|RestResult], OutOfLevel ) :-
    !, process_level( Rest, Level, RestResult, OutOfLevel ).
process_level( OutOfLevel, _, [], OutOfLevel ) :- !.
queue_to_result( Queue, Result ) :-
    !, queue_to_result( Queue, 0, Result ).
queue_to_result( [], _, [] ) :- !.
queue_to_result( Queue, Level, [Current|Result] ) :-
    !, process_level( Queue, Level, Current, NewQueue ),
    NewLevel is Level + 1,
    queue_to_result( NewQueue, NewLevel, Result ).

同样,我将树表示为三个元素列表。

于 2011-01-06T09:37:03.230 回答