4

我使用Store comonad编写了一个简单的Conway 生命游戏实现（参见下面的代码）。我的问题是网格生成从第五次迭代开始明显变慢。我的问题是否与我使用 Store comonad 的事实有关？还是我犯了一个明显的错误？据我所知，其他基于 Zipper comonad 的实现是有效的。 

import Control.Comonad

data Store s a = Store (s -> a) s

instance Functor (Store s) where
    fmap f (Store g s) = Store (f . g) s

instance Comonad (Store s) where
    extract (Store f a) = f a
    duplicate (Store f s) = Store (Store f) s

type Pos = (Int, Int)

seed :: Store Pos Bool
seed = Store g (0, 0)
    where
        g ( 0,  1) = True
        g ( 1,  0) = True
        g (-1, -1) = True
        g (-1,  0) = True
        g (-1,  1) = True
        g _        = False

neighbours8 :: [Pos]
neighbours8 = [(x, y) | x <- [-1..1], y <- [-1..1], (x, y) /= (0, 0)]

move :: Store Pos a -> Pos -> Store Pos a
move (Store f (x, y)) (dx, dy) = Store f (x + dx, y + dy)

count :: [Bool] -> Int
count = length . filter id

getNrAliveNeighs :: Store Pos Bool -> Int
getNrAliveNeighs s = count $ fmap (extract . move s) neighbours8

rule :: Store Pos Bool -> Bool
rule s = let n = getNrAliveNeighs s
        in case (extract s) of
            True  -> 2 <= n && n <= 3
            False -> n == 3

blockToStr :: [[Bool]] -> String
blockToStr = unlines . fmap (fmap f)
    where
        f True  = '*'
        f False = '.'

getBlock :: Int -> Store Pos a -> [[a]]
getBlock n store@(Store _ (x, y)) =
    [[extract (move store (dx, dy)) | dy <- yrange] | dx <- xrange]
    where
        yrange = [(x - n)..(y + n)]
        xrange = reverse yrange

example :: IO ()
example = putStrLn
        $ unlines
        $ take 7
        $ fmap (blockToStr . getBlock 5)
        $ iterate (extend rule) seed
4

1 回答 1

6

store comonad 本身并不真正存储任何东西（除了抽象意义上的函数是一个“容器”），而是必须从头开始计算它。经过几次迭代，这显然变得非常低效。

你可以在不改变你的代码的情况下缓解这个问题，如果你只是用一些记忆来备份这个s -> a函数：

import Data.MemoTrie

instance HasTrie s => Functor (Store s) where
  fmap f (Store g s) = Store (memo $ f . g) s

instance HasTrie s => Comonad (Store s) where
  extract (Store f a) = f a
  duplicate (Store f s) = Store (Store f) s

尚未测试这是否真的提供了可接受的性能。

顺便说一句，Edward Kmett在旧版本的comonad-extras包中有一个明确记忆的版本，但现在它已经消失了。我最近查看了它是否仍然有效（在调整依赖项后似乎确实有效）。

于 2017-08-04T13:08:43.597 回答