8

尝试使用 JSR $E09A 在我的 Commodore 64 (C64) 上生成一系列随机数，并从 $63 和 $64 中检索数字。（根据我看到的所有文档，当您使用 BASIC 中的 RND(0) 时，它是相同的例程。但无法对其进行迭代。以下将起作用，并在执行时在 $63 和 $64 中放置不同的数字本身。

. C000  A5 00    LDA $00
. C002  20 9A E0 JSR $E09A
. C005  00       BRK

现在，当我尝试使用以下代码迭代 10 次时，它永远不会返回。

. C000  A0 0A    LDY #$0A
. C002  A9 00    LDA #$00
. C004  20 9A E0 JSR $E09A
. C007  88       DEY
. C008  D0 F8    BNE $C002
. C00A  00       BRK

我是否错过了一些如此明显的东西，我看不到它。我不担心它有多“随机”。此时我只想要一系列随机数。

4

7 回答 7

11

SID 芯片实际上可以生成比 BASIC 的伪随机数更随机的数字。使用以下命令启动生成器：

LDA #$FF  ; maximum frequency value
STA $D40E ; voice 3 frequency low byte
STA $D40F ; voice 3 frequency high byte
LDA #$80  ; noise waveform, gate bit off
STA $D412 ; voice 3 control register
RTS

然后，您可以随时获取随机数：

LDA $D41B ; get random value from 0-255
于 2017-07-24T22:18:12.813 回答
8

感谢Ross Ridge建议被调用函数正在更改 Y 寄存器中的值。我知道它必须是显而易见的！

通过在 之前存储 YJSR并在之后恢复，它现在将正确迭代。这是快速修复：

编辑：更新 7/10/17 - 显示完整代码并纳入JeremyP建议。这本质上是一个硬币翻转迭代器（50000 次重复），用于试验随机

.C 033c  A9 00       LDA #$00
.C 033e  85 FB       STA $FB    ; set up register for counter
.C 0340  85 FC       STA $FC
.C 0342  A2 C8       LDX #$C8   ; outer loop= 200
.C 0344  86 FD       STX $FD
.C 0346  A0 FA       LDY #$FA   ; inner loop=250
.C 0348  84 FE       STY $FE
.C 034a  20 94 E0    JSR $E094  ; Get random# Vic20 Address (E09B for C64)
.C 034d  A5 63       LDA $64
.C 034f  C9 80       CMP #$80   ; >128 = HEADS
.C 0351  90 0D       BCC $0360  ; else continue loop
.C 0353  18          CLC        ; increment 2 byte number
.C 0354  A5 FB       LDA $FB
.C 0356  69 01       ADC #$01   ; LSB
.C 0358  85 FB       STA $FB
.C 035a  A5 FC       LDA $FC
.C 035c  69 00       ADC #$00   ; MSB
.C 035e  85 FC       STA $FC
.C 0360  C6 FE       DEC $FE
.C 0362  D0 E6       BNE $034A  ; end inner loop
.C 0364  C6 FD       DEC $FD
.C 0366  D0 DE       BNE $0346  ; end outer loop
.C 0368  60          RTS        ; return to basic

LDA $63我可以通过循环或在循环内获取随机数LDA $64并将其用于我的目的。

事实证明，这比预期的要慢得多，只花费了 BASIC 的一半时间。RND 函数需要很多周期，但是，我找到了这个Compute！使用 SID 芯片作为随机数发生器的文章。

LDA #$FF  ; maximum frequency value
STA $D40E ; voice 3 frequency low byte
STA $D40F ; voice 3 frequency high byte
LDA #$80  ; noise waveform, gate bit off
STA $D412 ; voice 3 control register

一旦打开，它就会独立生成数字，无需再次执行。重复调用的循环LDA $D41B将在每次迭代中为您提供一个新的随机数。在我的测试中，50,000 次迭代花费了 1.25 秒，而百万次迭代花费了 24 秒多一点。对于一台 1MHz 的计算机来说相当令人印象深刻！

于 2017-07-06T00:30:30.857 回答
1

您实际上是在调用RND(0)which 使用计时器来生成种子。但是，这不能直接用于组装。首先尝试切换到一个正数（任何数字），看看它是否开始产生值。

于 2017-07-06T00:14:07.617 回答
1

如果您没有带有定时光栅IRQ 或类似功能的程序，您可以使用lda $d012.

于 2017-07-13T09:07:32.547 回答
0

我发现这个线程在 C64 程序集中搜索更通用的 RND(start, end) 例程。作为这个 BASIC 示例实现的东西：

INT(RND(1) * (end- start + 1)) + start

虽然这里有很多有用的答案，但我错过了这种解决方案，所以我必须找到自己的；它可能对另一个来到这个线程的人有帮助，所以这里是：

            lda #<end   
            sta $FD
            lda #>end
            sta $FE
            lda #<start
            sta $FB
            lda #>start
            sta $FC
