2

我正在查看 SAS 代码，发现以下引用宏变量的方法。

  1. &变量名 。
  2. &变量名

我知道第一种引用方式是我们如何引用 sas 中定义的宏变量的正常方式。

但是，您能否解释一下第二种方式（宏变量名称后没有句点）与第一种方式有何不同

4

2 回答 2

3

当您引用宏变量时，& 符号表示宏变量引用正在开始。宏处理器还需要确定宏变量引用的结束。

在大多数情况下，宏引用以空格或分号结尾。 

38   %let x=Hello;
39
40   %put &x;   *semicolon ends the reference;
Hello
41
42   %put &x World; *white space ends the reference;
Hello World

宏变量名可以由字母、数字和下划线组成。任何不能成为宏变量一部分的符号都将结束引用。例如一个问号：

44   %put &x?; *Question mark ends the reference;
Hello?

现在，假设您要生成字符串 HelloWorld，Hello 和 World 之间没有空格： 

46   %put &xWorld;
WARNING: Apparent symbolic reference XWORLD not resolved.
&xWorld

那没有用。宏处理器看到一个对名为 xWorld 的宏变量的引用，并且没有这样的宏变量。所以我们需要一种方法来告诉宏处理器宏变量引用在 x 之后结束。我们可以在 x 后面加一个句点，表示“宏变量引用到此结束”。 

47   %put &x.World;
HelloWorld

请注意，重要的是，我们输入的时间段不会显示在写入日志的文本中。当宏处理器将其用作宏变量引用的结束时，它会“吃掉”该句点。

这意味着，如果您希望在宏变量引用后加上句点，则必须键入两个句点。第一个被宏处理器吃掉。通常的示例是使用 libref：

48   %let mylib=sashelp;
49
50   proc print data=&mylib.class;run;
ERROR: File WORK.SASHELPCLASS.DATA does not exist.

NOTE: The SAS System stopped processing this step because of errors.
51
52   proc print data=&mylib..class;run;

NOTE: There were 19 observations read from the data set SASHELP.CLASS.

有些人喜欢总是在宏变量引用之后使用句点，作为一种编码风格。就个人而言，我只在需要指定宏变量引用结束时才使用句点。

于 2017-07-03T21:23:52.210 回答
1

这是引用变量的捷径。但是，在连接输出时会有所不同：

%let var = My name ;

%put &var.is Paul;
// Output: My name is Paul.

%put &varis Paul;
// Output: WARNING: Apparent symbolic reference VARIS not resolved.
// &varis Paul

另一个你肯定需要的例子.：

%let lib = sashelp;
data temp;
  set &lib..class;
run;

我建议始终使用该变体&variable.。因为很清楚变量在哪里结束。

于 2017-07-03T10:20:27.967 回答