19

我在 GLSL 中有一个径向模糊着色器，它采用纹理，对其应用径向模糊并将结果渲染到屏幕上。到目前为止，这非常有效。

问题是，这会将径向模糊应用于场景中的第一个纹理。但我真正想做的是将这种模糊应用于整个场景。

实现此功能的最佳方法是什么？我可以只使用着色器执行此操作，还是必须先将场景渲染为纹理（在 OpenGL 中），然后将此纹理传递给着色器以进行进一步处理？

// Vertex shader

varying vec2 uv;

void main(void)
{
    gl_Position = vec4( gl_Vertex.xy, 0.0, 1.0 );
    gl_Position = sign( gl_Position );
    uv = (vec2( gl_Position.x, - gl_Position.y ) + vec2(1.0) ) / vec2(2.0);
}



// Fragment shader

uniform sampler2D tex;
varying vec2 uv;
const float sampleDist = 1.0;
const float sampleStrength = 2.2; 

void main(void)
{
    float samples[10];
    samples[0] = -0.08;
    samples[1] = -0.05;
    samples[2] = -0.03;
    samples[3] = -0.02;
    samples[4] = -0.01;
    samples[5] =  0.01;
    samples[6] =  0.02;
    samples[7] =  0.03;
    samples[8] =  0.05;
    samples[9] =  0.08;

    vec2 dir = 0.5 - uv; 
    float dist = sqrt(dir.x*dir.x + dir.y*dir.y); 
    dir = dir/dist; 

    vec4 color = texture2D(tex,uv); 
    vec4 sum = color;

    for (int i = 0; i < 10; i++)
        sum += texture2D( tex, uv + dir * samples[i] * sampleDist );

    sum *= 1.0/11.0;
    float t = dist * sampleStrength;
    t = clamp( t ,0.0,1.0);

    gl_FragColor = mix( color, sum, t );
}

替代文字

4

1 回答 1

17

这基本上称为“后处理”，因为您在渲染后将效果（此处：径向模糊）应用于整个场景。

所以是的，你是对的：后处理的好方法是：

  • 创建屏幕大小的 NPOT 纹理 ( GL_TEXTURE_RECTANGLE)，
  • 创建一个 FBO，将纹理附加到它
  • 将此 FBO 设置为活动状态，渲染场景
  • 禁用 FBO，使用 FBO 的纹理绘制一个全屏四边形。

至于“为什么”，原因很简单：场景是并行渲染的（片段着色器是针对很多像素独立执行的）。为了对像素 (x,y) 进行径向模糊，首先需要知道周围像素的预模糊像素值。这些在第一遍中不可用，因为它们只是在此期间被渲染。

因此，您必须仅在渲染整个场景并且片段 (x,y) 的片段着色器能够从场景中读取任何像素后应用径向模糊。这就是您需要 2 个渲染阶段的原因。

于 2011-01-02T16:38:11.253 回答