sparql - 什么是以“t”开头的值以及如何忽略它们进行计数

Question

我正在尝试使用 SPARQL查询Wikidata中某些属性的频率。

例如，要找出不同性别值的频率是多少，我有以下查询：

SELECT ?rid (COUNT(?rid) AS ?count)
WHERE { ?qid wdt:P21 ?rid.
  BIND(wd:Q5 AS ?human)
  ?qid wdt:P31 ?human.
} GROUP BY ?rid

我得到以下结果：

wd:Q6581097 2752163
wd:Q6581072 562339
wd:Q1052281 223
wd:Q1097630 68
wd:Q2449503 67
wd:Q48270   36
wd:Q44148   8
wd:Q43445   4
t152990852  1
t152990762  1
t152990752  1
t152990635  1
t152775383  1
t152775370  1
t152775368  1
...

我对此有以下疑问：

• 这些t152...值指的是什么？
• 如何忽略包含的元组t152...？
  我试过FILTER ( !strstarts(str(?rid), "wd:") )了，但它超时了。
• 如何计算不同的答案数量？
  我尝试SELECT (COUNT(DISTINCT ?rid) AS ?count)使用上述查询，但它再次超时。

Answer 1

以 开头的值t是“skolemized”的未知值（例如，参见Q2423351表示未知性别或性别的人）。

为了提高性能，我建议您将查询分为三个部分：

1. 所有“正常”性别：

   SELECT ?rid (COUNT(?qid) AS ?count) 
   WHERE {
      ?qid wdt:P31 wd:Q5.
      ?qid wdt:P21 ?rid.
      ?rid wdt:P31 wd:Q48264 
   } GROUP BY ?rid ORDER BY DESC(?count)
   

   请注意，根据 Wikidata，wd:Q746411是wd:Q48270等的子类。

2. 所有“非正常”性别：

   SELECT ?rid (COUNT(?qid) AS ?count) 
   WHERE {
      ?qid wdt:P31 wd:Q5.
      ?qid wdt:P21 ?rid.
      FILTER (?rid NOT IN
              (
               wd:Q6581097,
               wd:Q6581072,
               wd:Q1052281,
               wd:Q2449503,
               wd:Q48270,
               wd:Q746411,
               wd:Q189125,
               wd:Q1399232,
               wd:Q3277905
              )
             ).
      FILTER (isURI(?rid))
   } GROUP BY ?rid ORDER BY DESC(?count)
   

   FILTER NOT EXISTS {?rid wdt:P31 wd:Q48264 }由于性能原因，我不使用。

3. 所有（即 1）“未知”性别：

   SELECT (COUNT(?qid) AS ?count) 
   WHERE {
      ?qid wdt:P31 wd:Q5.
      ?qid wdt:P21 ?rid.
      FILTER (!isURI(?rid))
   } 
   

实际上，在您的情况下，计算不同的wd:Q5或计算它们不不同并不是很重要，但由于性能原因，后者更可取。