8

我试图在谷歌图表中调整这个例子。为re-frame框架，reagent. 我想根据订阅创建一个实时图表。我用一个简单的计数器 =+-1 进行了测试。

我得到错误： Assert failed: Render must be a function, not nil (ifn? render-fun)。

(defn draw-demo-chart 
   [d]
   (let [[columns vectors options chart] (r/children d)
         data (new js/google.visualization.DataTable)]
       (doall ;gotta keep the doall on maps. lazy sequence...
      (map (fn [[type name]]
            (.addColumn data type name)) columns))
      (.addRows data vectors)
      (.draw chart data options)
      (.load js/google "visualization" "1" (clj->js {:packages ["corechart" "orgchart" "calendar" "map" "geochart"]}))     
      (.setOnLoadCallback js/google draw-demo-chart)
      ))


(defn draw-demo-chart-container
    []
    (let [count    (re-frame/subscribe [:count])
          columns  (reaction [["date" "X"] ["number" "Y"]])
          vectors  (reaction (clj->js [[(new js/Date "07/11/14") 145] [(new js/Date "07/12/14") 15]
                                      [(new js/Date "07/13/14") 23] [(new js/Date "07/14/14") 234]]))
          options  (reaction (clj->js {:title (str @count)}))
          chart    (reaction (new js/google.visualization.LineChart (.getElementById js/document "linechart"))) ]
     (fn []
        [draw-demo-graph @columns @vectors @options @chart])))

(def draw-demo-graph 
       (r/create-class {:reagent-render  draw-demo-chart
                        :component-did-mount draw-demo-chart
                        :component-did-update draw-demo-chart}))
4

1 回答 1

5

使用 Google Charts API 有几个挑战：

  1. 它异步加载，只有在准备好时才能使用。

我建议使用一个标志来记录 API 是否准备好，这将允许它在组件安装后加载 API 时渲染。

(defonce ready?
  (reagent/atom false))

(defonce initialize
  (do
    (js/google.charts.load (clj->js {:packages ["corechart"]}))
    (js/google.charts.setOnLoadCallback
      (fn google-visualization-loaded []
        (reset! ready? true)))))
  1. 您需要调用draw一个 HTML 元素：

只有在组件已安装时，HTML 元素才会存在。您可以使用 aref方便地获取 HTML 元素（否则您需要在挂载时保存对 in 的引用或搜索它）。

(defn draw-chart [chart-type data options]
  [:div
   (if @ready?
     [:div
      {:ref
       (fn [this]
         (when this
           (.draw (new (aget js/google.visualization chart-type) this)
                  (data-table data)
                  (clj->js options))))}]
     [:div "Loading..."])])

您需要在任何输入发生变化时重绘（上面的ref例子就是这样）。

  1. 设置数据源

我建议一种获取数据源的便捷方法：

(defn data-table [data]
  (cond
    (map? data) (js/google.visualization.DataTable. (clj->js data))
    (string? data) (js/google.visualization.Query. data)
    (seqable? data) (js/google.visualization.arrayToDataTable (clj->js data))))
  1. 用它

现在您可以将图表与反应值一起使用！

[draw-chart
    "LineChart"
    @some-data
    {:title (str "Clicks as of day " @day)}]

完整的代码清单在 https://github.com/timothypratley/google-chart-example

于 2017-09-03T21:29:14.977 回答