确实，DOS 没有为我们提供直接输出数字的功能。
您必须首先自己转换数字，然后让 DOS 使用其中一个文本输出函数显示它。
显示 AX 中保存的无符号 16 位数
在处理数字转换问题时，有助于了解组成数字的数字之间的关系。
让我们考虑数字 65535 及其分解：
(6 * 10000) + (5 * 1000) + (5 * 100) + (3 * 10) + (5 * 1)
方法1：10的递减除法
处理从左到右的数字很方便，因为它允许我们在提取单个数字后立即显示它。
通过将数字 (65535) 除以10000，我们得到一个位数的商 (6)，我们可以立即将其作为字符输出。我们还得到了一个余数（5535），它将成为下一步的股息。
通过将上一步 (5535) 的余数除以1000，我们得到一个位数的商 (5)，我们可以立即将其作为字符输出。我们还得到了一个余数（535），它将成为下一步的红利。
通过将上一步 (535) 的余数除以100，我们得到一个位数的商 (5)，我们可以立即将其作为字符输出。我们还得到一个余数（35），它将成为下一步的股息。
通过将上一步 (35) 的余数除以10，我们得到一个位数的商 (3)，我们可以立即将其作为字符输出。我们还得到一个余数 (5)，它将成为下一步的红利。
通过将上一步 (5) 的余数除以1，我们得到一个位数的商 (5)，我们可以立即将其作为字符输出。这里余数总是 0。（避免这种愚蠢的除以 1 需要一些额外的代码）
mov bx,.List
.a: xor dx,dx
div word ptr [bx] ; -> AX=[0,9] is Quotient, Remainder DX
xchg ax,dx
add dl,"0" ;Turn into character [0,9] -> ["0","9"]
push ax ;(1)
mov ah,02h ;DOS.DisplayCharacter
int 21h ; -> AL
pop ax ;(1) AX is next dividend
add bx,2
cmp bx,.List+10
jb .a
...
.List:
dw 10000,1000,100,10,1
虽然这种方法当然会产生正确的结果，但它有一些缺点：
考虑较小的数字 255 及其分解：
(0 * 10000) + (0 * 1000) + (2 * 100) + (5 * 10) + (5 * 1)
如果我们使用相同的 5 步过程，我们会得到“00255”。这两个前导零是不可取的，我们必须包含额外的指令来消除它们。
分隔线随每一步而变化。我们必须在内存中存储一个分隔符列表。动态计算这些除法器是可能的，但会引入许多额外的除法器。
如果我们想将此方法应用于显示更大的数字（例如 32 位），并且我们最终会希望这样做，那么所涉及的除法将变得非常有问题。
所以方法1是不切实际的，因此很少使用。
方法 2：除以 const 10
处理从右到左的数字似乎违反直觉，因为我们的目标是首先显示最左边的数字。但正如您即将发现的那样，它工作得很好。
通过将数字 (65535) 除以10，我们得到一个商 (6553)，它将成为下一步的被除数。我们还得到了一个我们还不能输出的余数（5），所以我们必须保存在某个地方。堆栈是一个方便的地方。
通过将上一步的商 (6553) 除以10，我们得到一个商 (655)，它将成为下一步的被除数。我们还得到了一个我们还不能输出的余数（3），所以我们必须把它保存在某个地方。堆栈是一个方便的地方。
通过将上一步 (655) 的商除以10，我们得到一个商 (65)，它将成为下一步的被除数。我们还得到了一个我们还不能输出的余数（5），所以我们必须把它保存在某个地方。堆栈是一个方便的地方。
通过将上一步 (65) 的商除以10，我们得到一个商 (6)，它将成为下一步的被除数。我们还得到了一个我们还不能输出的余数（5），所以我们必须把它保存在某个地方。堆栈是一个方便的地方。
通过将上一步 (6) 的商除以10，我们得到一个商 (0)，表明这是最后一次除法。我们还得到了一个余数 (6)，我们可以立即将其作为字符输出，但
结果证明不这样做是最有效的，因此我们将其保存在堆栈中。
此时堆栈包含我们的 5 个余数，每个余数都是 [0,9] 范围内的单个数字。由于堆栈是 LIFO（后进先出），我们首先要显示的值POP是我们要显示的第一个数字。我们使用带有 5 的单独循环POP来显示完整的数字。但在实践中，由于我们希望这个例程也能够处理少于 5 位的数字，因此我们将在数字到达时对其进行计数，然后再计算那么多的数字POP。
mov bx,10 ;CONST
xor cx,cx ;Reset counter
.a: xor dx,dx ;Setup for division DX:AX / BX
div bx ; -> AX is Quotient, Remainder DX=[0,9]
push dx ;(1) Save remainder for now
inc cx ;One more digit
test ax,ax ;Is quotient zero?
jnz .a ;No, use as next dividend
.b: pop dx ;(1)
add dl,"0" ;Turn into character [0,9] -> ["0","9"]
mov ah,02h ;DOS.DisplayCharacter
int 21h ; -> AL
loop .b
第二种方法没有第一种方法的缺点：
- 因为我们在商变为零时停止，所以丑陋的前导零从来没有任何问题。
- 分频器是固定的。这很容易。
- 应用这种方法来显示更大的数字非常简单，而这正是接下来要做的。
显示 DX:AX 中保存的无符号 32 位数字
在8086上，需要级联 2 次除以将 32 位值
DX:AX除以 10。
第 1 次除法除以高被除数（以 0 扩展）产生高商。第 2 次除法除以低被除数（与第 1 次除法的余数一起扩展）得到低商。这是我们保存在堆栈中的第二个除法的余数。
为了检查 dword inDX:AX是否为零，我已经OR在暂存寄存器中编辑了两半。
我选择在堆栈上放置一个哨兵，而不是计算数字，需要一个寄存器。因为这个哨兵获得了一个数字（[0,9]）不可能有的值（10），它很好地允许确定显示循环何时必须停止。
除此之外，此代码段类似于上面的方法 2。
mov bx,10 ;CONST
push bx ;Sentinel
.a: mov cx,ax ;Temporarily store LowDividend in CX
mov ax,dx ;First divide the HighDividend
xor dx,dx ;Setup for division DX:AX / BX
div bx ; -> AX is HighQuotient, Remainder is re-used
xchg ax,cx ;Temporarily move it to CX restoring LowDividend
div bx ; -> AX is LowQuotient, Remainder DX=[0,9]
push dx ;(1) Save remainder for now
mov dx,cx ;Build true 32-bit quotient in DX:AX
or cx,ax ;Is the true 32-bit quotient zero?
jnz .a ;No, use as next dividend
pop dx ;(1a) First pop (Is digit for sure)
.b: add dl,"0" ;Turn into character [0,9] -> ["0","9"]
mov ah,02h ;DOS.DisplayCharacter
int 21h ; -> AL
pop dx ;(1b) All remaining pops
cmp dx,bx ;Was it the sentinel?
jb .b ;Not yet
显示 DX:AX 中保存的带符号的 32 位数字
程序如下：
首先通过测试符号位找出有符号数是否为负。
如果是，则对数字取反并输出一个“-”字符，但注意不要DX:AX在过程中破坏数字。
该片段的其余部分与无符号数相同。
test dx,dx ;Sign bit is bit 15 of high word
jns .a ;It's a positive number
neg dx ;\
neg ax ; | Negate DX:AX
sbb dx,0 ;/
push ax dx ;(1)
mov dl,"-"
mov ah,02h ;DOS.DisplayCharacter
int 21h ; -> AL
pop dx ax ;(1)
.a: mov bx,10 ;CONST
push bx ;Sentinel
.b: mov cx,ax ;Temporarily store LowDividend in CX
mov ax,dx ;First divide the HighDividend
xor dx,dx ;Setup for division DX:AX / BX
div bx ; -> AX is HighQuotient, Remainder is re-used
xchg ax,cx ;Temporarily move it to CX restoring LowDividend
div bx ; -> AX is LowQuotient, Remainder DX=[0,9]
push dx ;(2) Save remainder for now
mov dx,cx ;Build true 32-bit quotient in DX:AX
or cx,ax ;Is the true 32-bit quotient zero?
jnz .b ;No, use as next dividend
pop dx ;(2a) First pop (Is digit for sure)
.c: add dl,"0" ;Turn into character [0,9] -> ["0","9"]
mov ah,02h ;DOS.DisplayCharacter
int 21h ; -> AL
pop dx ;(2b) All remaining pops
cmp dx,bx ;Was it the sentinel?
jb .c ;Not yet
对于不同的数字大小，我需要单独的例程吗？
在您需要偶尔显示 、 或 的程序中AL，AX您DX:AX可以只包含 32 位版本并使用较小尺寸的下一个小包装器：
; IN (al) OUT ()
DisplaySignedNumber8:
push ax
cbw ;Promote AL to AX
call DisplaySignedNumber16
pop ax
ret
; -------------------------
; IN (ax) OUT ()
DisplaySignedNumber16:
push dx
cwd ;Promote AX to DX:AX
call DisplaySignedNumber32
pop dx
ret
; -------------------------
; IN (dx:ax) OUT ()
DisplaySignedNumber32:
push ax bx cx dx
...
或者，如果您不介意AXandDX寄存器的破坏，请使用这个失败的解决方案：
; IN (al) OUT () MOD (ax,dx)
DisplaySignedNumber8:
cbw
; --- --- --- --- -
; IN (ax) OUT () MOD (ax,dx)
DisplaySignedNumber16:
cwd
; --- --- --- --- -
; IN (dx:ax) OUT () MOD (ax,dx)
DisplaySignedNumber32:
push bx cx
...