perl - perl 列出哈希引用的上下文

Question

为什么这行得通？那是第2行

DB<1> $a = {'a'=>1}; $b = {'a'=>2, 'b'=>0};
DB<2> $c = ($a, $b);
DB<3> print $c;
  HASH(0x8743e68)
DB<4> print $c->{a},$c->{b};
  20

我知道如果我仔细使用 %$a 和 %$b ，perl 会知道我的意思，但是列表中只有裸露的 refs，为什么它会起作用？

或者也许它只是看起来有效，而我真的做了其他事情？

Answer 1

中没有列表上下文

$c = ($a, $b);

相反，您看到的是逗号运算符的作用：

二进制“，”是逗号运算符。在标量上下文中，它计算其左参数，丢弃该值，然后计算其右参数并返回该值。这就像 C 的逗号运算符。

为了更清楚地看到这一点，请看一下：

#!/usr/bin/perl
use strict; use warnings;

my $x = {a => 1};
my $y = {a => 2, b => 0};

my $z = ($x, $y);

print "\$x = $x\t\$y = $y\t\$z = $z\n";

my @z = ($x, $y);
print "@z\n";

首先，我使用了警告。因此，当我运行此脚本时，我收到警告：

Useless use of private variable in void context at C:\Temp\t.pl line 7.

始终启用警告。

现在，输出显示正在发生的事情：

$x = HASH(0x39cbc) $y = HASH(0x39dac) $z = HASH(0x39dac)
哈希（0x39cbc）哈希（0x39dac）

显然，$z指的是与 相同的匿名哈希$y。没有复制值。

并且，与 do 和 . 一样$z[0]指代相同的匿名哈希，并且$x与$z[1]do$y和$z.

请注意，单独的括号不会创建列表上下文。如果是

my @z = ($x, $y);

它们是必要的，因为=比逗号运算符绑定得更紧密。

my @z = $x, $y;

将分配$x给$z[0]并丢弃$y（并发出警告）而

my @z = 1 .. 5;

会按预期工作。

最后，如果您想分配$z一个新的匿名哈希，其中包含$x和$y指向的匿名哈希的副本，您会这样做

#!/usr/bin/perl
use strict; use warnings;
use Data::Dumper;

my $x = {a => 1};
my $y = {a => 2, b => 0};

my $z = { %$x, %$y };

print Dumper $z;

这将输出：

$VAR1 = {
          'a' => 2,
          'b' => 0
        };

因为根据定义，哈希键是唯一的。如果要保留与两个散列的键关联的所有值，则需要做一些稍微复杂的事情（并使用匿名 arrayrefs 作为“联合”散列中的值）：

#!/usr/bin/perl
use strict; use warnings;
use Data::Dumper;

my $x = {a => 1};
my $y = {a => 2, b => 0};

my $z;

push @{ $z->{$_} }, $x->{$_} for keys %$x;
push @{ $z->{$_} }, $y->{$_} for keys %$y;

print Dumper $z;

输出：

VAR1 = {
         '一个' => [
                  1、
                  2
                ],
         'b' => [
                  0
                ]
       };