3

有什么方法可以在#+RESULTS块中启用字体粗细和颜色org-babel？

例如，ls使用该--color选项调用会在 shell 中按预期呈现字体粗细和颜色，但在#+RESULTS块内呈现时不会：

#+BEGIN_SRC shell
ls --color ~/
#+END_SRC

#+RESULTS:
| Applications      |
| Desktop           |
| Documents         |
| Downloads         |
| Library           |
...

终端ls有无的截图--color

另一个例子是nodemodule ，它以明文形式chalk出现在块中：#+RESULTS

#+BEGIN_SRC js
const chalk = require('chalk');

console.log(chalk.red('Hello world!'));
#+END_SRC

#+RESULTS:
: Hello world!
: undefined

chalk终端中的截图

4

1 回答 1

0

这是我想出的。通过在光标位于代码块（而不是结果块）上时运行它来将其用作交互式功能。您将需要安装该xterm-color软件包。

(defun org-babel-color-results()
  "Color org babel results.
Use the :wrap header argument on your code block for best results.
Without it, org may color overtop with whatever default coloring it
uses for literal examples.
Depends on the xterm-color package."
  (interactive)
  (when-let ((result-start (org-babel-where-is-src-block-result nil nil)))
    (save-excursion
      (goto-char result-start)
      (when (looking-at org-babel-result-regexp)
        (let ((element (org-element-at-point)))
          (pcase (org-element-type element)
            (`fixed-width
             (let ((post-affiliated (org-element-property :post-affiliated element))
                   (end (org-element-property :end element))
                   (contents (org-element-property :value element))
                   (post-blank (org-element-property :post-blank element)))
               (goto-char post-affiliated)
               (delete-region post-affiliated end)
               (insert (xterm-color-filter contents))
               (org-babel-examplify-region post-affiliated (point))
               (insert (make-string post-blank ?\n ))
               ))
            ((or `center-block `quote-block `verse-block `special-block)
             (let ((contents-begin (org-element-property :contents-begin element))
                   (contents-end (org-element-property :contents-end element)))
               (goto-char contents-begin)
               (let ((contents (buffer-substring contents-begin contents-end)))
                 (delete-region contents-begin contents-end)
                 (insert (xterm-color-filter contents)))))))))))

或者添加一个钩子

(add-hook 'org-babel-after-execute-hook 'org-babel-color-results)

这个链接是我的灵感。

我没有想到的一件事是，尽管当您不使用:wrap代码块上的参数时它会为文本着色，但Org Literal Examples : 的着色似乎会覆盖它。但是，您可以通过简单地删除: 预期具有颜色的线条来应用颜色。

于 2022-02-11T18:46:13.197 回答