6

我正在尝试使用许多（约 50 个）getter 和 setter 方法（有些名称不规则）来实现一个巨大的 Java 接口。我认为使用宏来减少代码量会很好。所以而不是

(def data (atom {:x nil}))
(reify HugeInterface
  (getX [this] (:x @data))
  (setX [this v] (swap! data assoc :x v)))

我希望能够写作

(def data (atom {:x nil}))
(reify HugeInterface
  (set-and-get getX setX :x))

这个设置和获取宏（或类似的东西）可能吗？我无法让它工作。

4

4 回答 4

9

（更新了第二种方法——见下面的第二条水平规则——以及一些解释性评论：第一种。）

我想知道这是否可能是朝着正确方向迈出的一步：

(defmacro reify-from-maps [iface implicits-map emit-map & ms]
  `(reify ~iface
     ~@(apply concat
         (for [[mname & args :as m] ms]
           (if-let [emit ((keyword mname) emit-map)]
             (apply emit implicits-map args)
             [m])))))

(def emit-atom-g&ss
  {:set-and-get (fn [implicits-map gname sname k]
                  [`(~gname [~'this] (~k @~(:atom-name implicits-map)))
                   `(~sname [~'this ~'v]
                      (swap! ~(:atom-name implicits-map) assoc ~k ~'v))])})

(defmacro atom-bean [iface a & ms]
  `(reify-from-maps ~iface {:atom-name ~a} ~emit-atom-g&ss ~@ms))

注意。宏将on的atom-bean实际编译时值emit-atom-g&ss传递给reify-from-maps. 编译特定atom-bean表单后，任何后续更改emit-atom-g&ss都不会影响已创建对象的行为。

来自 REPL 的示例宏扩展（为清楚起见添加了一些换行符和缩进）：

user> (-> '(atom-bean HugeInterface data
             (set-and-get setX getX :x))
          macroexpand-1
          macroexpand-1)
(clojure.core/reify HugeInterface
  (setX [this] (:x (clojure.core/deref data)))
  (getX [this v] (clojure.core/swap! data clojure.core/assoc :x v)))

两个macroexpand-1s 是必要的，因为atom-bean它是一个扩展为进一步宏调用的宏。macroexpand不会特别有用，因为它将一直扩展为对 的调用reify*，背后的实现细节reify。

这里的想法是，您可以提供emit-map类似emit-atom-g&ss上述内容的关键字，其名称（以符号形式）将触发reify-from-maps调用中的魔术方法生成。魔术是由在给定中存储为函数的函数执行的emit-map；函数的参数是“隐式”的映射（基本上任何和所有信息都应该可以被reify-from-maps形式中的所有方法定义访问，例如在这种特殊情况下的原子名称），然后是“魔术方法说明符”的reify-from-maps形式。如上所述，reify-from-maps需要看一个实际的关键字 -> 函数映射，而不是它的符号名称；所以，它只能在文字映射、其他宏内部或在eval.

普通方法定义仍然可以包含在内，并将被视为常规reify形式，前提是与其名称匹配的键不出现在emit-map. 发射函数必须以 : 期望的格式返回方法定义的 seqables（例如向量）reify：这样，为一个“魔术方法说明符”返回多个方法定义的情况相对简单。如果iface参数被替换为' body 中的ifaces和~iface，则可以指定多个接口用于实现。~@ifacesreify-from-maps

这是另一种方法，可能更容易推理：

(defn compile-atom-bean-converter [ifaces get-set-map]
  (eval
   (let [asym (gensym)]
     `(fn [~asym]
        (reify ~@ifaces
          ~@(apply concat
              (for [[k [g s]] get-set-map]
                [`(~g [~'this] (~k @~asym))
                 `(~s [~'this ~'v]
                      (swap! ~asym assoc ~k ~'v))])))))))

这会在运行时调用编译器，这有点昂贵，但每组要实现的接口只需要执行一次。结果是一个函数，它接受一个原子作为参数，并用get-set-map参数中指定的 getter 和 setter 实现给定接口的 atom 周围的包装器。（这样写，比以前的方法更不灵活，但上面的大部分代码都可以在这里重用。）

这是一个示例界面和一个 getter/setter 映射：

(definterface IFunky
  (getFoo [])
  (^void setFoo [v])
  (getFunkyBar [])
  (^void setWeirdBar [v]))

(def gsm
  '{:foo [getFoo setFoo]
    :bar [getFunkyBar setWeirdBar]})

还有一些 REPL 交互：

user> (def data {:foo 1 :bar 2})
#'user/data
user> (def atom-bean-converter (compile-atom-bean-converter '[IFunky] gsm))
#'user/atom-bean-converter
user> (def atom-bean (atom-bean-converter data))
#'user/atom-bean
user> (.setFoo data-bean 3)
nil
user> (.getFoo atom-bean)
3
user> (.getFunkyBar data-bean)
2
user> (.setWeirdBar data-bean 5)
nil
user> (.getFunkyBar data-bean)
5
于 2010-12-14T01:29:01.890 回答
4

关键是 reify 本身是一个宏，它在您自己的 set-and-get 宏之前扩展 - 所以 set-and-get 方法不起作用。因此，您需要在“外部”上也有一个宏来生成 reify，而不是在 reify 内部使用内部宏。

于 2010-12-14T10:17:40.407 回答
1

由于诀窍是在reify看到它之前扩展主体，因此更通用的解决方案可能是以下几点：

(defmacro reify+ [& body]
  `(reify ~@(map macroexpand-1 body)))
于 2014-07-18T19:45:45.960 回答
0

您也可以尝试强制您的宏首先展开：

(ns qqq (:use clojure.walk))
(defmacro expand-first [the-set & code] `(do ~@(prewalk #(if (and (list? %) (contains? the-set (first %))) (macroexpand-all %) %) code)))

(defmacro setter [setterf kw] `(~setterf [~'this ~'v] (swap! ~'data assoc ~kw ~'v)))
(defmacro getter [getterf kw] `(~getterf [~'this] (~kw @~'data)))
(expand-first #{setter getter} 
 (reify HugeInterface 
  (getter getX :x)
  (setter setX :x)))
于 2011-02-13T21:28:05.227 回答