1

我正在尝试使用 XSLT 转换.ods文件（content.xml来自 zip 的文件）以生成所需的.xml文件。

XSLT 使用元素的“固定”位置来获取内容，但在我的.ods文件中我有很多空白字段，我不知道如何让它们在 XSLT 中计数。

此外，我做了一些实验content.xml来确定这些空白（空）单元格是否被保存。

在content.xml我发现类似的东西：

<table:table-column table:style-name="co1" table:number-columns-repeated="16384" table:default-cell-style-name="ce1"/>
<table:table-row table:number-rows-repeated="1048576" table:style-name="ro1">

这些值是否以某种方式（例如通过数学计算）表示.ods文件中的空单元格或值的实际位置？

我在这里分享我的文件，让你有更清晰的想法

.ods示例：

在此处输入图像描述

这是我的 XSLT 文件：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:xs="http://www.w3.org/2001/XMLSchema" 
xmlns:fn="http://www.w3.org/2005/xpath-functions" 
xmlns:office="urn:oasis:names:tc:opendocument:xmlns:office:1.0" 
xmlns:style="urn:oasis:names:tc:opendocument:xmlns:style:1.0" 
xmlns:table="urn:oasis:names:tc:opendocument:xmlns:table:1.0" 
xmlns:text="urn:oasis:names:tc:opendocument:xmlns:text:1.0" 
xmlns:espd="urn:com:grow:espd:02.00.00" xmlns:cac="urn:X-test:UBL:Pre-
award:CommonAggregate" xmlns:cbc="urn:X-test:UBL:Pre-award:CommonBasic" 


<xsl:output method="html" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="office:spreadsheet/table:table">
<xsl:variable name="test" select="table:table-row/table:table-cell"/>
<p><xsl:value-of select="$test/text:p[1]"/></p>
</xsl:template>

输出是：

burak burak5 burak6 burak2 burak3 burak4 burak7 burak9 burak8 burak10

问题：

如何通过应用转换从单元格中获取单个值content.xml？
（例如：如何到达只是单元格D4？）

4

1 回答 1

1

如何通过应用转换从单元格中获取单个值content.xml？

.ods文件中的XML 数据以content.xml这种方式编码（总是以table:命名空间为前缀）：

  • 每个table-cell都包含在table-rows
  • Empty用属性指示的RLE（Run-Length-Encoding）table-cell编码为空，必须跳过但计数number-columns-repeated="..."
  • Emptytable-row也用 RLE 编码，由number-rows-repeated="..."属性指示
  • table-columns似乎只在开始时使用

因此，要获取特定单元格，例如D4= 4:4，table-row必须计算包括跳过的 s 在内的 s：

D4 = 4:4 = Get the fourth `table-row`, add one cell D1, then add number-columns-repeated="2"

GetCellValue这是一些带有示例的 XSLT-1.0 代码（也可用于 2.0 和 3.0） ：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:xs="http://www.w3.org/2001/XMLSchema" 
xmlns:fn="http://www.w3.org/2005/xpath-functions" 
xmlns:office="urn:oasis:names:tc:opendocument:xmlns:office:1.0" 
xmlns:style="urn:oasis:names:tc:opendocument:xmlns:style:1.0" 
xmlns:table="urn:oasis:names:tc:opendocument:xmlns:table:1.0" 
xmlns:text="urn:oasis:names:tc:opendocument:xmlns:text:1.0" 
xmlns:espd="urn:com:grow:espd:02.00.00" 
xmlns:cac="urn:X-test:UBL:Pre-award:CommonAggregate" 
xmlns:cbc="urn:X-test:UBL:Pre-award:CommonBasic" exclude-result-prefixes="xs fn office style table text espd cac cbc"> 

<xsl:output method="html" version="4.0" encoding="UTF-8" indent="yes"/>
<xsl:variable name="str" select="'x:1 y:4'" />             <!-- define some coord system -->


  <xsl:template match="/office:document-content/office:body/office:spreadsheet/table:table">
    Table dimensions: <xsl:call-template name="GetDimensions" />
    Value at 5x8: <xsl:call-template name="GetCellValue">
      <xsl:with-param name="x" select="5" />
      <xsl:with-param name="y" select="8" />
    </xsl:call-template>
    Value at 1x4: <xsl:call-template name="GetCellValue">  <!-- use string defined above -->
      <xsl:with-param name="x" select="substring-after(substring-before($str,' '),'x:')" />
      <xsl:with-param name="y" select="substring-after($str,'y:')" />
    </xsl:call-template>
  </xsl:template>

  <xsl:template name="GetCellValue">
    <xsl:param name="x" />
    <xsl:param name="y" />
    <xsl:variable name="targetRow" select="table:table-row[sum(preceding-sibling::*/@table:number-rows-repeated) + position() - count(preceding-sibling::*/@table:number-rows-repeated)= $y]" />
    <xsl:variable name="targetCell" select="$targetRow/table:table-cell[sum(preceding-sibling::*/@table:number-columns-repeated) + position() - count(preceding-sibling::*/@table:number-columns-repeated) &lt;= $x]" />
    <xsl:copy-of select="$targetCell[last()]/text:p/text()" />
  </xsl:template>

  <xsl:template name="GetDimensions">
    <xsl:variable name="firstRow" select="table:table-row[1]/table:table-cell" />
    <xsl:variable name="firstColumn" select="table:table-row" />
    <xsl:variable name="width" select="count($firstRow)+ sum($firstRow/@table:number-columns-repeated) - count($firstRow/@table:number-columns-repeated)" />
    <xsl:variable name="height" select="count($firstColumn)+ sum($firstColumn/@table:number-rows-repeated) - count($firstColumn/@table:number-rows-repeated)" />
    <xsl:value-of select="concat($width,'x',$height)" />
  </xsl:template>

</xsl:stylesheet>

输出是：

Table dimensions: 5x12
Value at 5x8: burak9
Value at 1x4: burak4

编辑：
我修改了一个xsl:call-template用于自定义格式的字符串输入，例如x:1 y:4.

Edit2：
一个 XSLT-2.0 版本可以一次检索多个单元格作为 XML 元素可以在这个答案中找到。

于 2017-07-26T17:27:48.237 回答