perl - 用自定义标签（Perl 解释器）解析 HTML 文档的简单 Perl 脚本是什么？

Question

好的，这就是我正在做的。我正在为以我的自定义扩展名（.cpm）结尾的文档制作 perl 解释器。我环顾四周，发现

似乎HTML::Parser是要走的路。我要的是一个简单的教程来解析带有特殊标签的文档。例如，我想要一些向我展示如何解析 HTML 文档的东西，但每当<putinbold>遇到它时，它都会将其替换为<b>.

我想要的一个例子-

<html>
This is HTML talking
<liamslanguage>say "This is Liams language speaking"</liamslanguage>
</html>

score 8 · Accepted Answer

解析 with 的重要部分HTML::Parser是用 right 分配handlersright argspec。一个示例程序：

#!/usr/bin/env perl

use strict;
use warnings;

use HTML::Parser;

my $html;
sub replace_tagname {
    my ( $tagname, $event ) = @_;

    if ( $tagname eq 'liamslanguage' ) {
        $tagname = 'b';
    }

    if ( $event eq 'start' ) {
        $html .= "<$tagname>";
    }
    elsif ( $event eq 'end' ) {
        $html .= "</$tagname>";
    }
}

my $p = HTML::Parser->new(
    'api_version' => 3,
    'start_h'     => [ \&replace_tagname,      'tagname, event' ],
    'default_h'   => [ sub { $html .= shift }, 'text'           ],
    'end_h'       => [ \&replace_tagname,      'tagname, event' ],
);
$p->parse( do { local $/; <DATA> } );
$p->eof();

print $html;

__DATA__
<html>
This is HTML talking
<liamslanguage>say "This is Liams language speaking"</liamslanguage>
</html>

perl - 用自定义标签（Perl 解释器）解析 HTML 文档的简单 Perl 脚本是什么？

1 回答 1

Related

Reference