xml - 使用属性作为键（ xsl ）合并相似的数据 xml 节点

Question

我想用这种格式转换一个包含 N 个部分的文件：

<File>
        <Sections Section="Section1" fieldName="field1" fieldValue="value1"/>
        <Sections Section="Section1" fieldName="field2" fieldValue="value2"/>
        <Sections Section="Section1" fieldName="field3" fieldValue="value3"/>
        <Sections Section="Section2" fieldName="field1" fieldValue="value1"/>
        <Sections Section="Section2" fieldName="field2" fieldValue="value2"/>
        <Sections Section="Section2" fieldName="field3" fieldValue="value3"/>
</File>

进入

<File>
   <Section1 field1="value1" field2="value2" field3="value3"/>
   <Section2 field1="value1" field2="value2" field3="value3"/>
</File>

使用属性 Section 的值作为创建元素的键。

我尝试了一些东西，但我做不到。

你可以帮帮我吗？

谢谢。

Answer 1

这是一个 XSLT 1.0 样式表：

<xsl:stylesheet 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">

  <xsl:output indent="yes"/>

  <xsl:key name="k1" match="File/Sections" use="@Section"/>

  <xsl:template match="File">
    <xsl:copy>
      <xsl:apply-templates select="Sections[generate-id() = generate-id(key('k1', @Section)[1])]" mode="group"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="Sections" mode="group">
    <xsl:element name="{@Section}">
      <xsl:apply-templates select="key('k1', @Section)"/>
    </xsl:element>
  </xsl:template>

  <xsl:template match="Sections">
    <xsl:attribute name="{@fieldName}">
      <xsl:value-of select="@fieldValue"/>
    </xsl:attribute>
  </xsl:template>

</xsl:stylesheet>

Answer 2

这是 XSLT 2.0 样式表

<xsl:stylesheet version="2.0" 
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/File" >
        <xsl:copy>
        <xsl:for-each-group select="Sections" group-by="@Section">
            <xsl:element name="{current-grouping-key()}">
                <xsl:for-each select="current-group()">
                    <xsl:attribute name="{@fieldName}" select="@fieldValue"/>
                </xsl:for-each>
            </xsl:element>
        </xsl:for-each-group>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>