rnd:
            //reseed, to avoid repeated sequence; RND(0)
            lda #00
            jsr $E09A
            //++end 
            inc $FD
            bne skip1
            inc $FE
skip1:
            //- start
            lda $FD
            sec
            sbc $FB
            sta $FD
            lda $FE
            sbc $FC
            sta $FE         

            //++end-start to FAC
            ldy $FD
            lda $FE
            jsr $B391 //A(h),Y(L) - FAC 
            ldx #<flt
            ldy #>flt
            jsr $BBD4   //store FAC to flt
            //get actual RND(1)
            lda #$7f
            jsr $E09A
            //multiply by ++end - start
            lda #<flt
            ldy #>flt
            jsr $BA28
            //to integer
            jsr $BCCC
            //FAC to int;
            jsr $B1BF
            lda $65         
            clc
            adc $FB
            sta $14
            lda $64
            adc $FC
            sta $15
            rts     
flt:        .byte 0,0,0,0,0

该例程使用 0 - 32767 范围内的 16 位数字。参数从 251,252 开始；以 253、254 结尾。在 $14 中找到 16 位结果。

于 2020-02-20T07:50:55.780 回答
0

C64 的真正问题是：

  1. SID 生成的数字也是伪随机的，它们按顺序重复（我找不到讨论这个的链接）

  2. 光栅位置不是随机的。

c64 中真正随机性的唯一来源是用户输入。

所以我要做的是：

  1. 初始化 SID 噪声波形
  2. 在启动时获取 cia timer 1 LSB（这在普通 c64 上很好，但在模拟器上不是随机的）
  3. 启动 cia 计时器 2
  4. 等待用户按下任意键（或操纵杆方向/按钮）
  5. 获取 cia 定时器 2 LSB
  6. 获取 SID 幅度值
  7. 可选择获取光栅位置，但取决于您是从基本程序还是汇编程序调用此例程，您可能无法获得完全随机的值。

然后你就有了你最喜欢的伪随机程序的随机种子。或者只是一个 16/24/32 位随机数。

例如，在游戏中，您可以在用户移动操纵杆时获取 cia 计时器并获取随机字节。

注意：在模拟器中删除 prg 或 d64 与编写“load...”非常不同，因为每个用户每次写入的方式都不同，并且在这种情况下，计时器 LSB 是“随机的”。

由于这个原因，在某些模拟器中，计算机启动时会添加随机延迟。

于 2020-09-01T13:52:02.637 回答
-1

现在已经很晚了，但是根据要求，您也可以滚动自己的 PRNG。一些算法很容易实现，例如，我将在这里使用参数展示一个 32 位xorshift[3,25,24]实现（因为这使得两个移位使用很少的代码）。返回的随机数有 16 位：

rnd_seed:
                sta     $22             ; store pointer to PRNG state
                stx     $23
                lda     #$00            ; initialize with 0
                ldy     #$03
rs_clrloop:     sta     ($22),y
                dey
                bne     rs_clrloop
                lda     $d012           ; except for LSB, use current raster
                bne     seed_ok
                lda     #$7f            ; or a fixed value if 0
seed_ok:        sta     ($22),y
                rts

rnd:
                sta     $22             ; store pointer to PRNG state
                stx     $23
                ldy     #$03
r_cpyloop:      lda     ($22),y         ; copy to ZP $fb - $fe
                sta     $fb,y
                dey
                bpl     r_cpyloop
                ldy     #$03            ; and shift left 3 bits
r_shiftloop:    asl     $fb
                rol     $fc
                rol     $fd
                rol     $fe
                dey
                bpl     r_shiftloop
                ldy     #$03
r_xorloop:      lda     ($22),y         ; xor with original state
                eor     $fb,y
                sta     ($22),y
                dey
                bpl     r_xorloop
                ldy     #$03
                lda     ($22),y
                lsr     a               ; MSB >> 1 gives ">> 25"
                ldy     #$00
                eor     ($22),y         ; xor with original state
                sta     ($22),y
                ldy     #$03            ; this is also value for "<< 24"
                eor     ($22),y         ; so xor with MSB
                sta     ($22),y
                tax                     ; use the two "higher" bytes as result ...
                dey
                lda     ($22),y         ; ... in A/X
                rts

使用示例：

main:
                lda     init
                bne     noinit
                lda     #<prng
                ldx     #>prng
                inc     init
                jsr     rnd_seed
noinit:         lda     #<prng
                ldx     #>prng
                jsr     rnd
                jmp     $bdcd        ; C64 BASIC routine output 16bit int in A/X

init:           .byte   $00
prng:           .res    4            ; 32bit PRNG state
于 2017-11-06T17:37:47.027 回答