1

我创建了以下语法：我想知道如何构建一个解释器，它在 java 中返回一棵树，我以后可以用它在屏幕上打印，我有点堆栈关于如何开始它。

grammar myDSL;

options {
  language = Java;
}
@header {
  package DSL;
}
@lexer::header {
  package DSL;
}


program
    :  IDENT '={' components* '}'
    ;


components
    : IDENT '=('(shape)(shape|connectors)* ')'
    ;

shape
    :  'Box' '(' (INTEGER ','?)* ')'
    |  'Cylinder' '(' (INTEGER ','?)* ')'
    |  'Sphere' '(' (INTEGER ','?)* ')'
    ;

connectors
    :  type '(' (INTEGER ','?)* ')'
    ;    

type
    :  'MG'
    |  'EL'
    ;

IDENT: ('a'..'z' | 'A'..'Z')('a'..'z' | 'A'..'Z' | '0'..'0')*;

INTEGER: '0'..'9'+;

// This if for the empty spaces between tokens and avoids them in the parser
WS: (' ' | '\t' | '\n' | '\r' | '\f')+ {$channel=HIDDEN;};

COMMENT: '//' .* ('\n' | '\r') {$channel=HIDDEN;};
4

1 回答 1

3

几点说明：

无需为默认目标语言 Java 设置语言。所以你可以删除这个：

options {
  language = Java;
}

您IDENT包含一个错误：

IDENT: ('a'..'z' | 'A'..'Z')('a'..'z' | 'A'..'Z' | '0'..'0')*;

'0'..'0')应该很可能是'0'..'9')。

子规则(INTEGER ','?)*也匹配源1 2 3 4（根本没有逗号！）。也许你打算这样做：(INTEGER (',' INTEGER)*)?

现在，关于你的问题：如何让 ANTLR 构造一个合适的 AST？这可以通过添加output = AST;您的选项块来完成：

options {
  //language = Java;
  output = AST;
}

^然后在你的解析器规则中添加“树运算符” !，或者使用树重写规则：rule: a b c -> ^(c b a).

“树运算符”^用于定义（子）树的根，!用于从（子）树中排除标记。

重写规则^( /* tokens here */ )的第一个标记（紧跟在 之后^(）是（子）树的根，所有后续标记都是根的子节点。

一个例子可能是为了。让我们采取你的第一条规则：

program
  :  IDENT '={' components* '}'
  ;

你想让IDENT它成为根，孩子，components*你想从树中排除。你可以这样做：={}

program
  :  IDENT^ '={'! components* '}'!
  ;

或通过这样做：

program
  :  IDENT '={' components* '}' -> ^(IDENT components*)
  ;
于 2010-12-19T16:47:28.437 回答