2

我有一个带有子类X的类Y。 X有一个calculate()我想Y用一些额外的行为覆盖的方法if，如果它失败，调用的语句X.calculate()。在 Python 中，这将通过以下方式完成：

class X(object):
    def calculate(self, my_arg):
        return "Hello!"

class Y(X):
    def calculate(self, my_arg):
        if type(my_arg) is int and my_arg > 5:
            return "Goodbye!"
        return super(Y, self).calculate(my_arg)

如何在 Perl 中使用该Moo模块执行此操作？

4

2 回答 2

3

正如文档指出的那样：

不支持super, override, inner, or augment- 作者认为增广是个坏主意，override可以翻译成：

around foo => sub {
  my ($orig, $self) = (shift, shift);
  ...
  $self->$orig(@_);
  ...
};

（强调我的）

#!/usr/bin/env perl

use strict;
use warnings;

package X;

use Moo;

sub calculate {
    return 'Hello!'
}


package Y;

use Moo;

extends 'X';

around calculate => sub {
    my $orig = shift;
    my $self = shift;

    if ( $_[0] > 5 ) {
        return $self->$orig(@_);
    }

    return 'Goodbye!';
};

package main;

my $y = Y->new;

print $y->calculate(3), "\n";
print $y->calculate(11), "\n";
于 2017-06-13T21:33:19.513 回答
0

这可以通过SUPER::伪类在 Perl 中完成，伪类是 Perl 方法解析系统的一部分。您只需将其放在方法调用的前面。它不适用于类方法或函数调用。

use strict;
use warnings;
use feature 'say';

package Foo;
use Moo;

sub frobnicate {
    my $self = shift;
    say "foo";
}

package Bar;
use Moo;
extends 'Foo';

sub frobnicate {
    my $self = shift;
    say "bar";
    $self->SUPER::frobnicate;    
}

package main;
Bar->new->frobnicate;

如果您有多级继承，您甚至可以使用它来调用每个父级的方法。

package Grandparent;
sub foo { ... }

package Parent;
use parent 'Grandparent';
sub foo { $_[0]->SUPER::foo }

package Child;
use parent 'Parent';
sub foo { $_[0]->SUPER::foo }

这将随后调用fooChild、Parent 和 Grandparent。

于 2017-06-13T21:27:25.913 回答