1

我有一个point定义如下的记录类型：

(define-record-type point
    (make-point x y)
    point?
    (x point-x)
    (y point-y)   

)

现在，我想扩展point记录类型并定义一个新的记录类型，如下所示：

(define-record-type cpoint 
    (make-cpoint color)
    cpoint?
    (color cpoint-color)   
    (parent point)    
)

当我在方案外壳中运行上述定义时，一切正常。我可以point正确地构造类型。但是，当我尝试cpoint按如下方式构造类型时：

(define p2 (make-cpoint 8 9 'red))

我收到以下错误：

; ...rfi/9/record.rkt:100:28: 数量不匹配；；预期的参数数量与给定数量不匹配；预期：1；给定：3；[,bt 用于上下文]

我认为既然cpoint是 的子级，它应该在其构造函数中point接受类型的参数。point

我怎样才能使这项工作？

PS我是Scheme的新手。

4

1 回答 1

1

SRFI-9 中没有子记录。因此，您需要独立指定它们：

(define-record-type cpoint 
  (make-cpoint x y color)
  cpoint?
  (x cpoint-x)
  (y cpoint-y)
  (color cpoint-color))

因此 getx和yfor的访问cpoint器point是不同的。

有父母的替代品

在 R6RS 中，你有(rnrs records syntactic (6))它类似于 SRFI-9，但不兼容。您的代码如下所示：

#!r6rs

(import (rnrs base)
        (rnrs records syntactic))

(define-record-type (point make-point point?)
  (fields (immutable x point-x)
          (immutable y point-y)))

(define-record-type (cpoint make-cpoint cpoint?)
  (fields (immutable c cpoint-c))
  (parent point))


(make-cpoint 4 5 'red) ; ==>  implementation chosen visual representation, perhaps #cpoint-4-5-red

您已标记 Racket，如果您使用的是默认语言，#lang racket则它们具有struct：

#lang racket

(struct point (x y) #:transparent) 
(struct cpoint point (color) #:transparent) 

(cpoint 4 5 'red) ; ==>  (cpoint 4 5 'red)

我添加了#:transparent因为它是 R6RS 中的默认设置。你真的希望构造函数名称是make-xxx你需要指定它：

#lang racket

(struct point (x y)
  #:constructor-name make-point
  #:transparent) 

(struct cpoint point (color)
  #:constructor-name make-cpoint
  #:transparent) 

(make-cpoint 4 5 'red) ; ==>  (cpoint 4 5 'red)
于 2017-08-11T14:31:00.607 回答