-2

我即将在 Prolog 中实现逻辑术语的证明器。我当前的代码不是很漂亮，因此，我只想说明我想让我的程序做什么，希望你能给我一些好的建议:)

它应该有一个变量列表（可以说是逻辑参数），其次是一个包含这些参数的逻辑公式（例如'not'(A 'and' B) 'or' 'not'(B 'and' C) 'or' ...等等）。

作为输出，我希望我的程序以可能的一致分配来响应。单个参数可以是true ( 1) 或false ( 0)。

所以我的目标是像A=0, B=0, C=0 ; A=1这样的回报。

我很高兴为我的程序提供每一个帮助:)

4

1 回答 1

5

有几种方法可以解决这个问题。就语法而言，一种方便的方法是定义运算符，如下所示：

:- op(500, fx, not).
:- op(600, xfx, and).
:- op(700, xfx, or).

（我只是在这里猜测合理的优先级设置，但只是为了说明。有关详细信息，请参阅op文档。）

完成后，您可以编写一个表达式，例如：A and BProlog 将“看到”它为and(A, B)：

| ?- write_canonical(A and B).
and(_23,_24)

从那里，您需要有一种方法来评估表达式。在这方面，这里有很多关于 SO 的问题（在这个网站上搜索[prolog] boolean expression evaluation），但我将提供一个简单的例子。现在都是关于如何表示结果以及递归。

在表示结果时，您可以使用 Prolog 的成功/失败机制，因为您正在处理布尔结果。或者，您可以有一个明确的结果，例如 0 和 1。让我们尝试 0 和 1，因为这是您对真假的表示。

% Describe a valid boolean
bool(0).
bool(1).

% The evaluation of a valid boolean is itself
exp_eval(X, X) :- bool(X).

% Evaluation of an 'and' expression
exp_eval(and(A, B), Result) :-
    exp_eval(A, ResultA),
    exp_eval(B, ResultB),
    Result #= ResultA * ResultB.

% Evaluation of an 'or' expression
exp_eval(or(A, B), Result) :-
    exp_eval(A, ResultA),
    exp_eval(B, ResultB),
    % Just a little trick to get 1 if either ResultA or ResultB or both are 1
    Result #= (ResultA + ResultB + 1) // 2.

% Evaluation of a 'not' expression
exp_eval(not(A), Result) :-
    exp_eval(A, ResultNot),
    Result #= 1 - ResultNot.  % 0 ---> 1, and 1 ---> 0

而不是像我上面所做的那样计算“布尔”1/0结果，而是可以将它们断言为如下事实：

bool_not(0, 1).
bool_not(1, 0).

bool_and(0, 0, 0).
bool_and(0, 1, 0).
bool_and(1, 0, 0).
bool_and(1, 1, 1).

bool_or(0, 0, 0).
bool_or(0, 1, 1).
bool_or(1, 0, 1).
bool_or(1, 1, 1).

然后，例如，Result #= (ResultA + ResultB + 1) // 2您可以只拥有bool_or(ResultA, ResultB, Result).

现在我们可以评估表达式，我们需要一个求解器：

solve(Exp) :-
    term_variables(Exp, Variables),
    maplist(bool, Variables),  % Variables should be valid booleans
    exp_eval(Exp, 1).          % We only want true results for the expression

请注意，在原始问题陈述中，据说变量列表将作为参数给出，但您可以使用term_variables/2从表达式中获取变量。

然后你可以运行求解器：

| ?- solve(not(A and B) or not(B and C)).

A = 0
B = 0
C = 0 ? a

A = 0
B = 0
C = 1

A = 0
B = 1
C = 0

A = 0
B = 1
C = 1

A = 1
B = 0
C = 0

A = 1
B = 0
C = 1

A = 1
B = 1
C = 0

no
| ?-

我不知道你的表达方式是什么。但无论它是什么，您都可以将其映射到上述解决方案。我所展示的内容简单明了。您可以跳过这些op/3内容并使用标准术语表达式，例如or(not(and(A,B)), not(and(B,C)))使用上面的代码。如果您将输入作为某种标记序列，例如，[not, (, A, and, B, ...]那么您将不得不进行一些列表处理。

于 2017-06-08T14:23:13.633 回答