2

如何为 FOR 循环制定解决方法？问题是延迟扩展对于带有“！”的文件名失败。在他们中

代码（这是更大脚本的一部分）

:FileScan
::Sets the filenames(in alphabetical order) to variables
SETLOCAL EnableDelayedExpansion
SET "EpCount=0"
FOR /f "Tokens=* Delims=" %%x IN ('Dir /b /o:n %~dp0*.mkv* *.mp4* *.avi* *.flv* 2^>nul') DO (
    SET /a "EpCount+=1"
    SET Ep!EpCount!=%%x
)
IF %EpCount%==0 ( Echo. & Echo: No Episodes Found & GOTO :Err )

:FolderScan
::Sets the foldernames(in alphabetical order) to variables
SET "FolderCount=0"
FOR /f "Tokens=* Delims=" %%x IN ('Dir /b /o:n /a:d "%~dp0Put_Your_Files_Here" 2^>nul') DO (
    SET /a "FolderCount+=1"
    SET Folder!FolderCount!=%%x
)

如果无法批量执行，我该如何在 PowerShell 中执行原始批处理可以调用​​的操作，例如：

:FileScan
Call %~dp0FileScanScript.ps1
IF %EpCount%==0 ( Echo. & Echo: No Episodes Found & GOTO :Err )
:FolderScan
Call %~dp0FolderScanScript.ps1

编辑： CALL SET 修复了原始代码，完全避免了 DelayedExpansion

SET "EpCount=0"
FOR /f "Tokens=* Delims=" %%x IN ('Dir /b /o:n %~dp0*.mkv* *.mp4* *.avi* *.flv* 2^>nul') DO (
    SET /a "EpCount+=1"
    CALL SET "Ep%%EpCount%%=%%x"
)
4

3 回答 3

2

最简单的解决方案确实是用来引入另一个解析阶段：callset

setlocal DisableDelayedExpansion
pushd "%~dp0."
set /A "EpCount=0"
for /F "delims=" %%x in ('
    dir /B /A:-D /O:N "*.mkv*" "*.mp4*" "*.avi*" "*.flv*" 2^> nul
') do (
    set /A "EpCount+=1"
    call set "Ep%%EpCount%%=%%x"
)
popd
endlocal

但是，一旦插入符号^出现在字符串或文件名中，这就会导致问题，因为call当它们出现引用时它们会加倍。

为了解决这个问题，您需要确保在第二个解析阶段也扩展字符串，这可以通过使用临时变量来实现，如下所示：

setlocal DisableDelayedExpansion
pushd "%~dp0."
set /A "EpCount=0"
for /F "delims=" %%x in ('
    dir /B /A:-D /O:N "*.mkv*" "*.mp4*" "*.avi*" "*.flv*" 2^> nul
') do (
    set "Episode=%%x"
    set /A "EpCount+=1"
    call set "Ep%%EpCount%%=%%Episode%%"
)
popd
set Ep
endlocal

此外，我添加了过滤选项/A:-D以dir确保不返回任何目录。此外，我使用pushdandpopd临时更改为脚本的父目录。您编写的dir命令行在脚本的父目录中搜索文件*.mkv*，但在当前工作目录中搜索所有其他文件，这可能不是您想要的。

另一种选择是切换延迟扩展，以便在禁用延迟扩展时扩展for变量引用，并在启用时完成对数组样式变量的分配。但是您需要实施措施以将变量值传输到障碍之外，如下例所示：%%xEpendlocal

setlocal DisableDelayedExpansion
pushd "%~dp0."
set /A "EpCount=0"
for /F "delims=" %%x in ('
    dir /B /A:-D /O:N "*.mkv*" "*.mp4*" "*.avi*" "*.flv*" 2^> nul
') do (
    rem /* Delayed expansion is disabled at this point, so expanding
    rem    the `for` variable reference `%%x` is safe here: */
    set "Episode=%%x"
    set /A "EpCount+=1"
    rem // Enable delayed expansion here:
    setlocal EnableDelayedExpansion
    rem /* Use a `for /F` loop that iterates once only over the assignment string,
    rem    which cannot be empty, so the loop always iterates; the expanded value
    rem    is stored in `%%z`, which must be assigned after `endlocal` in order
    rem    to have it available afterwards and not to lose exclamation marks: */
    for /F "delims=" %%z in ("Ep!EpCount!=!Episode!") do (
        endlocal
        set "%%z"
    )
)
popd
set "Ep"
endlocal
于 2017-07-17T16:25:26.707 回答
1 
CALL SET Ep%%EpCount%%=%%x

会适当地设置你的变量，就像

FOR /f "tokens=1*delims=[]" %%x IN (
 'Dir /b /o:n %~dp0*.mkv* *.mp4* *.avi* *.flv* 2^>nul ^|find /v /n ""'
 ) DO (
 SET /a epcount=%%x
 CALL SET ep%%x=%%y
)

（在每个名称前面加上[num]then 用于for提取num到%%x和name到%%y（假设没有以[or开头的名称]））

于 2017-07-16T21:46:07.897 回答
0

注意：除了之外， OP 最初还标记了问题，但后来删除了该标记（自恢复以来）。

等效于以下批处理文件 ( cmd) 循环：

SETLOCAL EnableDelayedExpansion
FOR /f "Tokens=* Delims=" %%x IN ('Dir /b /o:n %~dp0*.mkv* *.mp4* *.avi* *.flv* 2^>nul') DO (
    SET /a "EpCount+=1"
    SET Ep!EpCount!=%%x
)

在PowerShell (PSv3+) 中是：

# Collect all episode paths in array $Eps
$Eps = (Get-ChildItem -Recurse $PSScriptRoot -Include *.mkv, *.mp4, *.avi, *.flv).FullName
# Count the number of paths collected.
$EpCount = $Eps.Count

以上内容也适用于具有嵌入式!实例的路径。
$Eps将是完整文件名的数组。

然后一一处理匹配的文件：

foreach ($ep in $Eps) { # Loop over all files (episodes)
  # Work with $ep
}

使用单个数组而不是 distinct $Ep1, $Ep2, ... 变量可以使处理更加简单和高效。

以上是对内存中已经收集的文件名逐个处理的最快方式。
一种内存效率更高（尽管速度稍慢）、基于管道的方法是：

Get-ChildItem -Recurse $PSScriptRoot -Include *.mkv,*.mp4,*.avi,*.flv | ForEach-Object {
  # Work with $_.FullName - automatic variable $_ represents the input object at hand.
}
于 2017-07-16T20:55:32.013 回答