9

我正在开发一个 Erlang 系统，并且由于记录是编译时预处理器宏（几乎），并且它们不能在运行时被操纵......基本上，我正在使用属性模式，其中属性在运行时添加到前端 (AS3) 上的对象。理想情况下，我会在 Erlang 端使用一个列表来反映这一点，因为它是一种基本数据类型，但随后无法使用 QCL [查询 ETS 表] 中的记录，因为要使用它们我必须明确说明我使用哪个记录属性想要查询...我在 larges 表中至少有 15 列，因此将它们全部列在一个巨大的 switch 语句（case X of）中简直丑陋。

有谁知道如何优雅地解决这个问题？也许一些内置函数用于创建具有适当签名的元组以用于模式匹配（用于 QLC）？

谢谢

4

3 回答 3

4

听起来您希望能够执行诸如在运行时由用户界面代码确定的位置get_record_field(Field, SomeRecord)之类的事情。Field

您是对的，因为您不能在标准 erlang 中执行此操作，因为记录和record_info函数在编译时被扩展和消除。

我使用或查看过几种解决方案。我的解决方案如下：（该示例提供运行时访问#dns_rec和#dns_rr记录的权限inet_dns.hrl）

%% Retrieves the value stored in the record Rec in field Field.
info(Field, Rec) ->
    Fields = fields(Rec),
    info(Field, Fields, tl(tuple_to_list(Rec))).

info(_Field, _Fields, []) -> erlang:error(bad_record);
info(_Field, [], _Rec) -> erlang:error(bad_field);
info(Field, [Field | _], [Val | _]) -> Val;
info(Field, [_Other | Fields], [_Val | Values]) -> info(Field, Fields, Values).

%% The fields function provides the list of field positions
%% for all the kinds of record you want to be able to query
%% at runtime. You'll need to modify this to use your own records.
fields(#dns_rec{}) -> fields(dns_rec);
fields(dns_rec) -> record_info(fields, dns_rec);
fields(#dns_rr{}) -> fields(dns_rr);
fields(dns_rr) -> record_info(fields, dns_rr).

%% Turns a record into a proplist suitable for use with the proplists module.
to_proplist(R) ->
    Keys = fields(R),
    Values = tl(tuple_to_list(R)),
    lists:zip(Keys,Values).

此处提供了一个可编译的版本：rec_test.erl

您还可以将此动态字段查找扩展为匹配规范的动态生成，以便与ets:select/2或mnesia:select/2如下所示一起使用：

%% Generates a matchspec that does something like this
%% QLC psuedocode: [ V || #RecordKind{MatchField=V} <- mnesia:table(RecordKind) ]
match(MatchField, RecordKind) ->
    MatchTuple = match_tuple(MatchField, RecordKind),
    {MatchTuple, [], ['$1']}.

%% Generates a matchspec that does something like this
%% QLC psuedocode: [ T || T <- mnesia:table(RecordKind),
%%                        T#RecordKind.Field =:= MatchValue]
match(MatchField, MatchValue, RecordKind) ->
    MatchTuple = match_tuple(MatchField, RecordKind),
    {MatchTuple, [{'=:=', '$1', MatchValue}], ['$$']}.

%% Generates a matchspec that does something like this
%% QLC psuedocode: [ T#RecordKind.ReturnField
%%                   || T <- mnesia:table(RecordKind),
%%                        T#RecordKind.MatchField =:= MatchValue]
match(MatchField, MatchValue, RecordKind, ReturnField) 
  when MatchField =/= ReturnField ->
    MatchTuple = list_to_tuple([RecordKind
           | [if F =:= MatchField -> '$1'; F =:= ReturnField -> '$2'; true -> '_' end
              || F <- fields(RecordKind)]]),
    {MatchTuple, [{'=:=', '$1', MatchValue}], ['$2']}.


match_tuple(MatchField, RecordKind) ->
    list_to_tuple([RecordKind
           | [if F =:= MatchField -> '$1'; true -> '_' end
              || F <- fields(RecordKind)]]).

Ulf Wiger 还编写了一个 parse_transform，Exprecs，它或多或少会自动为您执行此操作。我从未尝试过，但 Ulf 的代码通常非常好。

于 2009-02-26T19:35:22.927 回答
1

我通过使用解析转换工具读取 .hrl 文件并生成辅助函数来解决这个问题（在开发中）。

我在Trap Exit写了一篇关于它的教程。

我们一直使用它来生成匹配规范。美妙之处在于，您无需了解开发时记录的当前状态。

但是，一旦您投入生产，情况就会发生变化！如果您的记录是表的基础（与表中字段的定义相反），那么更改基础记录会更加困难（委婉地说！）。

于 2009-02-27T00:42:02.317 回答
0

我不确定我是否完全理解您的问题，但在大多数情况下，我已经从记录转移到了道具列表。它们更灵活，也更慢。使用 (d)ets 我通常使用一些记录字段进行粗略选择，然后检查剩余记录上的 proplists 以进行详细选择。

于 2009-01-20T22:05:29.380 回答